Documentation/Fonctions Calc/AMORLINC
TDF LibreOffice Document Liberation Project Blogs communautaires Weblate Nextcloud Redmine Ask LibreOffice Donner
Nom de la fonction :
AMORLINC
Catégorie :
Analyse financière
Résumé :
Calcule l'amortissement d'un actif sur une période donnée à l'aide d'un modèle d'amortissement linéaire. Cette méthode amortit l'actif d'une valeur constante à chaque exercice comptable complet. Si l'actif est acquis en cours d'exercice, l'amortissement pour cette période est calculé au prorata.
AMORLINC est destiné aux utilisateurs du système comptable français.
Syntaxe :
AMORLINC(Coût; Date d'achat; Première période; Récupération; Période; Taux[; Base])
Renvoie :
Renvoie un nombre réel non négatif qui correspond à l'amortissement de l'actif au cours de la période spécifiée, exprimé dans les mêmes unités monétaires que le coût et les valeurs de récupération de l'actif.
Arguments :
Coût est un nombre réel positif, ou une référence à une cellule contenant ce nombre, qui est le coût ou la valeur de l'actif avant amortissement.
Date d'achat est une date, ou une référence à une cellule contenant cette date, qui correspond à la date de début de l'amortissement. Pour un actif corporel, il s'agit généralement de la date d'acquisition.
Première période est une date, ou une référence à une cellule contenant cette date, qui est la date de fin de la première période comptable au cours de laquelle l'amortissement est calculé.
Récupération est un nombre réel positif, ou une référence à une cellule contenant ce nombre, qui est la valeur résiduelle de l'actif à la fin de sa durée de vie amortie. Récupération doit être dans les mêmes unités monétaires que Coût.
Période est un entier non négatif, ou une référence à une cellule contenant cet entier, qui spécifie la période comptable pour laquelle la valeur d'amortissement est renvoyée. La valeur 0 indique la période se terminant à la date indiquée par Première période. Les périodes comptables suivantes sont numérotées 1, 2, 3, et ainsi de suite.
Taux est un nombre réel positif (exprimé sous forme de pourcentage, tel que 2,5 %, ou de fraction décimale, telle que 0,025), ou une référence à une cellule contenant ce nombre, qui est le taux annuel auquel la valeur de l'actif est amortie.
Base est un entier compris entre 0 et 4, ou une référence à une cellule contenant cet entier, qui indique comment l'année doit être calculée. Pour plus d'informations, consultez la page Wikipédia [1] (Convention de comptage des jours).
Base | Calcul |
---|---|
0 ou manquant | Méthode américaine (NASD), 12 mois de 30 jours chacun |
1 | Nombre exact de jours dans les mois, nombre exact de jours dans l'année. |
2 | Nombre exact de jours dans le mois, l'année compte 360 jours. |
3 | Nombre exact de jours dans le mois, l'année compte 365 jours. |
4 | Méthode européenne, 12 mois de 30 jours chacun. |
- Si l'une des dates Date d'achat ou Première période n'est pas une date valide, alors AMORLINC renvoie une erreur #VALEUR !.
- Si l'un des éléments Coût, Récupération, Période ou Taux n'est pas numérique, alors AMORLINC signale une erreur #VALEUR !.
- Si Base n'est pas numérique, alors AMORLINC signale une erreur d'argument non valide (Err :502).
- Si Date d'achat est postérieure à Première période, alors AMORLINC signale une erreur d'argument non valide (Err :502).
- Si Coût ou Taux est inférieur ou égal à 0, alors AMORLINC signale une erreur d'argument non valide (Err :502).
- Si Récupération est inférieur à 0 ou supérieur à Coût, alors AMORLINC signale une erreur d'argument non valide (Err :502).
- Si l'une des valeurs Période ou Base est une valeur non entière, alors AMORLINC la tronque en une valeur entière.
- Si Période est inférieur à 0, alors AMORLINC signale une erreur d'argument non valide (Err :502).
- Si, après une troncature, Base n'est pas égal à 0, 1, 2, 3 ou 4, alors AMORLINC signale une erreur d'argument non valide (Err :502).
Détails complémentaires :
- En utilisant AMORLINC, la durée d'amortissement de l'actif comprend une période fractionnaire initiale jusqu'à la fin de la première période comptable, puis un certain nombre de périodes comptables complètes, puis une période fractionnaire finale.
- Si Période = 0, l'amortissement est calculé au prorata. Pour cette période, la formule de AMORLINC est :
- [math]\displaystyle{ \operatorname{AMORLINC_{0}}~=~f*Coût~*~Taux~*~\operatorname{FRACTION.ANNEE}(Date~d'achat; Première~période; Base) }[/math]
- Si Date d'achat est égale à Première période, alors [math]\displaystyle{ \operatorname{AMORLINC_{0}}~=~0 }[/math]
- En général, l'amortissement est calculé pour N périodes comptables complètes (périodes 1, 2, 3, …, N), où N est donné par :
- [math]\displaystyle{ N~=~\operatorname{INT}\left ( \frac{(Coût~-~Récupération~-~\operatorname{AMORLINC_{0}})}{Coût~\times ~Taux} \right ) }[/math]
- Pour ces périodes complètes (1 ≤ Période ≤ N), l'amortissement est [math]\displaystyle{ Coût~\times ~Taux }[/math].
- Dans la plupart des cas, un amortissement supplémentaire intervient au cours d'une période comptable finale ('Période égale N + 1). Il s'agit généralement d'une période partielle, car l'amortissement total sur l'ensemble des périodes ne peut excéder la différence entre le coût et la valeur résiduelle. L'amortissement sur cette période est donné par :
- [math]\displaystyle{ \operatorname{AMORLINC_{N+1}}~=~Coût~-~Récupération~-~\operatorname{AMORLINC_{0}}~-~N~ \times ~Coût~ \times ~Taux }[/math]
- Pour les périodes au-delà de la durée de vie amortie de l'actif (Période > N+1), AMORLINC renvoie la valeur 0,0.
- Il existe deux différences principales entre le comportement de AMORLINC dans Calc et Microsoft Excel.
- Excel ne prend pas en charge l'option 2 pour l'argument Base (nombre réel de jours dans le mois, 360 jours dans l'année).
- Calc et Excel se comportent différemment lorsque la date d'achat coïncide avec la fin d'une période comptable. Calc considère la période initiale 0 comme étant de durée nulle et renvoie donc un amortissement nul. Excel considère la période initiale 0 comme la première période complète.
- Ces différences peuvent limiter l’interopérabilité lorsque vous disposez d’une feuille de calcul Calc contenant des appels AMORLINC qui est ensuite ouverte dans Excel.
- Pour plus d’informations générales sur la dépréciation et l’amortissement, consultez les pages Amortissement et Amortissement (business) de Wikipédia.
Exemples :
Exemple simple avec plusieurs appels à AMORLINC
Le tableau suivant illustre le comportement de la fonction AMORLINC.
A | B | C | D | E | |
---|---|---|---|---|---|
1 | Coût | 1200 | Période | Amortissement | |
2 | Date d'achat | 2022-07-01 | 0 | 90 | |
3 | Première période | 2022-12-31 | 1 | 180 | |
4 | Récupération | 200 | 2 | 180 | |
5 | Période | 3 | 180 | ||
6 | Taux | 15% | 4 | 180 | |
7 | Base | 0 | 5 | 180 | |
8 | 6 | 10 | |||
9 | 7 | 0 | |||
10 | 8 | 0 | |||
11 | |||||
12 | Total | 1000 |
Les données des cellules B1:B4 et B6:B7 contiennent les valeurs de la plupart des arguments passés dans les appels de fonction AMORLINC. La fonction est appelée neuf fois, une fois pour chaque valeur de l'argument Période donnée dans les cellules D2 à D10. La cellule E2 contient la formule =AMORLINC($B$1; $B$2; $B$3; $B$4; $D2; $B$6; $B$7)
; la cellule E3 contient la formule =AMORLINC($B$1; $B$2; $B$3; $B$4; $D3; $B$6; $B$7)
; et ainsi de suite.
Les valeurs renvoyées par les appels AMORLINC sont affichées dans les cellules E2 à E10, et la cellule E12 contient la somme de toutes les valeurs des cellules E2 à E10. Les caractéristiques suivantes sont visibles dans ces résultats :
- Période 0. L'actif ayant été acquis au milieu de la période comptable, l'amortissement prévu pour la période 0 devrait être d'environ la moitié de sa valeur au cours des années complètes suivantes. Ceci est reflété dans les données de l'exemple (90 contre 180).
- Pour cet exemple de données, l'amortissement est calculé sur cinq périodes comptables complètes (périodes 1 à 5). Durant ces périodes, l'amortissement est calculé comme suit : [math]\displaystyle{ 1200 \times 0,15~=~180 }[/math].
- L'amortissement total jusqu'à la fin de la période 5 est de 990. Étant donné qu'un actif ne peut pas être amorti en dessous de sa valeur résiduelle, l'amortissement de la période 6 est limité à [math]\displaystyle{ 1200~-~200~-~990~=~10 }[/math] et l'amortissement de toute période ultérieure est nul.
Exemples supplémentaires
Formule | Description | Renvoie |
---|---|---|
=AMORLINC(1500; "2001-04-01"; "2001-06-15"; 454; 0; 0,19; 2) | Ici, la fonction calcule l'amortissement au prorata pour la période 0, qui est une courte période d'environ 2,5 mois. | 59,375 |
=AMORLINC(1500; "2001-04-01"; "2001-06-15"; 454; 0; 0,19) | Ici, la fonction calcule à nouveau l'amortissement au prorata pour la période 0, soit une courte période d'environ 2,5 mois. Cependant, dans ce cas, la valeur de l'argument Base n'est pas spécifiée ; la valeur par défaut est donc 0, ce qui donne un résultat légèrement différent de l'exemple précédent. | 58,5833333333333 |
=AMORLINC(1500; "2001-04-01"; "2001-06-15"; 454; 1; 0,19; 2) | Ici, la fonction calcule le montant de l'amortissement pour une période comptable complète (période 1). | 285 |
=AMORLINC(2000; DATE(2020; 2; 1); DATE(2020; 12; 31); 10; 4; 10%; 0) | Ici, la fonction calcule le montant de l'amortissement pour une période comptable complète (période 4). Notez qu'il est souvent recommandé d'utiliser la fonction DATE plutôt que de saisir des valeurs de date formatées. | 200 |
Fonctions LibreOffice associées :
Standard ODF :
Fonctions Excel relatives (ou similaires) :
AMORLINC