Documentation/Calc Functions/MODE.MULT

    From The Document Foundation Wiki
    This page contains changes which are not marked for translation.

    Function name:

    MODE.MULT

    Category:

    Statistical Analysis

    Summary:

    Finds the mode(s) of an unsorted set of numbers containing at least one duplicate value. The mode is the most frequently occurring number in the set.

    MODE.MULT is an array function and if there are multiple mode values with the same frequency of occurrence they are returned in a vertical array.

    Syntax:

    MODE.MULT(Number 1[; Number 2[; ...[; Number 255]]])

    Returns:

    Returns a vertical array of real numbers, which are the modes of the supplied set of numbers. The number of cells occupied by this vertical array is as follows:

    • If the formula containing the call to MODE.MULT is entered without selecting any cells, then MODE.MULT will return as many values as there are modes.
    • If the formula is entered after having selected a vertical block of cells, then MODE.MULT populates all cells in the selected block. If there are less modes than selected cells, then the extra cells are populated with the value not available error (#N/A). If there are more modes than selected cells, then only a subset of the modes are displayed.

    Arguments:

    Number 1, Number 2, … , Number 255 give the set of real numbers from which the mode is to be calculated. Each argument may be a value or an expression, a reference to a single cell, a reference to a cell range, the name of a named or database range, or an inline array.

    Note that although MODE.MULT can accept up to 255 arguments, each argument could specify a range of cells. This means that many more than 255 real numbers could be processed.

    The following conditions (including errors) may be encountered:

    • If any argument is a string in quotation marks, then MODE.MULT reports a parameter list error (Err:504).
    • Text in cells and empty cells are ignored.
    • If the list of supplied numbers includes no duplicate values, then MODE.MULT reports a #VALUE! error.

    Additional details:

    • The name space for MODE.MULT is COM.MICROSOFT.MODE.MULT.
    • For more information on the mode value, visit Wikipedia's Mode (statistics) page.

    Examples:

    The following table shows sample spreadsheet data that is used in the first two examples of the subsequent table.

    A B
    1 1 2
    2 2 1
    3 3 2
    4 4 5
    5 3 3
    Formula Description Returns
    =MODE.MULT(A1:B5) where the cells A1:B5 contain the data shown in the table above and the formula is entered into cell A7 without preselecting any cells. Here the function finds two modes. Cell A7 contains 2
    Cell A8 contains 3
    =MODE.MULT(A1:B5) where the cells A1:B5 contain the data shown in the table above and the formula is entered into cell A7 after preselecting cells A7:A10. Here the function finds the same two mode values but populates four cells. Cell A7 contains 2
    Cell A8 contains 3
    Cell A9 contains #N/A
    Cell A10 contains #N/A
    =MODE.MULT(A1:A10) where cells A1:A10 contain the values 1, 2, 3, 2, 4, 1, 3, 5, 6, and 3 respectively and no block of cells is selected when the formula is entered. Here the function returns the most common value within the supplied range. 3
    =MODE.MULT(3; 2; 1; 2; 4; 1; 3) where no block of cells is selected when the formula is entered. Here there are three values that occur twice and MODE.MULT returns those values in vertically adjacent cells. 3
    2
    1
    =MODE.MULT({-0.6; 0.5; 0.1; -0.2; -0.2; 0.3; 0.5; -0.2; 0.7}) where no block of cells is selected when the formula is entered. Here nine values are passed as an inline array and there is only one mode value. -0.2

    Related LibreOffice functions:

    AVERAGE

    MEDIAN

    MODE

    MODE.SNGL

    ODF standard:

    None

    Related (or similar) Excel functions:

    MODE.MULT since v.2010.