Documentatie/Calc-functies/HYPERLINK

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/HYPERLINK and the translation is 100% complete.
    Other languages:


    Functienaam:

    HYPERLINK

    Categorie:

    Werkblad

    Samenvatting:

    Maakt een klikbare teksthyperlink in de formulecel. Wanneer op de hyperlink wordt geklikt, opent Calc de gespecificeerde bron (vaak in een andere toepassing) of gaat naar de gespecificeerde locatie in het huidige werkblad.

    Standaard geeft de formulecel het koppelingsdoel weer als een tekenreeks, maar indien nodig kan een gebruiksvriendelijkere tekenreeks worden weergegeven.

    Syntaxis:

    HYPERLINK(URL[; Celtekst])

    Retourneert:

    Retourneert een tekenreeks, die ofwel het linkdoel (wanneer slechts één argument wordt opgegeven) of de alternatieve celtekst (wanneer een tweede argument wordt opgegeven) vertegenwoordigt.

    Argumenten:

    URL is een tekenreeks (tussen aanhalingstekens) of een verwijzing naar een cel die een tekenreeks bevat, die het doel van de koppeling specificeert.

    Celtekst is een tekenreeks (tussen aanhalingstekens) of een getal of een verwijzing naar een cel die een van die typen bevat, die alternatieve tekst specificeert die moet worden weergegeven in de formulecel in plaats van het doel van de koppeling.

    Aanvullende details:

    • De actie die nodig is om een zo'n hyperlink te openen, hangt af van de huidige instelling van de optie Extra ▸ Opties ▸ LibreOffice ▸ Beveiliging ▸ Beveiligingsopties en waarschuwingen ▸ Opties ▸ Ctrl-klik vereist om hyperlinks te openen (LibreOffice ▸ Voorkeuren ▸ LibreOffice ▸ Beveiliging ▸ Beveiligingsopties en waarschuwingen ▸ Opties ▸ Ctrl-klik vereist om hyperlinks te openen op macOS). Als de optie is aangevinkt, gebruik dan Ctrl+klik met de muisaanwijzer op de hyperlink; als de optie niet is aangevinkt, gebruik dan de linkermuisknop met de muisaanwijzer op de hyperlink.
    • Als u een cel met hyperlink wilt bewerken, maar merkt dat door erop te klikken de hyperlink direct wordt geopend, selecteert u een cel in de buurt en navigeert u met de pijltoetsen op het toetsenbord naar de cel met de hyperlink.
    • Als een cel een functie HYPERLINK aanroep bevat (zelfs als die functie niet wordt geëvalueerd), wordt die cel een cel met een hyperlink; dat wil zeggen, als u erop klikt, zal het proberen de doelkoppeling te openen. Dit betekent bijvoorbeeld in een cel die de formule bevat:
    =ALS(WAAR(); "sommige tekst"; HYPERLINK("https://www.example.com"))
    de functie wordt nooit geëvalueerd. Niettemin wordt de cel in eerste instantie een cel met een hyperlink. Wanneer echter op de formulecel wordt geklikt, mislukt de koppeling.

    Voorbeelden:

    Formule Beschrijving
    =HYPERLINK("https://www.example.org") Hier toont de functie de tekst "https://nl.libreoffice.org/" in de formulecel en opent https://nl.libreoffice.org/ wanneer erop wordt geklikt.
    =HYPERLINK("https://www.example.org"; "Click here") Hier toont de functie de tekst "Klik hier" in de formulecel en opent https://nl.libreoffice.org/ wanneer erop wordt geklikt.
    =HYPERLINK("https://www.example.org"; 12345) Hier toont de functie het getal 12345 in de formulecel en opent https://nl.libreoffice.org/ wanneer erop wordt geklikt.
    =HYPERLINK(B4) waarbij cel B4 de tekenreeks "https://nl.libreoffice.org/" bevat (ingevoerd zonder aanhalingstekens). Hier toont de functie de tekst "https://nl.libreoffice.org/" in de formulecel en opent https://nl.libreoffice.org/ wanneer erop wordt geklikt.
    =HYPERLINK("https://nl."; "Klik") & " libreoffice.org/" Hier toont de functie de tekst "Klik libreoffice.org" in de formulecel en opent https://nl.libreoffice.org/ wanneer erop wordt geklikt.
    =HYPERLINK("#Blad1.A1"; "Ga naar boven") Hier toont de functie de tekst "Ga naar boven" in de formulecel en springt naar cel Blad1.A1 in het huidige document wanneer erop wordt geklikt.
    =HYPERLINK("file:///C:/miscellaneous/writer.odt#Specification"; "Ga naar bladwijzer Writer") Hier toont de functie de tekst "Ga naar Writer-bladwijzer" in de formulecel en opent, wanneer erop wordt geklikt, het gespecificeerde tekstdocument op de locatie van de bladwijzer "Specificatie".
    =HYPERLINK("file:///C:/spreadsheets/"; "Open spreadsheets folder") Hier toont de functie de tekst "Map werkbladen openen" in de formulecel en toont, wanneer erop wordt geklikt, de inhoud van de map C:/werkbladen/ in een bestandsbeheervenster.

    Gerelateerde LibreOffice-functies:

    Geen.

    ODF standaard:

    Section 6.11.3, part 2

    Gerelateerde (of gelijkwaardige) Excel-functies:

    HYPERLINK