Documentazione/Funzioni di Calc/SOMMA.PIÙ.SE
TDF LibreOffice Document Liberation Project Blog comunitari Weblate Nextcloud Redmine Ask LibreOffice Donazione
Nome funzione:
SOMMA.PIÙ.SE
Categoria:
Matematica
Riepilogo:
Calcola la somma di un insieme di numeri in un intervallo di celle, con le celle da sommare determinate utilizzando più criteri. La differenza principale tra SOMMA.PIÙ.SE e La funzione SOMMA.SE è che quest'ultima si limita a valutare un solo criterio.
I criteri passati a SOMMA.PIÙ.SE possono utilizzare caratteri jolly o espressioni regolari.
Sintassi:
SOMMA.PIÙ.SE(Area della somma; Area 1; Criteri 1[; Area 2; Criteri 2[; … [; Area 127; Criteri 127]]])
Restituisce:
Restituisce un numero reale che è il risultato della somma dei numeri nelle celle pertinenti.
Argomenti:
Argomento Area della somma
Area della somma specifica le celle da sommare. Area della somma solitamente assume una delle seguenti forme:
- Un riferimento a un intervallo di celle (ad esempio, A1:A25), che potrebbe non utilizzare l'operatore di concatenazione dei riferimenti (~).
- Il nome di un'area nominata.
- Il nome di un'area in una base di dati.
Argomenti di area
Area 1 specifica l'insieme di celle da confrontare con Criteri 1 e assume una delle forme elencate per Area della somma. Area 1 dovrebbe avere le stesse dimensioni di Area della somma.
Area 2, ..., Area 127 hanno lo stesso significato di Area 1.
Argomenti di criteri
Criteri 1 è il criterio per la corrispondenza con le celle nell'Area 1 o con una cella contenente tale criterio. Il Criteri 1 può assumere una delle seguenti forme:
- Un numero, ad esempio 34,5. Le date e i valori logici (VERO o FALSO) vengono trattati come numeri.
- Un'espressione, ad esempio 2/3, RADQ($D$1) o DATA(2021; 11; 1).
- Una stringa di testo, ad esempio "golf" o "<>10".
SOMMA.PIÙ.SE cerca le celle nell'Area 1 che sono uguali a Criteri 1, a meno che Criteri 1 non sia un testo stringa che inizia con un comparatore (>, <, >=, <=, = o <>). In quest'ultimo caso SOMMA.PIÙ.SE confronta le celle nell'Area 1 con il resto della stringa di testo (interpretata come numero se possibile e testo altrimenti). Ad esempio, la condizione ">4,5" verifica se il contenuto di ciascuna cella è maggiore del numero 4,5, la condizione "<cane" verifica se il contenuto di ciascuna cella viene prima del testo "cane" in ordine alfabetico e la condizione "<>01-11-2021" verifica se il contenuto di ciascuna cella non è uguale alla data specificata.
Criteri 1 supporta i seguenti comportamenti specifici:
- La stringa "=" corrisponde alle celle vuote. Ad esempio, la formula
=SOMMA.PIÙ.SE(A1:A10; B1:B10; "=")restituisce la somma di tutti i valori nell'intervallo A1:A10 se tutte le celle nell'intervallo B1:B10 sono vuote. Notate che "=0" non corrisponde alle celle vuote. - La stringa "<>" corrisponde a celle non vuote. Ad esempio, la formula
=SOMMA.PIÙ.SE(A1:A10; C1:C10; "<>")restituisce la somma di tutti i valori nell'intervallo A1:A10 se non sono presenti celle vuote nell'intervallo C1:C10. - Se il valore dopo il comparatore <> non è vuoto, allora Criteri 1 corrisponde a qualsiasi contenuto di cella tranne quel valore, comprese le celle vuote.
Criteri 2, ..., Criteri 127 hanno lo stesso significato di Criteri 1.
Condizioni di errore
- Se un intervallo di celle passato come argomento contiene un operatore di concatenazione di riferimenti (~), allora SOMMA.PIÙ.SE segnala un errore di argomento non valido (Err:502).
- Tutti gli intervalli di celle passati come argomenti (Area della somma e Area 1, …, Area 127) devono occupare lo stesso numero di righe e lo stesso numero di colonne. In caso contrario, SOMMA.PIÙ.SE segnala un errore di argomento non valido (Err:502).
- Se gli argomenti Area n e Criteri n non sono accoppiati correttamente, allora SOMMA.PIÙ.SE segnala un errore di variabile mancante (Err:511).
Dettagli aggiuntivi:
Dettagli specifici della funzione SOMMA.PIÙ.SE
- La corrispondenza predefinita eseguita da SOMMA.PIÙ.SE non fa distinzione tra maiuscole e minuscole. Tuttavia, è possibile eseguire una corrispondenza con distinzione tra maiuscole e minuscole quando si utilizza un'espressione regolare includendo un modificatore di modalità "(?-i)" all'interno dell'espressione regolare, come dimostrato da uno degli esempi seguenti.
- Il comportamento di SOMMA.PIÙ.SE è influenzato da diverse impostazioni disponibili nella finestra di dialogo ▸ ▸ ▸ ( ▸ ▸ ▸ su macOS).
- Se è selezionata la casella Criteri di ricerca = e <> devono essere applicati a celle intere, la condizione "red" corrisponderà solo a "red"; se deselezionato corrisponderà a "red", "Fred", "red herring".
- Se è selezionata la casella di controllo Abilita caratteri jolly nelle formule, la condizione corrisponderà utilizzando i caratteri jolly, quindi ad esempio "b?g" corrisponderà a "bag", "beg", "big", "bog", e "bug".
- Se è selezionata la casella di controllo Abilita espressioni regolari nelle formule, la condizione corrisponderà utilizzando le espressioni regolari, quindi ad esempio "r.d" corrisponderà a "red", "rid" e "rod", mentre "red .*" corrisponderà a "red", "redraw", e "redden".
- L'impostazione della casella di controllo Maiuscole e minuscole non ha alcun impatto sul funzionamento di SOMMA.PIÙ.SE.
Informazioni generali sulle espressioni regolari in Calc
 |
Nota:
|
- Un'espressione regolare è una stringa di caratteri che definisce una sequenza di testo da ricercare. Potete trovare maggiori e più dettagliate informazioni sulla pagina di Wikipedia relativa alle Espressioni regolari.
- Le espressioni regolari sono ampiamente usate in molti campi e sono disponibili molteplici processori di espressioni regolari. Calc utilizza il pacchetto open source Regular Expressions della International Components for Unicode (ICU). Vedere la loro documentazione sulle Espressioni regolari per maggiori dettagli, che comprendono la definizione integrale della sintassi delle Espressioni regolari ICU.
- In aggiunta a ciò, la guida in linea di LibreOffice fornisce un elenco delle espressioni regolari di alto livello.
- Il motore per le espressioni regolari di Calc supporta il rilevamento di gruppi numerati, che consentono di identificare dei sotto intervalli all'interno di una corrispondenza e di usarli all'interno di un testo sostitutivo. Le parentesi sono usate per raggruppare i componenti di un'espressione regolare e creare un gruppo numerato. Per inserire un gruppo rilevato all'interno di un testo sostitutivo, usate il formato "$n", nel quale n è il numero del gruppo rilevato.
Informazioni generali sui caratteri jolly di Calc
I caratteri jolly sono dei caratteri speciali che possono essere usati all'interno delle stringhe di ricerca e passato come argomenti ad alcune funzioni di Calc; possono essere usati anche per definire dei criteri di ricerca all'interno della finestra di dialogo Trova e sostituisci. L'uso di caratteri jolly permette la definizione di parametri di ricerca più avanzati usando un'unica stringa di ricerca.
Calc supporta come argomento sia i caratteri jolly, sia le espressioni regolari, a seconda delle impostazioni correnti del programma. Per impostazione predefinita sono supportati i caratteri jolly e non le espressioni regolari.
Per assicurarvi che siano supportati i caratteri jolly, andate in ▸ ▸ ▸ e controllate che sia selezionata l'opzione Permetti caratteri jolly nelle formule. Prestate attenzione al fatto che potete usare questa finestra di dialogo anche per passare alle espressioni regolari selezionando Permetti le espressioni regolari nelle formule, oppure scegliere di non supportare né i caratteri jolly, né le espressioni regolari.
La tabella seguente identifica i caratteri jolly supportati da Calc.
| Carattere jolly | Descrizione |
|---|---|
| ? (punto interrogativo) | Trova qualsiasi carattere singolo. Per esempio, la stringa di ricerca "b?g" trova "bag" e "beg" ma non troverà "boog" o "mug". Fate attenzione che non troverà neppure "bg", in quanto "?" deve corrispondere esattamente ad un carattere. Il carattere jolly "?" non combacia con una corrispondenza di zero caratteri. |
| * (asterisco) | Trova qualsiasi sequenza di caratteri, compresa una stringa vuota. Per esempio, la stringa di ricerca "*cast" troverà "cast", "forecast" e “outcast”, ma, usando le impostazioni predefinite di Calc, non troverà "forecaster". Se l'opzione I criteri di ricerca = e <> devono riferirsi a celle intere è disabilitata in , allora "forecaster" sarà trovato usando la stringa di ricerca "*cast".
|
| ~ (tilde) | Annulla il significato speciale di un carattere punto interrogativo, asterisco o tilde che segue immediatamente dopo il carattere tilde. Per esempio, la stringa di ricerca "why~?" troverà "why?" ma non troverà "whys" né "why~s". |
La comparazione dei caratteri jolly non fa distinzione tra caratteri maiuscoli e minuscoli, perciò "A?" troverà entrambi "A1" e "a1".
Questi caratteri jolly sono supportati in Calc e Microsoft Excel. Perciò, se avete la necessità dell'interoperabilità tra le due applicazioni, scegliete di lavorare con i caratteri jolly e non con le espressioni regolari. Al contrario, se l'interoperabilità non è necessaria, prendete in considerazione l'uso delle espressioni regolari per avere a disposizione capacità di ricerca più potenti.
Esempi:
Esempi di vendita di articoli di cancelleria
Considera la seguente tabella che mostra le informazioni sulle vendite e sui ricavi per un piccolo fornitore di articoli di cancelleria. La stringa "N/A" si riferisce ai prodotti che non erano disponibili per la fornitura durante il periodo coperto dai dati.
| A | B | C | |
|---|---|---|---|
| 1 | Prodotto | Vendite | Entrate |
| 2 | Matita | 20 | $65 |
| 3 | Penna | 35 | $85 |
| 4 | Notebook | 20 | $190 |
| 5 | Libro | 17 | $180 |
| 6 | Astuccio | N/A | N/A |
In tutti gli esempi basati su questa tabella, va notato che la riga 6 per gli astucci non contiene dati numerici e quindi non contribuirà mai al risultato di SOMMA.PIÙ.SE, qualunque sia il criterio specificato.
| Formula | Descrizione | Restituisce |
|---|---|---|
| =SOMMA.PIÙ.SE(B2:B6; B2:B6; ">=20") | Qui la funzione somma i dati numerici "Vendite" maggiori o uguali a 20. | 75 |
| =SOMMA.PIÙ.SE(C2:C6; B2:B6; ">=20"; C2:C6; ">70") | Qui la funzione individua le voci maggiori o uguali a 20 nei dati Vendite che hanno anche un valore maggiore di $70 nei dati Entrate e somma le voci numeriche corrispondenti nei dati Entrate . | $275 |
| =SOMMA.PIÙ.SE(C2:C6; B2:B6; ">"&MIN(B2:B6); B2:B6; "<"&MAX(B2:B6)) | Qui la funzione calcola la somma delle voci numeriche nei dati Entrate che corrispondono a tutti i valori nei dati Vendite tranne il minimo e il massimo. | $255 |
| =SOMMA.PIÙ.SE(C2:C6; A2:A6; "pen.*"; B2:B6; "<"&MAX(B2:B6)) | Questo esempio funzionerà come descritto qui solo se le espressioni regolari sono abilitate. Qui la funzione individua le voci nei dati Prodotto che iniziano con i caratteri "penna" e hanno un valore nei dati Vendite che non è il massimo, e somma le voci numeriche corrispondenti nei dati Entrate dati. | $65 |
| =SOMMA.PIÙ.SE(C2:C6; A2:A6; E2&".*"; B2:B6; "<"&MAX (B2:B6)) dove la cella E2 contiene la stringa "penna" (inserita senza virgolette doppie). | Questo esempio funzionerà come descritto qui solo se le espressioni regolari sono abilitate. Se è necessario modificare facilmente un criterio, è possibile specificarlo in una cella separata e utilizzare un riferimento a questa cella nella condizione della funzione SOMMA.PIÙ.SE. Qui il collegamento alla cella viene sostituito con il suo contenuto, ottenendo lo stesso risultato dell'esempio precedente. | $65 |
Esempi di vendita di attrezzature sportive
Gli esempi in questa sottosezione si basano su un piccolo database di dati di vendita di attrezzature sportive, con i dati organizzati come nella tabella seguente.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Data | Valore delle vendite | Categoria | Regione | Dipendente |
| 2 | 2021-10-02 | $1,508 | Golf | Est | Hans |
| 3 | 2021-10-02 | $410 | Tennis | Nord | Kurt |
| 4 | 2021-10-02 | $2,340 | Navigazione | Sud | Ute |
| 5 | 2021-10-03 | $4,872 | Tennis | Est | Brigitte |
| 6 | 2021-10-06 | $3,821 | Tennis | Sud | Fritz |
| 7 | 2021-10-06 | $2,623 | Tennis | Est | Fritz |
| 8 | 2021-10-07 | $3,739 | Golf | Sud | Fritz |
| 9 | 2021-10-08 | $4,195 | Golf | Ovest | Ute |
| 10 | 2021-10-10 | $2,023 | Golf | Est | Hans |
| Formula | Descrizione | Restituisce |
|---|---|---|
| =SOMMA.PIÙ.SE(B2:B10; B2:B10; ">=4000") | Qui la funzione somma le voci numeriche nei dati "Valore delle vendite" maggiori o uguali a $ 4.000. Questa formula è equivalente sia a =SOMMA.SE(B2:B10; ">=4000") che a =SUMIF}}(B2:B10; ">=4000"; B2:B10). |
$9,067 |
| =SOMMA.PIÙ.SE(B2:B10; E2:E10; "ute") | Qui la funzione individua le voci per Ute nei dati Dipendente e somma le voci numeriche corrispondenti nei dati Valore delle vendite. Questa formula è equivalente a =SOMMA.SE(E2:E10; "ute"; B2:B10) e questo riordino degli argomenti evidenzia una differenza fondamentale tra le due funzioni - Area della somma è il terzo argomento per SOMMA.SE e il primo argomento per SOMMA.PIÙ.SE. |
$6,535 |
| =SOMMA.PIÙ.SE(B2:B10; CategoryData; "golf") dove l'intervallo denominato CategoryData è stato creato per coprire l'intervallo di celle C2:C10. | Qui la funzione individua le voci per Golf nei dati Categoria e somma le voci numeriche corrispondenti nei dati SOMMA.PIÙ.SEValore delle vendite. | $11,465 |
| =SOMMA.PIÙ.SE(B2:B10; D2:D10; F1; E2:E10; F2) dove le celle F1 e F2 contengono rispettivamente le stringhe di testo ">=sud" e "ute" (entrambi inseriti senza digitare le virgolette doppie). | Qui la funzione individua le voci per Sud e Ovest nei dati Regione che hanno anche Ute nei dati Dipendente e somma le voci numeriche corrispondenti nei dati Valore vendite. | $6,535 |
| =SOMMA.PIÙ.SE(B2:B10; A2:A10; DATA(2021; 10; 2); C2:C10; "tennis") | Qui la funzione individua le voci per il 02-10-2021 nella colonna Data che hanno anche Tennis nei dati Categoria e somma le voci numeriche corrispondenti nei dati Valore delle vendite. | $410 |
| =SOMMA.PIÙ.SE(B2:B10; A2:A10; ">="&DATA(2021; 10; 6); E2:E10; "<>"&E8) | Qui la funzione individua le voci datate a partire dal 2021-10-06 nella colonna Data che non hanno Fritz nei dati Dipendente e somma le voci numeriche corrispondenti nel Valore delle vendite dati. | $6,218 |
| =SOMMA.PIÙ.SE(B2:B10; C2:C10; "tennis"; D2:D10; "east"; E2:E10; "fritz") | Qui la funzione individua le voci che hanno Tennis nei dati Categoria, Est nei dati Regione e Fritz nei dati Dipendente. Somma le voci numeriche corrispondenti nei dati "Valore delle vendite". | $2,623 |
| =SOMMA.PIÙ.SE(B2:B10; D2:D10; "????"; E2:E10; "*e") | Questo esempio funzionerà come descritto qui solo se i caratteri jolly sono abilitati. Qui la funzione individua le voci di quattro caratteri nei dati Regione (Est e Ovest) che hanno anche una voce nei dati Dipendente che termina con la lettera "e" o "E" (Brigitte e Ute). Somma le voci numeriche corrispondenti nei dati "Valore delle vendite". | $9,067 |
| =SOMMA.PIÙ.SE(B2:B10; C2:C10; "^t.*"; D2:D10; ".*h") | Questo esempio funzionerà come descritto qui solo se le espressioni regolari sono abilitate. Qui la funzione individua nei dati Categoria le voci per il Tennis che iniziano con la lettera "t" o "T" (Tennis) che hanno anche una voce nei dati Regione che termina con la lettera " h" o "H" (Nord e Sud). Somma le voci numeriche corrispondenti nei dati "Valore delle vendite". | $4,231 |
| =SOMMA.PIÙ.SE(B2:B10; E2:E10; "(?-i)ute") | Questo esempio funzionerà come descritto qui solo se le espressioni regolari sono abilitate. Il modificatore di modalità "(?-i)" all'interno dell'espressione regolare cambia in una corrispondenza con distinzione tra maiuscole e minuscole e quindi non viene trovata alcuna voce nei dati Dipendente. Confrontalo con il secondo esempio in questa tabella. | $0 |
Ulteriori esempi
Per ulteriori esempi, scarica e visualizza questo foglio di Calc.
Funzioni di LibreOffice correlate:
Standard ODF:
Funzioni equivalenti (o simili) di Excel:
SUMIFS