Dokumentation/Calc Funktionen/ERSETZEN

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/REPLACE and the translation is 100% complete.
    Other languages:


    Funktionsname:

    ERSETZEN

    Kategorie:

    Text

    Zusammenfassung:

    Ersetzt Zeichen in einem Text durch Zeichen aus einem anderen Text.

    Syntax:

    ERSETZEN(Text; Position; Länge; Neuer Text)

    Rückgabewerte:

    Gibt den Text zurück, in dem aus dem Originaltext die angegebenen Zeichen durch die angegebenen Zeichen im neuen Text ersetzt wurden.

    Argumente:

    Text ist ein Text (in Anführungszeichen), eine Zahl oder eine Referenz auf eine Zelle mit einem dieser Typen. Das ist dann der Originaltext mit den zu ersetzenden Zeichen.

    Position ist eine positive Ganzzahl oder eine Referenz auf eine Zelle mit dieser Ganzzahl. Diese Ganzzahl ist die Position des ersten Zeichens im Originaltext, das ersetzt werden soll.

    Länge ist eine nicht-negative Ganzzahl oder eine Referenz auf eine Zelle mit dieser Ganzzahl. Dies ist die Anzahl der zu ersetzenden Zeichen.

    Neuer Text ist ein Text (in Anführungszeichen), eine Zahl oder eine Referenz auf eine Zelle mit einem dieser Typen. Das ist der neue Text mit den Ersatzzeichen. Es ist nicht nötig, dass der Neue Text die gleiche Länge hat wie in Länge angegeben. Der Neue Text wird am Besten auf einen leeren Text gesetzt, um den Text zu löschen, anstatt einzelne Zeichen im Text zu ersetzen.

    • Falls entweder die Position oder die Länge nicht numerisch ist, dann meldet ERSETZEN einen #WERT! Fehler.
    • Falls entweder die Position oder die Länge keine Ganzzahl ist, verkürzt sie ERSETZEN auf eine Ganzzahl.
    • Falls die Position kleiner als 1 ist oder die Länge kleiner als 0 ist, dann meldet ERSETZEN einen invalid argument error (Fehler:502).
    • Falls die Länge 0 ist, werden keine Zeichen ersetzt. Trotzdem werden die Zeichen aus dem Neuen Text vor dem Zeichen eingesetzt, das ursprünglich an der angegebenen Position steht.
    • Falls die Position größer als die Länge des Textes ist, werden die Zeichen des Neuen Textes an den Originaltext angehängt.
    • Falls die Position + die Länge größer als die Länge des Textes ist, ersetzt ERSETZEN alle Zeichen ab der Position bis zum Ende des Textes.

    Zusätzliche Informationen:

    Die Formel:

    =ERSETZEN(Text; Position; Länge; Neuer Text)

    ist äquivalent zu :

    =LINKS(Text; Position-1) & Neuer Text & TEIL(Text; Position+Länge; LÄNGE(Text))

    Der Text und der Neue Text können als Zahlen angegeben werden, aber ERSETZEN gibt immer Text zurück. Falls weitere Berechnungen mit einer Zahl, die in einen Text ungewandelt wurde, durchgeführt werden sollen, muss der Text in eine Zahl zurückgewandelt werden (z. Bsp. entweder mit der Funktion WERT oder der Funktion ZAHLWERT).

    Beispiele:

    Formel Beschreibung Ergebnis
    =ERSETZEN("mouse"; 2; 3; "ic") Hier entfernt die Funktion drei Buchstaben ab dem Buchstaben auf Position 2 ("ous") und ersetzt sie durch zwei Buchstaben ("ic") und gibt "mice" zurück. mice
    =ERSETZEN(D1; D2; D3; D4), wobei die Zelle D1 den Text "mouse" enthält, Zelle D2 enthält die Zahl 2, Zelle D3 die Zahl 3 und Zelle D4 den Text "ic". Hier entfernt die Funktion wieder drei Buchstaben, beginnend mit dem Buchstaben auf Position 2 ("ous") und ersetzt sie mit zwei Buchstaben ("ic") und gibt den Text "mice" zurück. mice
    =ERSETZEN("1234567"; 1; 1; "444") Hier entfernt die Funktion einen Buchstaben an der Position 1 ("1"), ersetzt sie durch drei Buchstaben ("444") und gibt "444234567" zurück. 444234567
    =ERSETZEN(1.234.567; 1; 1; 444) In diesem Beispiel werden der Originaltext und der neue Text als Zahlen ohne Anführungszeichen angegeben. Hier entfernt die Funktion wieder ein Zeichen an der Position 1 ("1"), ersetzt sie durch drei Zeichen ("444") und gibt den Text "444234567" zurück. 444234567
    =ERSETZEN("Input string"; 7; 0; "text ") Hier entfernt die Funktion keine Zeichen, aber fügt fünf Zeichen ("text ") sofort nach Zeichen Nummer 7 ("s") ein und gibt den Text "Input text string" zurück. Input text string
    =ERSETZEN("LibreOffice"; 120; 3; " Calc") Hier ist der Wert der Position eine beliebige Zahl größer als die Länge des Textes, so dass der fünf-stellige Text " Calc" an das Ende des Originaltextes angehängt wird. In diesem Beispiel wird die Länge ignoriert (obwohl sie trotzdem eine nicht-negative Zahl sein muss). LibreOffice Calc
    =ERSETZEN("Hallo xxxx!"; 6; 5; "") Hier entfernt die Funktion fünf Zeichen ab Position 6 (" xxxx") und ersetzt sie durch einen leeren Text (also löscht sie) und gibt den Text "Hallo!" zurück. Hallo!

    Ähnliche LibreOffice Funktionen:

    ERSETZENB

    WECHSELN

    ODF Standard:

    Kapitel 6.20.17, Teil 2.

    Betroffene (oder ähnliche) EXCEL-Funktionen:

    REPLACE