Documentatie/Calc-functies/EN

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/AND and the translation is 100% complete.
    Other languages:


    Functienaam:

    EN

    Categorie:

    Logisch

    Samenvatting:

    Test meerdere voorwaarden om te bepalen of aan alle voorwaarden is voldaan. WAAR wordt geretourneerd als aan alle voorwaarden is voldaan en anders ONWAAR.

    Syntaxis:

    EN(Logische waarde 1 [; Logische waarde 2 [; … [; Logische waarde 255]]])

    Retourneert:

    Retourneert de logische waarde WAAR als aan alle opgegeven voorwaarden is voldaan en retourneert de logische waarde ONWAAR als niet aan één of meer van de opgegeven voorwaarden wordt voldaan.

    Argumenten:

    Logische Waarde 1, Logische Waarde 2, … , Logische Waarde 255 geven de reeks voorwaarden die gecontroleerd moeten worden. Elke voorwaarde moet een uitdrukking bevatten die een logische waarde oplevert die WAAR of ONWAAR is. Als een uitdrukking resulteert in een getal in plaats van een logische waarde, wordt de waarde 0 (nul) behandeld als ONWAAR en worden alle niet-nulwaarden behandeld als WAAR. Elk argument kan één van de volgende vormen aannemen:

    • Een logische waarde of een uitdrukking die kan worden geëvalueerd tot een logische waarde. Voorbeelden zijn WAAR, 3, 1<5, 2+3=7, A2*A3 en B8<10.
    • Een verwijzing naar een enkele cel die een logische waarde of uitdrukking bevat.
    • Een verwijzing naar een celbereik dat logische waarden of uitdrukkingen bevat (bijvoorbeeld D6:E12 of A1:B9~E12:E14).
    • De naam van een benoemd bereik, bestaande uit cellen die logische waarden of uitdrukkingen bevatten.
    • De naam van een databasebereik, bestaande uit cellen die logische waarden of uitdrukkingen bevatten.
    • Een matrix van logische waarden of getallen (bijvoorbeeld {WAAR; ONWAAR; 0; 123,456}).

    Merk op dat hoewel EN tot 255 argumenten kan accepteren, elk argument een celbereik kan specificeren. Dit betekent dat het aantal verwerkte positieve gehele getallen veel meer dan 255 kan zijn.

    • Als de argumenten niet ten minste één logische waarde geven, rapporteert EN de fout #WAARDE!
    • Als de argumenten precies één waarde opleveren, geeft EN die logische waarde als resultaat.
    • Als een argument een string tussen aanhalingstekens is, dan rapporteert EN de fout #WAARDE!. Dit geldt niet voor verwijzingen naar cellen die strings bevatten.
    • Lege cellen en cellen die tekst bevatten, worden genegeerd door EN.
    • Als een cel een fout bevat, verspreidt EN die fout ongeacht de inhoud van andere cellen.

    Aanvullende details:

    Details specifiek voor de functie EN

    • In zijn eenvoudigste vorm is de logische EN (ook wel logische conjunctie genoemd) van twee logische waarden een bewerking die de waarde WAAR produceert als beide opdrachtelementen waar zijn en anders ONWAAR. Het kan als volgt worden uitgedrukt als een waarheidstabel:
    Waarheidstabel voor logische bewerking EN
    Opdrachtelement 1 Opdrachtelement 2 Opdrachtelement 1
    EN
    Opdrachtelement 2
    waar waar waar
    waar onwaar onwaar
    onwaar waar onwaar
    onwaar onwaar onwaar
    • EN negeert alle tekst in cellen of lege cellen. Als u verkeerde resultaten vermoedt, zoek dan naar tekst binnen het (de) opgegeven gegevensbereik(en). Gebruik de functie Beeld ▸ Waardemarkering van Calc om tekstinhoud binnen een gegevensbereik te markeren.
    • Hoewel u EN op zichzelf kunt gebruiken, is het vaak veel handiger in combinatie met andere functies. Beschouw bijvoorbeeld een waarde in cel A1 waarvan u verwacht dat deze in het bereik van 1 tot 10 ligt. U kunt een formule plaatsen zoals =ALS(EN(A1>=1; A1<=10); "Binnen bereik "; "Buiten bereik") in een andere cel om te controleren of een waarde in cel A1 binnen het verwachte bereik valt.


    Algemene informatie over de logische functies van Calc

    Note pin.svg

    NB:
    Voor het gemak wordt de informatie in deze subsectie herhaald op alle pagina's die de logische functies van Calc beschrijven.

    Calc gebruikt de getallen 0 (ONWAAR) en 1 (WAAR) om logische waarden weer te geven. Voer bijvoorbeeld 1 in in een cel met de standaard algemene getalopmaak. Selecteer vervolgens Opmaak ▸ Cellen op de Menubalk om het dialoogvenster Cellen opmaken weer te geven, selecteer de optie Booleaanse waarde in het gedeelteCategorie van het tabblad Getallen en klik op de knop OK. Merk op dat het getal 1 nu wordt weergegeven als WAAR. Om terug te keren naar het weergeven van het getal 1, herhaalt u het proces maar selecteert u Getal in plaats van Booleaanse waarde.

    Om een logische waarde in een cel in te voeren, typt u gewoon WAAR of ONWAAR (hoofdletterongevoelig) in de cel. Calc zal de logische waarde herkennen, deze in hoofdletters weergeven en de opmaak van de cel wijzigen in de opmaak die past bij Booleaanse waarden.

    Calc-functies die een logisch resultaat produceren, geven een getal terug, of 0 of 1. In het geval van een formule die zo'n logische functie eenvoudig aanroept en zich in een cel bevindt die de standaard algemene getalopmaak heeft, wordt de cel overgeschakeld naar de opmaak van de Booleaanse waarde en de geretourneerde waarde wordt weergegeven als ONWAAR of WAAR. Bijvoorbeeld =WAAR() retourneert de waarde 1, die wordt weergegeven als WAAR; als u de opmaak vervolgens wijzigt in een numerieke opmaak, wordt het weergegeven als het getal 1.

    Calc-functies die op een logisch resultaat testen, evalueren altijd de te testen uitdrukking en controleren of deze gelijk is aan 0. De waarde 0 wordt als ONWAAR beschouwd en elke andere waarde wordt als WAAR genomen. Bijvoorbeeld, =NIET(0) geeft WAAR terug en =NIET(57,89) geeft ONWAAR terug.

    In tegenstelling tot Calc heeft Microsoft Excel een apart type voor logische waarden - het zijn geen getallen maar worden soms geconverteerd naar getallen. Wees daarom voorzichtig als u compatibiliteit nodig heeft.

    Voorbeelden:

    Gegevens voor voorbeelden
    A B C D
    1 =WAAR() 45 2,2
    2 =NIET(ONWAAR()) 3
    3 1 -5,4
    4 2
    5 3 "Voorwaarden": A1:A5   genoemd bereik
    Formule Beschrijving Retourneert
    =EN(ONWAAR(); WAAR()) Een van de argumenten is niet waar. ONWAAR
    =EN(WAAR(); C1>10; ONWAAR()) Een van de argumenten is niet waar. ONWAAR
    =EN(D1:D3) Alle opgegeven numerieke waarden zijn niet gelijk zijn aan 0. WAAR
    =EN({2; 4; 6; 8}) Alle opgegeven numerieke waarden zijn niet gelijk zijn aan 0 (nul). WAAR
    =EN(12<13; 14>12; 7<6) Het derde argument is ONWAAR. ONWAAR
    =EN(Voorwaarden) Alle cellen in het bereik zijn of WAAR of ongelijk 0 (nul). WAAR

    Gerelateerde LibreOffice-functies:

    ONWAAR

    ALS

    ALS.FOUT

    ALS.NB

    ALS.VOORWAARDEN

    NIET

    OF

    SCHAKELEN

    WAAR

    EX.OF

    ODF standaard:

    Section 6.15.2, part 2

    Gerelateerde (of gelijkwaardige) Excel-functies:

    AND