Documentatie/Calc-functies/VINDEN

From The Document Foundation Wiki
Jump to navigation Jump to search
This page is a translated version of the page Documentation/Calc Functions/FIND and the translation is 100% complete.
Other languages:
English • ‎Nederlands



Functienaam:

VINDEN

Categorie:

Tekst

Samenvatting:

Gebruikt een hoofdlettergevoelige overeenkomst om de positie van een tekstreeks binnen een andere tekstreeks te vinden.

Syntaxis:

VINDEN(Tekst zoeken; Tekst[; Positie])

Retourneert:

Retourneert een positief geheel getal dat de positie is van het eerste teken van het eerste voorkomen van de tekenreeks die moet worden gevonden, binnen de tekenreeks die moet worden doorzocht. De geretourneerde waarde mag niet groter zijn dan de lengte van de tekenreeks die moet worden doorzocht.

Argumenten:

Tekst zoeken is een tekenreeks (tussen aanhalingstekens), een getal of een verwijzing naar een cel die één van die typen bevat, dat wil zeggen de tekenreeks die moet worden gevonden.

Tekst is een tekenreeks (tussen aanhalingstekens), een getal of een verwijzing naar een cel die één van die typen bevat, dat wil zeggen de tekenreeks die moet worden doorzocht.

Positie is een positief geheel getal of een verwijzing naar een cel die een positief geheel getal bevat, dat wil zeggen de tekenpositie van waaruit het zoeken begint. Als Positie wordt weggelaten, gebruikt VINDEN de waarde 1.

  • Als Positie een niet-gehele waarde is, kapt VINDEN deze af tot een geheel getal.
  • Na afkapping, als Positie kleiner is dan 1 of groter is dan de lengte van de te doorzoeken string, dan retourneer VINDEN als fout #WAARDE!.
  • Als er geen overeenkomst wordt gevonden, meldt VINDEN als fout #WAARDE!. Dit is een foutconditie die moet worden afgehandeld als deze wordt gebruikt als argument voor een andere functie.

Aanvullende details:

VINDEN ondersteunt geen jokertekens of reguliere expressies. Gebruik de functie ZOEKEN als u zoekopdrachten met jokertekens of reguliere expressies nodig hebt, of als u zoekopdrachten nodig hebt die niet hoofdlettergevoelig zijn.

In Extra ▸ Opties ▸ LibreOffice Calc ▸ Berekenen (of LibreOffice ▸ Voorkeuren ▸ LibreOffice Calc ▸ Berekenen op macOS), heeft de instelling voor Zoekcriteria = en <> moeten op hele cellen toepasbaar zijn geen effect op het gedrag van VINDEN.

Suggesties voor het omgaan met de fout #WAARDE! die wordt geretourneerd wanneer er geen overeenkomst wordt gevonden, zijn onder meer:

  • =ALS(ISFT(VINDEN("xyz"; "abcdef"; 1)); "FOUT: Ontbrekende subtekenreeks"; "Subtekenreeks aanwezig") geeft als resultaat "FOUT: Ontbrekende subtekenreeks" en geeft niet de fout van de functie VINDEN.
  • =ALS(ISGETAL(VINDEN("xyz"; "abcdef"; 1)); "Substring aanwezig"; "FOUT: Ontbrekende Substring") geeft als resultaat "FOUT: Ontbrekende Substring" en wordt niet doorgegeven als fout van de functie VINDEN.

Voorbeelden:

Formule Beschrijving Retourneert
=VINDEN("fifty"; "Fifty-fifty") Hier retourneert de functie 7 omdat de overeenkomst hoofdlettergevoelig is. 7
=VINDEN(76; 998877667654) Hier retourneert de functie 6 omdat het zoeken standaard begint bij het eerste teken van de string die moet worden doorzocht. 6
=VINDEN(76; 998877667654; 7) Hier retourneert de functie 9 omdat het matchen begint bij het zevende teken van de string die moet worden doorzocht. 9
=VINDEN(D1; D2; D3) waarbij cel D1, D2 en D3 respectievelijk "Rook", "Ridder" en het cijfer 1 bevatten. Hier retourneert de functie de #WAARDE! fout omdat er geen overeenkomst is. #WAARDE!

Gerelateerde LibreOffice-functies:

GELIJK

VINDENB

ZOEKEN

ODF standaard:

Section 6.20.9, part 2

Gelijkwaardige Excel-functies:

VIND.ALLES