Dokumentation/Calc Funktionen/FINDEN

TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende

• Start
• Entwicklung
• Gestaltung
• QA
• Events
• Dokumentation
• Webseite
• Lokalisierung
• Barrierefreiheit
• Marketing
• Diversität
• Wiki Hilfe

• Dokumentation Start
• Handbücher
• Andere Quellen
• FAQ
• HowTo
• Makros
• Doku Entwicklung

Calc Funktionen Start | Liste der Funktionen | Abkürzungen

Funktionsname:

FINDEN

Kategorie:

Text

Zusammenfassung:

Sucht case-sensitiv die Position eines Textes innerhalb eines anderen Textes.

Syntax:

FINDEN(Suchtext; Text[; Position])

Rückgabewerte:

Gibt die Position des ersten Zeichens des ersten Auftretens des zu suchenden Textes innerhalb des abzusuchenden Textes als Ganzzahl zurück. Der Rückgabewert kann nicht größer als die Länge des abzusuchenden Textes sein.

Argumente:

Suchtext ist ein Text (in Anführungszeichen), eine Zahl oder eine Referenz auf eine Zelle mit einem dieser Typen. Das ist dann der zu suchende Text.

Text ist ein Text (in Anführungszeichen), eine Zahl oder eine Referenz auf eine Zelle mit einem dieser Typen. Das ist dann der abzusuchende Text.

Position ist eine positive Ganzzahl oder eine Referenz auf eine Zelle mit dieser Ganzzahl. Das ist dann die Position des Zeichens mit dem die Suche startet. Falls die Position fehlt, verwendet FINDEN die 1.

• Falls Position keine Ganzzahl ist, verkürzt sie FINDEN auf eine Ganzzahl.
• Falls die Position nach einer eventuellen Verkürzung kleiner als 1 oder größer als die Länge des abzusuchenden Textes ist, dann meldet FINDEN einen #WERT! Fehler.
• Falls kein Treffer erzielt wurde, dann meldet FINDEN einen #WERT! Fehler. Das ist ein Fehlerfall, der behandelt werden muss, wenn er als Argument für eine andere Funktion dienen soll.

Zusätzliche Informationen:

FINDEN unterstützt weder Platzhalter noch reguläre Ausdrücke. Falls Suchen mit Platzhaltern oder regulären Ausdrücken oder nicht case-sensitive Suchen erforderlich sind, sollte die Funktion SUCHEN verwendet werden.

Im Dialog Extras ▸ Optionen ▸ LibreOffice Calc ▸ Berechnen (oder LibreOffice ▸ Preferences ▸ LibreOffice Calc ▸ Berechnen unter macOS) hat die Einstellung Suchkriterien = und <> müssen auf ganze Zellen angewendet werden keine Auswirkung auf das Verhalten von FINDEN.

Vorschläge für die Behandlung von #WERT! Fehlern nachdem kein Treffer gefunden wurde:

• =WENN(ISTFEHLER(FINDEN("xyz"; "abcdef"; 1)); "ERR: Missing Substring"; "Substring Present") gibt "ERR: Missing Substring" anstatt des Fehlers aus der Funktion FINDEN zurück.
• =WENN(ISTZAHL(FINDEN("xyz"; "abcdef"; 1)); "Substring Present"; "ERR: Missing Substring") gibt "ERR: Missing Substring" zurück und meldet nicht den Fehler aus der Funktion FINDEN weiter.

Beispiele:

Formel	Beschreibung	Ergebnis
=FINDEN("fifty"; "Fifty-fifty")	Hier gibt die Funktion 7 zurück, weil der Treffer case-sensitiv ist.	7
=FINDEN(76; 998877667654)	Hier gibt die Funktion 6 zurück, weil die Suche standardmässig beim ersten Zeichen des abzusuchenden Textes beginnt.	6
=FINDEN(76; 998877667654; 7)	Hier gibt die Funktion 9 zurück, weil die Suche beim siebten Zeichen des abzusuchenden Textes beginnt.	9
=FINDEN(D1; D2; D3), wobei die Zellen D1, D2 und D3 "Rook", "Knight" und die Zahl 1 enthalten.	Hier gibt die Funktion den Fehler #WERT! zurück, weil kein Treffer gefunden wurde.	#WERT!

Ähnliche LibreOffice Funktionen:

IDENTISCH

FINDENB

SUCHEN

ODF Standard:

Kapitel 6.20.9, Teil 2.

Betroffene (oder ähnliche) EXCEL-Funktionen:

FIND