Documentatie/Calc-functies/DB
TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren
Functienaam:
DB
Categorie:
Financieel
Samenvatting:
Berekent de afschrijving van een bezit voor een bepaalde periode met behulp van de degressieve methode met vaste rente. Deze methode berekent de afschrijving op basis van de huidige boekwaarde van het bezit (in plaats van de oorspronkelijke kostprijs) en deze neemt af van de ene periode naar de volgende. Dit leidt ertoe dat de afschrijving in eerdere perioden groter is en in latere perioden lager.
DB gebruikt een vast afschrijvingspercentage dat een functie is van de initiële waarde van het bezit, de restwaarde en de geschatte gebruiksduur.
Syntaxis:
DB(Kosten; Restwaarde; Levensduur; Periode[; Maand])
Retourneert:
Retourneert een niet-negatief reëel getal dat de afschrijving is van het bezit gedurende een bepaalde periode met behulp van de degressieve methode met vaste rente. Het geretourneerde getal is in dezelfde valuta-eenheid als de opgegeven kosten- en restwaarden en wordt standaard opgemaakt in een landafhankelijke valuta-indeling.
Argumenten:
Kosten is een positief reëel getal of een verwijzing naar een cel die dat getal bevat, wat de kostprijs of waarde is van het bezit vóór afschrijving.
Restwaarde is een niet-negatief reëel getal, of een verwijzing naar een cel die dat getal bevat, wat de restwaarde is van het bezit aan het einde van zijn afgeschreven levensduur. Restwaarde moet in dezelfde valuta-eenheden zijn als Kosten.
Levensduur is een reëel getal in het bereik 0,0 < Levensduur ≤ 1200,0 of een verwijzing naar een cel die dat getal bevat, dat het aantal perioden definieert waarover het bezit wordt afgeschreven.
Periode is een positief geheel getal in het bereik van 1 tot Levensduur + 1 of een verwijzing naar een cel die dat gehele getal bevat, dat de periode aangeeft waarvoor de afschrijvingswaarde wordt geretourneerd.
Maand is een positief geheel getal in het bereik van 1 tot 12 of een verwijzing naar een cel die dat gehele getal bevat, het aantal maanden voor het eerste jaar van afschrijving. Als het argument wordt weggelaten, wordt een standaardwaarde van 12 gebruikt.
- Als een argument niet-numeriek is, retourneert DB als foutcode #WAARDE!.
- Als Maand een niet-gehele waarde is, dan kapt DB deze af tot een gehele waarde.
- De functie retourneert als foutcode Ongeldig argument (Fout:502) in elk van de volgende gevallen:
- Kosten ≤ 0,0.
- Restwaarde < 0,0 of Restwaarde > Kosten.
- Levensduur ≤ 0,0 of Levensduur > 1200,0.
- Periode ≤ 0 of Periode > Levensduur + 1;
- Maand < 1 of Maand > 12 (na eventuele afkapping)
- Als 0,0 < Periode < 1,0, dan retourneert DB een afschrijvingswaarde van 0,0.
Aanvullende details:
- DB berekent de afschrijving over een periode. Als u een andere waarde dan 12 opgeeft voor het argument Maand, dan gaat DB ervan uit dat de duur van een afschrijvingsperiode 12 maanden of één jaar is. Als het argument Maand wordt weggelaten of opgegeven als 12, hoeft uw afschrijvingsperiode niet één jaar te zijn.
- Om de afschrijving te berekenen, gebruikt DB een vast tarief gedurende de levensduur van het bezit, gegeven door:
- [math]\displaystyle{ Tarief~=~1- \left( \frac{Restwaarde}{Kosten} \right)^{\frac{1}{Levensduur}} }[/math]
- De afschrijving in elke periode i wordt berekend als:
- [math]\displaystyle{ Afschrijving _{i}~=~Waarde\_bij\_begin\_van\_periode \times Tarief }[/math]
- [math]\displaystyle{ Afschrijving _{i}~=~Waarde\_bij\_begin\_van\_periode \times Tarief }[/math]
- Hier
- [math]\displaystyle{ Waarde\_ bij\_begin\_ van\_ periode~=~Kosten - Afschrijving\_ tot nu toe\_ }[/math]
- Als Maand kleiner is dan 12, is het gebruikte afschrijvingspercentage voor de eerste periode:
- [math]\displaystyle{ Tarief \times \frac{Maand}{12} }[/math]
- Als Maand kleiner is dan 12, is het afschrijvingspercentage dat wordt gebruikt voor de laatste periode (Levensduur + 1):
- [math]\displaystyle{ Tarief \times \frac{12-Maand}{12} }[/math]
- Ga voor meer achtergrondinformatie over afschrijving naar de pagina Depreciation op Wikipedia.
Voorbeelden:
Houd er rekening mee dat de opmaak van de geretourneerde waarden die in de volgende voorbeelden worden gegeven, uitgaat van de landinstelling Engels (VS).
Eenvoudig voorbeeld met meerdere aanroepen naar DB
De volgende tabel illustreert het gedrag van de functie DB.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Kosten | 1200 | Periode | Afschrijving | |
| 2 | Restwaarde | 200 | 1 | $216.60 | |
| 3 | Levensduur | 4 | 2 | $355.01 | |
| 4 | Maand | 6 | 3 | $226.85 | |
| 5 | 4 | $144.96 | |||
| 6 | 5 | $46.31 | |||
| 7 | 6 | Fout:502 | |||
| 8 | |||||
| 9 | Totaal | $989.73 |
De gegevens in cellen B1:B4 bevatten de waarden voor vier van de argumenten die zijn doorgegeven in DB functieaanroepen. De functie wordt zes keer aangeroepen, één keer voor elke waarde van het argument Periode in de cellen D2 tot D7. Cel E2 bevat de formule =DB($B$1; $B$2; $B$3; $D2; $B$4); cel E3 bevat de formule =DB($B$1; $B$2; $B$3; $D3; $B$4); enzovoort.
De waarden die worden geretourneerd door de DB-aanroepen worden weergegeven in cellen E2:E7 en cel E9 bevat de som van alle waarden in cellen E2:E6 (cel E7 geeft een fout weer en is daarom uitgesloten van dit bedrag). In deze resultaten zijn de volgende kenmerken te zien:
- Periode 1. DB gebruikt een vast tarief gegeven door [math]\displaystyle{ \left(1- \left( \frac{restwaarde}{kosten} \right)^{\frac{1 }{levensduur}}\right) }[/math] of [math]\displaystyle{ \left(1- \left( \frac{200}{1200} \right)^{\frac{1}{4}}\right)= 0,361 }[/math] tot op drie decimalen. Aangezien de eerste periode 6 maanden omvat, is de afschrijving voor de periode [math]\displaystyle{ 0,5 \times 0,361 \times 1200 = 216,6 }[/math]. Merk op dat de resultaten van DB standaard zijn opgemaakt als een valuta.
- Periode 2. Deze periode omvat een heel jaar en de waarde van het actief aan het begin van dat jaar is [math]\displaystyle{ 1200-216,6=983,4 }[/math]. Daarom is de afschrijving voor deze periode [math]\displaystyle{ 0,361 \times 983,4=355,01 }[/math].
- Periode 3 en 4. De afschrijving in deze perioden wordt op dezelfde wijze berekend als periode 2.
- Periode 5. Aangezien de levensduur van het activum wordt gegeven als 4 jaar en periode 1 slechts 6 maanden lang was, vindt gedurende periode 5 nog eens 6 maanden afschrijving plaats.
- Punt 6. Er wordt een foutcode Ongeldig argument (Foutː 502) geretourneerd omdat de waarde van het argument Periode groter is dan de waarde van het argument Levensduur plus 1.
- Merk op dat de totale afschrijving van 989,73 niet precies gelijk is aan het verschil tussen de kostprijs en de restwaarde van 1000.
Extra voorbeelden
| Formule | Beschrijving | Retourneert |
|---|---|---|
| =DB(25000; 1000; 3; 2; 6) | Een computersysteem met een initiële kostprijs van 25.000 valuta-eenheden wordt afgeschreven over een periode van drie jaar, waarbij de eerste periode zes maanden bedraagt. De restwaarde is 1.000 valuta-eenheden. De afschrijving van het computersysteem over het tweede jaar is 11.037,95 valuta-eenheden. Hetzelfde resultaat wordt verkregen met de formule =DB(25000; 1000; 3; 2; 6.9) omdat het niet-gehele getal 'Maand' waarde wordt afgekapt tot 6. |
$11,037.95 |
| =DB(25000; 1000; 3; 2) | Dit is hetzelfde voorbeeld als hierboven met het verschil dat het argument Maand niet is gespecificeerd, vandaar dat het standaard 12 is. In dit geval is de afschrijving van het computersysteem over het tweede jaar 5.625,90 valuta-eenheden. | $5,625.90 |
Gerelateerde LibreOffice-functies:
ODF standaard:
Gerelateerde (of gelijkwaardige) Excel-functies:
DB