Dokumentation/Calc Funktionen/SUMMEWENN
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende
Funktionsname:
SUMMEWENN
Kategorie:
Mathematisch
Zusammenfassung:
In seiner einfachsten Form bestimmt SUMMEWENN, welche Zelle in einem Bereich ein bestimmtes Kriterium erfüllt, und bildet die Summe aus den Zahlen aus diesen Zellen. In seiner zweiten Form bestimmt SUMMEWENN, welche Zelle in einem Bereich ein bestimmtes Kriterium erfüllt, und bildet die Summe aus den Zellen eines korrespondierenden Bereiches.
Das Kriterium in SUMMEWENN kann Platzhalter oder reguläre Ausdrücke nutzen.
Syntax:
SUMMEWENN(Bereich; Kriterium[; Summenbereich])
Rückgabewerte:
Gibt das Ergebnis der Addition aus den angegebenen Zahlen als Dezimalzahl zurück.
Argumente:
Bereichsargument
Bereich gibt die Zellen zum Abgleich und, wenn Summenbereich fehlt, die Zellen zum Aufaddieren an. Bereich hat üblicherweise eine der folgenden Formen:
- Eine Referenz auf einen Zellbereich (z.Bsp. A1:A25). Falls Summenbereich fehlt, dann kann Bereich auch den Bereichsverknüpfer (~) enthalten.
- Der Name eines benannten Bereiches.
- Der Name eines Datenbankbereiches.
Kriterium
Kriterium ist das Kriterium für die Auswahl, oder eine Zelle die das Kriterium enthält. Kriterium kann eine der folgenden Formen annehmen:
- Eine Zahl, wie z. Bsp. 34,5. Daten und logische Ausdrücke (WAHR oder FALSCH) werden wie Zahlen behandelt.
- Ein Ausdruck, wie 2/3, WURZEL($D$1) oder DATUM(2021; 11; 1).
- Ein Text wie "Golf" oder "<>10".
SUMMEWENN sucht nach Zellen im Bereich, die dem Kriterium entsprechen, es sei denn Kriterium ist ein Textfeld, das mit einem Vergleichsoperator (>, <, >=, <=, =, or <>) startet. In letzterem Fall vergleicht SUMMEWENN die Zellen im Bereich mit dem Rest aus dem Text (wenn möglich interpretiert als Zahl, ansonsten als Text). Die Bedingung "> 4,5" testet, ob der Inhalt der Zelle größer als die Zahl 4,5 ist. Die Bedingung "< Hund" testet, ob jede Zelle alphabetisch vor dem Text Hund kommt. Und die Bedingung "<> 01.11.2021" testet, ob der Inhalt der Zelle nicht gleich dem angegebenen Datum ist.
Kriterium unterstüzt folgende Verhaltensweisen:
- Der Text "=" entspricht einem leeren Feld. Die Formel
=SUMMEWENN(B1:B10; "="; A1:A10)gibt z. Bsp. die Summe aller Werte im Bereich A1:A10 zurück, falls alle Zellen im Bereich B1:B10 leer sind. Der Text "= 0" entspricht nicht leeren Zellen. - Der Text "<>"entspricht nicht-leeren Zellen. Die Formel
=SUMMEWENN(C1:C10; "<>"; A1:A10)gibt z. Bsp. die Summe aller Werte im Bereich A1:A10 zurück, falls alle Zellen im Bereich C1:C10 nicht leer sind. - Falls der Wert hinter dem Operator "<>" nicht leer ist, dann entspricht Kriterium jedem Zellinhalt ausser dem Wert im Kriterium, inklusive leerer Zellen.
Summenbereich
Summenbereich spezifiziert die aufzusummierenden Zellen und hat eine der Formen aus dem Abschnitt Bereich. Bereichssumme sollte normalerweise die selbe Ausdehnung wie Bereich haben - falls dies nicht der Fall ist, wird SUMMEWENN einen Bereich auswählen der mit der ersten Zelle im Summenbereich beginnt und die gleiche Ausdehnung wie der Bereich hat.
Fehlerbedingungen
- Falls das Argument Summenbereich angegeben ist und mehrere Bereiche innerhalb des Bereiches verknüpft sind, dann meldet SUMMEWENN einen parameter list error (Fehler:504).
Zusätzliche Informationen:
Spezifische Eigenheiten der Funktion SUMMEWENN
- SUMMEWENN erlaubt nur ein zutreffendes Kriterium. Falls Sie Zellen aufgrund mehrerer Kriterien auswählen wollen, nutzen Sie die Funktion SUMMEWENNS.
- Die Standard-Treffer aus SUMMEWENN sind nicht case-sensitiv. Trotzdem kann ein case-sensitiver Treffer mittels eines regulären Ausdruckes ausgewählt werden, wobei ein Modifizierer "(?-i)" wie in einem der Beispiele unten demonstriert, verwendet wird.
- Das Verhalten von SUMMEWENN wird von mehreren Einstellungen aus dem Dialog ▸ ▸ ▸ ( ▸ ▸ ▸ on macOS) beeinflusst.
- Falls das Auswahlfeld für Suchkriterien = und <> müssen auf ganze Zellen zutreffen angeklickt ist, dann trifft das Kriterium "rot" nur auf "rot" zu; falls das Auswahlfeld nicht angeklickt ist, dann trifft "rot" auch auf "roter Hering" zu.
- Falls das Auswahlfeld für Platzhalter in Formeln ermöglichen angeklickt ist, wird die Bedingung Platzhalter verwenden - so wird z. Bsp. "b?g" für "bag", "beg", "big", "bog" und "bug" zutreffen.
- Falls das Auswahlfeld für Reguläre Ausdrücke in Formeln ermöglichen angeklickt ist, wird die Bedingung reguläre Ausdrücke verwenden - so wird z. Bsp. "r.d" für "red", "redraw" und "redden" zutreffen.
- Das Auswahlfeld für Groß- und Kleinschreibung hat auf die Funktion SUMMEWENN keine Auswirkung.
Allgemeine Informationen über die regulären Ausdrücke in Calc
 |
Anmerkung:
|
- Ein regulärer Ausdruck ist eine Zeichenkette die ein Textmuster beschreibt. Genauere allgemeine Hintergrundinformationen finden sich in der Wiki Regulärer Ausdruck
- Reguläre Ausdrücke sind weit verbreitet. Dabei gibt es viele Prozessoren für reguläre Ausdrücke. Calc nutzt den open source Regular Expressions package from the International Components for Unicode (ICU). Siehe bitte unter deren Dokumentation zu den regulären Ausdrücken für weitergehende Informationen inklusive der volständigen Beschreibung zur Syntax der ICU Regular Expressions.
- Zusätzlich stellt die LibreOffice Hilfe eine umfangreiche Liste der regulären Ausdrücke zur Verfügung.
- Calcs Generator für reguläre Ausdrücke unterstützt zahlreiche Erfassungs Möglichkeiten, welche es Untergruppen in einem Bereich erlauben innerhalb eines Treffers identifiziert zu werden und in einem Text ersetzt werden können. Runde Klammern werden genutzt um Komponenten eines regulären Ausdruckes zu gruppieren und eine nummerierte Treffer-Liste zu erzeugen. Um eine solche Treffer-Liste in einen Text einzufügen, verwenden Sie bitte das Kürzel "$n", wobei n die Zahl der Treffer-Liste ist.
Allgemeine Informationen über die Platzhalter in Calc
Platzhalter sind spezielle Zeichen für Suchtexte in Argumenten für einige Funktionen in Calc; sie können auch im Suchdialog verwendet werden. Der Gebrauch von Platzhaltern ermöglicht fortgeschrittenere Suchparamter bei einer einfachen Textsuche.
Calc unterstützt entweder Platzhalter oder reguläre Ausdrücke abhängig von den Einstellungen der aktuellen Applikation. Standardmäßig werden Platzhalter statt regulärer Ausdrücke unterstützt.
Um sicherzustellen, dass Platzhalter unterstützt werden, rufen Sie ▸ ▸ ▸ auf. Überprüfen Sie hier, ob die Einstellung Platzhalter in Formeln ermöglichen ausgewählt ist. Beachten Sie auch, dass reguläre Ausdrücke durch Auswählen von Reguläre Ausdrücke in Formeln ermöglichen unterstüzt werden können. Genauso können Sie weder Platzhalter noch reguläre Ausdrücke unterstützen lassen.
Die folgende Tabelle zeigt die Platzhalter, die Calc unterstützt.
| Platzhalter | Beschreibung |
|---|---|
| ? (Fragezeichen) | Vertritt ein einzelnes Zeichen. Zum Beispiel kann der Suchtext "b?g" "bag" oder "beg" heißen, aber nicht "boog" oder "mug". Beachte, dass es auch nicht "bg" heißen kann, da "?" genau ein Zeichen sein muss. Der Platzhalter "?" vertritt kein fehlendes Zeichen. |
| * (Asterisk) | Vertritt eine Reihe von Zeichen inklusive dem Leer-Text. Zum Beispiel vertritt der Text "*cast" "cast", "forecast" und "outcast", aber nicht "forecaster" unter Verwendung der Standardeinstellungen von Calc. Falls die Einstellung Suchkriterien = und <> müssen auf ganze Zellen zutreffen in ▸ ▸ ▸ ausgeblendet ist, dann wird "forecaster" auch durch *cast vertreten. |
| ~ (Tilde) | Unterdrückt die Sonderbehandlung des Fragezeichens Asterisken oder der Tilde, welche direkt nach der Tilde kommen. Zum Beispiel, stellt der Suchstring "why~?" nur "why?" und nicht "whys" oder "why~s" dar. |
Platzhalter sind nicht case sensitiv, also "A?" heißt sowohl "A1" also auch "a1".
Diese Platzhalter werden sowohl in Calc als auch in Microsoft EXCEL unterstützt. Wenn also Kompatibilität zwischen den beiden Anwendungen erforderlich ist, arbeiten Sie mit Platzhaltern anstatt mit regulären Ausdrücken. Wenn dagegen Kompatibilität nicht notwendig ist, arbeiten Sie stattdessen mit regulären Ausdrücken für mächtigere Möglichkeiten.
Beispiele:
Basis Beispiele
| Formel | Beschreibung | Ergebnis |
|---|---|---|
| =SUMMEWENN(A1:A9; "<0") wobei die Zellen A1 bis A9 die Zahlen -1, 2, -3, 4, -5, 6, -7, 8, and -9 enthalten. | Hier summiert die Funktion die negativen Zahlen im Zellbereich A1:A9 auf. | −25 |
| =SUMMEWENN(A1:A9; F1) wobei die Zellen A1 bis A9 die Zahlen -1, 2, -3, 4, -5, 6, -7, 8, and -9 und die Zelle F1 den Text ">=0" (eingegeben ohne die Anführungszeichen) enthalten. | Hier summiert die Funktion die nicht-negativen Zahlen im Zellbereich A1:A9 auf. | 20 |
| =SUMMEWENN(B2:B4; "<"&F2; C2:C4), wobei die Zellen B2 bis B4 die Zahlen 7, 9 und 11 enthalten. Die Zellen C2 bis C4 enthalten die Zahlen 4, 5 und 6. Die Zelle F2 enthält die Zahl 10. | Hier ermittelt die Funktion, ob die Zahl in den Zellen B2 und B3 kleiner als 10 sind und summiert somit die Zahlen in den Zellen C2 und C3 auf. | 9 |
| =SUMMEWENN(D1:D9; "Äpfel"; E1:E9) wobei die Zellen D1, D4, D5, D6 und D9 den Text "Äpfel" enthält, die Zellen D2, D3, D4, D7 und D8 enthält den Text "Birnen". Die Zellen E1 bis E9 enthalten die Zahlen 12, 19, 10, 27, 97, 73, 79, 71 und 40. Die Zahlen repräsentieren die Anzahl der korrespondierenden Früchte. | Hier summiert die Funktion die komplette Zahl an Äpfeln auf. | 249 |
andere Beispiele
Die Beispiele in diesem Kapitel basieren auf einer kleinen Datenbank für Verkaufszahlen von Sportausrüstung. Die Daten sind wie in folgender Tabelle angeordnet.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Datum | Verkaufssumme | Kategorie | Region | Vertreter |
| 2 | 2021-10-02 | $1,508 | Golf | Ost | Hans |
| 3 | 2021-10-02 | $410 | Tennis | Nord | Kurt |
| 4 | 2021-10-02 | $2,340 | Segeln | Süd | Ute |
| 5 | 2021-10-03 | $4,872 | Tennis | Ost | Brigitte |
| 6 | 2021-10-06 | $3,821 | Tennis | Süd | Fritz |
| 7 | 2021-10-06 | $2,623 | Tennis | Ost | Fritz |
| 8 | 2021-10-07 | $3,739 | Golf | Süd | Fritz |
| 9 | 2021-10-08 | $4,195 | Golf | West | Ute |
| 10 | 2021-10-10 | $2,023 | Golf | Ost | Hans |
| Formel | Beschreibung | Ergebnis |
|---|---|---|
| =SUMMEWENN(B2:B10; ">=4000") | Hier summiert die Funktioon die numerischen Einträge der Verkaufssumme, welche größer oder gleich $ 4.000,-- sind. | $9,067 |
| =SUMMEWENN(E2:E10; "ute"; B2:B10) | Hier lokalisiert die Funktion die Einträge für Ute in der Spalte Vertreter und summiert die korrespondierenden numerischen Einträge in der Spalte Verkaufssumme auf. | $6,535 |
| =SUMMEWENN(CategoryData; "Golf"; B2:B10) wobei der benannte Bereich Kategorie Daten über die Zellen C2:C10 erstellt wurde. | Hier lokalisiert die Funktion die Einträge für die Kategorie Golf und summiert die entsprechenden Summen in der Verkaufssumme auf. | $11,465 |
| =SUMMEWENN(D2:D10; F1; B2:B10) wobei Zelle F1 den Text ">=Süd" (ohne die Anführungszeichen eingegeben). | Hier lokalisiert die Funktion die Einträge für Süd und West in der Spalte Region und summiert die korrespondierenden numerischen Einträge in der Spalte Verkaufssumme auf. | $14,095 |
| =SUMMEWENN(A2:A10; DATUM(2021; 10; 2); B2:B10) | Hier lokalisiert die Funktion die Einträge für 02.10.2021 in der Spalte Datum und summiert die korrespondierenden numerischen Einträge in der Spalte Verkaufssumme auf. | $4,258 |
| =SUMMEWENN(A2:A10; ">="&DATUM(2021; 10; 7); B2:B10) | Hier lokalisiert die Funktion die Einträge am oder nach dem 07.10.2021 in der Spalte Datum und summiert die entsprechenden Summen in der Verkaufssumme auf. | $9,957 |
| =SUMMEWENN(D2:D10; "????"; B2:B10) | Dieses Beispiel arbeitet nur wie hier beschrieben, wenn Platzhalter möglich sind. Hier lokalisiert die Funktion die Vier Buchstaben Einträge in der Region (Nord und West) und summiert die entsprechenden Summen in der Verkaufssumme auf. | $15,221 |
| =SUMMEWENN(E2:E10; "^f.*"; B2:B10) | Dieses Beispiel arbeitet nur wie hier beschrieben, wenn reguläre Ausdrücke möglich sind. Hier lokalisiert die Funktion die Einträge der Verkäufer, die mit einem "f" oder "F" beginnen (Fritz) und summiert die entsprechenden Summen in der Verkaufssumme auf. | $10,183 |
| =SUMMEWENN(E2:E10; "(?-i)ute"; B2:B10) | Dieses Beispiel arbeitet nur wie hier beschrieben, wenn reguläre Ausdrücke möglich sind. Der Modifizierer "(?-i)" im regulären Ausdruck wechselt auf einen case-sensitiven Treffer und so werden keine Einträge im Verkäufer gefunden. Vergleichen Sie das mit dem zweiten Eintrag in dieser Tabelle. | $0 |
Ähnliche LibreOffice Funktionen:
ODF Standard:
Betroffene (oder ähnliche) EXCEL-Funktionen:
SUMIF