Dokumentation/Calc Funktionen/NETTOARBEITSTAGE.INTL
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende
Funktionsname:
NETTOARBEITSTAGE.INTL
Kategorie:
Datum und Zeit
Zusammenfassung:
Berechnet die Netto Anzahl an Werk- oder Arbeitstagen zwischen zwei Tagen. Feiertage (oder andere arbeitsfreie Tage) können angegeben werden und die Standard Arbeitswoche kann abgeändert werden.
Syntax:
NETTOARBEITSTAGE.INTL(Startdatum; Enddatum[; [Wochenende][Feiertage]])
Rückgabewerte:
Gibt die Anzahl an Werk- oder Arbeitstagen in der angegebenen Zeitspanne als Ganzzahl an, exklusive der definierten Feiertage und Wochenendtage. Das Start- und das Enddatum werden mitgezählt, es sei denn sie sind als Feiertage oder Wochenende definiert.
Argumente:
Startdatum ist das Datum (in Anführungszeichen) oder der Zeitstempel, ggf. aus einer Referenz auf eine Zelle, die als Start- oder Enddatum der Periode gilt, die berechnet werden soll.
Enddatum ist das Datum (in Anführungszeichen) oder der Zeitstempel, ggf. aus einer Referenz auf eine Zelle, die als Enddatum der Periode gilt, die berechnet werden soll.
Wochenende ist eine Zahl oder ein Text oder eine Referenz auf eine Zelle, die eine dieser Typen enthält. Dadurch definiert sich die genutzte Standard Arbeitswoche. Die möglichen numerischen Optionen zeigen einen einfachen Weg, die Arbeitswoche anzugeben. Die folgende Tabelle zeigt die möglichen Werte. Werte 1 bis 7 betreffen eine Woche mit zwei arbeitsfreien Tagen, die Werte 11 bis 17 betreffen eine Woche mit einem arbeitsfreien Tag.
| Zahl | arbeitsfreie Tage |
|---|---|
| 1 oder weggelassen | Samstag und Sonntag |
| 2 | Sonntag und Montag |
| 3 | Montag und Dienstag |
| 4 | Dienstag und Mittwoch |
| 5 | Mittwoch und Donnerstag |
| 6 | Donnerstag und Freitag |
| 7 | Freitag und Samstag |
| 11 | nur Sonntag |
| 12 | nur Montag |
| 13 | nur Dienstag |
| 14 | nur Mittwoch |
| 15 | nur Donnerstag |
| 16 | nur Freitag |
| 17 | nur Samstag |
Ein Text ist eine flexiblere Methode, um eine Arbeitswoche zu definieren. Der Text umfasst sieben Stellen. - '0' zeigt einen Arbeitstag und '1' zeigt einen arbeitsfreien Tag an. Jede Stelle bezeichnet einen Tag der Woche, begonnen mit dem Montag. Zum Beispiel definiert "0100011" den Dienstag, Samstag und Sonntag als arbeitsfreie Tage.
Feiertage ist eine Liste von Feiertagen (oder alle anderen Tage), die nicht als Arbeitstage gelten. Diese Liste kann als Zellbereich mit Zeitstempeln (vielleicht im Datumsformat) übergeben werden. Alternativ kann die Liste als Aufzählung entweder als Daten (in Anführungszeichen) oder als Zeitstempel mitgegeben werden. Falls die Liste fehlt, werden keine Feiertage berücksichtigt.
- Falls Startdatum oder Enddatum kein gültiges Datum ist, meldet NETTOARBEITSTAGE einen #WERT! Fehler.
- Falls das Startdatum vor dem Enddatum liegt, ist das Ergebnis eine positive Zahl: falls das Startdatum nach dem Enddatum liegt, ist das Ergebnis eine negative Zahl.
- NETTOARBEITSTAGE.INTL ignoriert jede Zeitkomponente des Startdatums und des Enddatums.
- Falls eine Zeichenkette für das Wochenende angegeben ist, und die Zeichenkette nicht exakt sieben Zeichen hat, meldet NETTOARBEITSTAGE.INTL einen #WERT! Fehler. Falls die Zeichenkette sieben Zeichen hat, aber mindestens eines dieses Zeichen weder '0' noch '1' ist, meldet NETTOARBEITSTAGE.INTL einen invalid argument error (Fehler:502).
- Falls eine Zahl für das Wochenende angegeben ist, und die Zahl keine Ganzzahl ist, meldet NETTOARBEITSTAGE.INTL einen invalid argument error (Fehler:502). Falls die Zahl eine Ganzzahl ist, aber weder zwischen 1 und 7 noch zwischen 11 und 17 liegt, meldet NETTOARBEITSTAGE.INTL einen #WERT! Fehler.
- Falls das Wochenende als eine Referenz auf eine Zelle angegeben ist, und diese Zelle eine Fehlermeldung (so wie #NAME?) enthält, wird diese Fehlermeldung auch von NETTOARBEITSTAGE.INTL als Ergebnis zurückgegeben.
- Falls Feiertage als Aufzählung mitgegeben wird, tritt ein #WERT! Fehler auf, wenn einer der Einträge der Aufzählung kein Datum und kein Zeitstempel ist.
- Falls Feiertage als Zellbereich mitgegeben wird, dann werden in den meisten Fällen Zellen, die kein Datum oder Zeitstempel im relevanten Zeitraum enthalten, ignoriert. Wenn eine Zelle trotzdem einen Fehlercode (wie z. Bsp. #NAME?) enthält, dann wird dieser Fehler als Ergebnis von NETTOARBEITSTAGE.INTL zurückgegeben.
Zusätzliche Informationen:
Spezifische Eigenheiten der Funktion NETTOARBEITSTAGE.INTL
NETTOARBEITSTAGE.INTL zählt den ersten und den letzten Tag der Periode mit (siehe #Beispiele: weiter unten).
Allgemeine Informationen über die Datums- und Zeit-Funktionen in Calc
 |
Anmerkung:
|
- Intern wird Datum/Zeit als Dezimalzahl verarbeitet. Das kommt ab und zu als Zeitstempel zum Ausdruck. Zum Beispiel entspricht der 08.02.2021, 12:00:00 dem Zeitstempel 44235,5. Der ganzzahlige Anteil des Zeitstempels (vor dem Dezimalpunkt) ist die Anzahl der Tage seit einem vordefinierten Startdatum. Der gebrochene Teil des Zeitstempels (nach dem Dezimalpunkt) ist die Tageszeit ausgedrückt als Teil des Tages. Zum Beispiel stellt 0,25 die Uhrzeit 06:00:00 und 0,75 die Uhrzeit 18:00:00 dar.
- Calc nutzt den 30.12.1899 als Standard Startdatum (Tag 0). Unter ▸ ▸ ▸ kann allerdings ein alternatives Startdatum eingestellt werden. Solange Sie aber keine speziellen Anforderungen an die Tabellenanwendungen haben, empfehlen wir keine Änderungen an dieser Einstellung vorzunehmen. Falls Sie Zellen mit Datums-Werten kopieren und in andere Tabellen einfügen, kontrollieren Sie, dass beide Dokumente das gleiche Startdatum verwenden, um unerwartete Änderungen an den Datumsanzeigen zu vermeiden.
- Ein negativer Zeitstempel entspricht einem Datum vor dem Calc Startdatum. Calc berechnet alle Daten zurück bis zum 15.10.1582 unter Verwendung des Gregorianischen Kalenders für frühere Daten.
- Ein Zeitstempel ist das selbe wie jede andere Zahl, außer wir entscheiden uns dazu, sie als Datum/Zeit darzustellen. Sie können eine Zahl in eine Zelle eingeben und dann die Formatierung der Zelle ein Datum/eine Zeit darstellen lassen. Sie können in eine Zelle auch ein Datum/eine Zeit eingeben und dann die Formatierung der Zelle auf einen Zeitstempel ändern.
- Zur Klarstellung: die Beschreibungen der Calc Funktionen in dieser Wiki nutzen das Standard ISO 8601 Format für Datum und Zeit da dieses unabhängig von Ihren lokalen Einstellungen sein sollte. Der Standard Wert auf Ihrem Computer mag unterschiedlich dazu sein. Wenn Sie ein Datum als Teil einer Formel eingeben, können Schräg- oder Bindestriche als Trennzeichen im Datum als mathematische Operatoren gedeutet werden. Daher wird ein Datum in diesem Format nicht als Datum erkannt und führt zu fehlerhaften Berechnungen. Um ein Datum als Datum erkannt zu bekommen, nutzen Sie bitte die DATUM-Funktion oder platzieren Sie das Datum in Anführungsstrichen in der ISO 8601-Notation. Vermeiden Sie lokale Datums-Formate, die Fehler erzeugen können, falls das Dokument in einer anderen Lokalisierung geladen wird.
- Zeit-Zonen Information wird in den Datum & Zeit Funktionen von Calc nicht verwendet.
- Falls Sie zwei Ziffern in der Jahresangabe (zum Beispiel 21 statt 2021) angeben wollen, muss Calc wissen, ob Sie 1921 oder 2021 meinen. Gehen Sie zu ▸ ▸ ▸ , um sich den Jahrebereich, wie Calc zweistellige Jahresangeben interpretieren soll, anzeigen zu lassen bzw. zu ändern.
- Calc nutzt Logik um zu entscheiden, wie Text behandelt werden soll, der als Operand in einer arithmetrischen Operation oder als Argument einer Funktion angegeben wird und stattdessen eine Zahl erwartet wird. In diesem Kontext ist unzweifelhafte Übertragung für ISO 8601 Daten und Zeiten in ihren erweiterten Formaten mit Trennzeichen möglich. Zum Beispiel gibt die einfache Formel
=1 + "2021-02-08"das Ergebnis2021-02-09(sofern als Datum formatiert). Trotzdem kann diese Logik durch die Einstellung auf dem Dialog Detaillierte Einstellungen für Berechnungen beeinträchtigt werden. Dieser Dialog findet sich unter ▸ ▸ ▸ hinter dem Button Details im Bereich Detaillierte Einstellungen für Berechnungen. Falls ein #WERT!-Fehler auftritt, kann das daran liegen, dass Fehler #WERT! berechnen ausgewählt wurde. In dem Fall sollte man mit den anderen selbsterklärenden Optionen im Drop-Down-Feld Konvertierung von Text in eine Zahl experimentieren.
Beispiele:
| A | B | C | D | E | F | G | H | |
|---|---|---|---|---|---|---|---|---|
| 1 | Start / Enddatum | Feiertage | Wochenende | |||||
| 2 | 2020-01-01 | Formatiert als Text, ohne doppelte Anführungszeichen | 0000011 | |||||
| 3 | 2020-12-31 | 2020-01-01 | ||||||
| 4 | 2020-04-10 | Formatiert als allgemeine Zahl | 11 | |||||
| 5 | 2020-04-13 | |||||||
| 6 | 2020-05-08 | |||||||
| 7 | 2020-05-25 | |||||||
| 8 | 2020-08-31 | |||||||
| 9 | 2020-12-25 | |||||||
| 10 | 2020-12-28 |
| Formel | Beschreibung | Ergebnis |
|---|---|---|
| =NETTOARBEITSTAGE.INTL("2021-02-18"; "2021-02-19") | Gibt 2 Arbeitstage zurück, basierend auf dem Start- und Enddatum, keinen Feiertagen und der Standard-Fünf-Tage-Woche. Dieses einfache Beispiel zeigt die inklusive Natur der Zählweise. | 2 |
| =NETTOARBEITSTAGE.INTL("2020-12-31"; "2020-01-01") | Werktage im Jahr 2020. Der negative Wert zeigt, dass das Startdatum nach dem Enddatum liegt. | −262 |
| =NETTOARBEITSTAGE.INTL("2020-01-01"; "2020-12-31"; 5) | Eine Fünf-Tage-Woche (mit Mittwoch und Donnerstag als arbeisfreien Tagen). | 260 |
| =NETTOARBEITSTAGE.INTL("2020-01-01"; "2020-12-31";; {"2020-01-01"; "2020-04-10"; "2020-04-13"; "2020-05-08"; "2020-05-25"; "2020-08-31"; "2020-12-25"; "2020-12-28"}) | Acht angegebene Feiertage und die Standard-Fünf-Tage-Arbeitswoche. Ein extra Separator ist eingefügt, der anzeigt, dass das Wochenende fehlt. | 254 |
| =NETTOARBEITSTAGE.INTL(B2; B3; H2; E3:E10) | Äquivalent zum vorigen, unter Verwendung der obigen Datentabelle; Zelle H2 enthält die Zahl 0000011, formatiert als Text ohne doppelte Anführungszeichen. |
254 |
| =NETTOARBEITSTAGE.INTL(B2; B3; H4; E3:E10) | Ähnlich dem obigen Beispiel, nur dass das Wochenende nur aus dem Sonntag besteht; Zelle H4 enthält den numerischen Wert 11. |
306 |
| =NETTOARBEITSTAGE.INTL("2020-01-01"; "2020-12-31"; "0000111") | Eine Vier-Tage-Arbeitswoche (Montag bis Donnerstag). | 210 |
| =NETTOARBEITSTAGE.INTL(43831; 43861; "1000111"; { 43845; 43852 }) | 43831, 43861, 43845 und 43852 sind die Zeitstempel für die Tage 01.01.2020, 31.01.2020, 15.01.2020 und 22.01.2020. Zwei Feiertage innerhalb der Periode und einer Drei-Tage-Woche (Dienstag, Mittwoch und Donnerstag). | 12 |
Ähnliche LibreOffice Funktionen:
ODF Standard:
Nichts.
Betroffene (oder ähnliche) EXCEL-Funktionen:
NETWORKDAYS.INTL since v.2010.