Jump to content

Documentation/Fonctions Calc/NB.JOURS.COUPONS

From The Document Foundation Wiki
This page is a translated version of the page Documentation/Calc Functions/COUPDAYS and the translation is 100% complete.

Nom de la fonction :

NB.JOURS.COUPONS

Catégorie :

Analyse financière

Résumé :

Calcule le nombre de jours de la période du coupon qui contient la date de liquidation.

Syntaxe :

NB.JOURS.COUPONS(Règlement; Échéance; Fréquence[; Base])

Renvoie :

Renvoie un nombre compris entre 90 et 366 (inclus), correspondant au nombre de jours de la période du coupon durant lequel tombe la date de règlement. Dans certains cas, la valeur renvoyée peut comporter une partie fractionnaire.

Arguments :

Règlement désigne une date (entre guillemets), un numéro de série date-heure ou une référence à une cellule contenant l'un de ces types, qui précise le moment où une transaction est réglée. À cette date, le vendeur finalise le transfert de l'obligation à l'acheteur, et ce dernier effectue le paiement correspondant au vendeur.

Échéance est une date (entre guillemets), un numéro de série date-heure ou une référence à une cellule contenant l'un de ces types, qui précise l'échéance de l'obligation. À l'échéance, l'émetteur de l'obligation doit rembourser l'intégralité du montant de l'obligation au détenteur.

Fréquence est un entier positif, ou une référence à une cellule contenant cet entier, qui correspond au nombre de coupons payés par an. Les valeurs correctes sont 1 (annuel), 2 (semestriel) ou 4 (trimestriel).

Base est un entier compris entre 0 et 4, ou une référence à une cellule contenant cet entier, qui indique comment l'année doit être calculée. Pour plus d'informations, consultez la page Wikipédia [1] (Convention de comptage des jours).

Base Calcul
0 ou manquant Méthode américaine (NASD), 12 mois de 30 jours chacun
1 Nombre exact de jours dans les mois, nombre exact de jours dans l'année.
2 Nombre exact de jours dans le mois, l'année compte 360 ​​jours.
3 Nombre exact de jours dans le mois, l'année compte 365 jours.
4 Méthode européenne, 12 mois de 30 jours chacun.
  • Si Règlement ou Échéance n'est pas une expression de date valide, alors NB.JOURS.COUPONS signale une erreur #VALEUR!.
  • Si la date de Règlement est égale ou postérieure à la date dÉchéance, alors NB.JOURS.COUPONS signale une erreur d'argument non valide (Err:502).
  • Si Fréquence n'est pas numérique, alors NB.JOURS.COUPONS signale une erreur #VALEUR!.
  • Si Base n'est pas numérique, alors NB.JOURS.COUPONS signale une erreur d'argument non valide (Err:502).
  • Si Base ou Fréquence est une valeur non entière, alors NB.JOURS.COUPONS la tronque en une valeur entière.
  • Si, après une troncature, Fréquence n'est pas égale à 1, 2 ou 4, alors NB.JOURS.COUPONS signale une erreur d'argument non valide (Err:502).
  • Si, après une troncature, Base n'est pas égal à 0, 1, 2, 3 ou 4, alors NB.JOURS.COUPONS signale une erreur d'argument non valide (Err:502).

Détails complémentaires :

  • Lorsque l'argument Base est défini sur 1 (nombre exact de jours en mois, nombre exact de jours en année), NB.JOURS.COUPONS calcule à partir de la date d'échéance pour trouver les deux dates de coupon (une avant ou à la date de règlement, une après la date de règlement) et renvoie ensuite le nombre de jours entre elles.
  • Pour toutes les autres valeurs valides de l'argument Base, toutes les années sont considérées comme ayant le même nombre de jours. Ainsi, la fonction NB.JOURS.COUPONS calcule le nombre de jours de la période de coupon contenant la date de règlement en divisant simplement le nombre de jours par an par la valeur spécifiée de l'argument Fréquence. Pour les valeurs de Base égales à 0, 2 et 4, NB.JOURS.COUPONS renvoie 90, 180 ou 360 (selon la valeur de Fréquence). Pour une valeur de Base égale à 3, NB.JOURS.COUPONS renvoie 365, 182,5 ou 91,25 (selon la valeur de Fréquence).


  • Les exemples de cette page utilisent le format de date standard ISO 8601, car celui-ci doit être indépendant des paramètres régionaux sélectionnés. Le format de date par défaut de votre ordinateur peut être différent. Évitez d'utiliser des formats de date dépendant des paramètres régionaux, car ils peuvent générer des erreurs si le document est chargé avec des paramètres régionaux différents. Il est souvent recommandé d'utiliser la fonction DATE plutôt que de saisir des valeurs de date formatées.
  • Si Règlement ou Échéance inclut des composantes temporelles, elles sont ignorées par NB.JOURS.COUPONS.
  • Pour plus d’informations sur les coupons, visitez la page Coupon (finance) de Wikipédia.

Exemples :

Formule Description Renvoie
=NB.JOURS.COUPONS(A1; A2; A3; A4) où la cellule A1 contient la date 01/09/2022, la cellule A2 contient la date 15/11/2025, la cellule A3 contient le nombre 2 et la cellule A4 contient le nombre 3. Un investisseur achète une obligation arrivant à échéance le 15 novembre 2025, la transaction étant réglée le 1er septembre 2022. L'obligation verse des intérêts semestriels et le calcul des jours est basé sur la formule 3 (nombre exact de jours dans un mois, 365 jours dans une année). Ici, la fonction calcule le nombre de jours de la période de versement du coupon incluant la date de règlement, soit 182,5. 182,5
=NB.JOURS.COUPONS("2022-09-01"; "2022-11-15"; 2) Un investisseur achète une obligation arrivant à échéance le 15 novembre 2025, la transaction étant réglée le 1er septembre 2022. L'obligation verse des intérêts semestriels. Le quatrième argument étant omis, la fonction NB.JOURS.COUPONS utilise par défaut une convention de calcul des jours de base 0 (12 mois de 30 jours chacun). Dans ce cas, la fonction calcule 180 jours dans la période de versement du coupon incluant la date de règlement. 180
=NB.JOURS.COUPONS(DATE(2022; 9; 1); DATE(2025; 11; 15); 2) Ici, la formule exécute la même fonction que dans l'exemple précédent mais utilise la fonction DATE au lieu de saisir des valeurs de date formatées. 180
=NB.JOURS.COUPONS(44805; 45976; 2) Calc traite les dates comme des nombres, où chaque date correspond à un numéro de série date-heure. En supposant que l'option Date de Outils ▸ Options ▸ LibreOffice Calc ▸ Calculer (LibreOffice ▸ Préférences ▸ LibreOffice Calc ▸ Calculer sous macOS) soit définie sur sa valeur par défaut, 44805 correspond au numéro de série date-heure du 01/09/2022 et 45976 au numéro de série date-heure du 15/11/2025. Ici, la formule remplit la même fonction que dans l'exemple précédent. 180

Fonctions LibreOffice associées :

NB.JOURS.COUPON.PREC

NB.JOURS.COUPON.SUIV

DATE.COUPON.SUIV

NB.COUPONS

DATE.COUPON.PREC

Standard ODF :

Section 6.12.6, part 2

Fonctions Excel relatives (ou similaires) :

COUPDAYS