Documentatie/Calc-functies/WERKDAG

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/WORKDAY and the translation is 100% complete.
    Other languages:


    Functienaam:

    WERKDAG

    Categorie:

    Datum en tijd

    Samenvatting:

    Berekent de datum die een bepaald aantal werkdagen voor of na een bepaalde begindatum is. Feestdagen (of andere niet-werkdagen) kunnen worden opgegeven. Zaterdag en zondag worden als niet-werkdagen in het weekend beschouwd.

    Syntaxis:

    WERKDAG(Begindatum; Dagen[; Feestdagen])

    Retourneert:

    Retourneert een geheel getal dat het datum-tijd-serienummer is van de dag die een opgegeven aantal werkdagen voor of na de opgegeven datum is. De geretourneerde waarde is standaard opgemaakt als een getal, maar u kunt indien nodig een andere opmaak toepassen (zoals Datum).

    Argumenten:

    Begindatum is de datum (tussen aanhalingstekens) of een datum-tijd-serienummer of een verwijzing naar de cel die één van die typen bevat, de datum waarop de berekening moet worden uitgevoerd.

    Dagen is een geheel getal of een verwijzing naar een cel die die waarde bevat die het aantal werkdagen is dat als referentie in de berekening moet worden gebruikt. Een positieve waarde wordt ingevoerd om een later resultaat dan Begindatum te krijgen, een negatieve waarde wordt ingevoerd om een resultaat eerder dan Begindatum te krijgen.

    Feestdagen is een lijst met data die overeenkomen met feestdagen die niet als werkdagen worden geteld. Deze lijst kan worden doorgegeven als een celbereik met serienummers voor datum en tijd (mogelijk weergegeven in een datumnotatie). Als alternatief kan de lijst worden doorgegeven als een inline matrix met datumreeksen (tussen aanhalingstekens) of datum-tijd-serienummers. Indien weggelaten, worden geen feestdagen verondersteld.

    • Als Begindatum geen geldige datumuitdrukking is, retourneert WERKDAG als fout #WAARDE!
    • WERKDAG negeert alle tijdcomponenten van Begindatum.
    • Als Dagen niet-numeriek is, dan retourneert WERKDAG als fout #WAARDE!
    • Als Dagen een niet-gehele waarde is, wordt deze door WERKDAG afgekapt tot een geheel getal.
    • Als Feestdagen wordt doorgegeven als een inline matrix, ontstaat er een Ongeldige argument (Fout:502) als een invoer van die matrix geen datum of een datum-tijd-serienummer is.
    • Als Feestdagen wordt doorgegeven als een celbereik en één van die cellen bevat gegevens die geen datum of een datum-tijd-serienummer zijn, retourneert WERKDAG als fout Ongeldig argument (Fout:502).

    Aanvullende details:

    Details specifiek voor de functie WERKDAG

    WERKDAG beschouwt normaal gesproken maandag tot en met vrijdag als werkdagen, tenzij een bepaalde dag samenvalt met een bepaalde feestdag. De normale weekenddagen van zaterdag en zondag worden als niet-werkdagen beschouwd.

    De functie WERKDAG van Calc ondersteunt de optionele parameter Werkdagen die is gespecificeerd in ODF 1.2 niet, maar is compatibel met de gelijknamige functie van Microsoft Excel. Als u een andere werkweek moet specificeren, gebruik dan de functie WERKDAG.INTL van Calc.


    Algemene informatie over de datum- en tijdfuncties van Calc

    Note pin.svg

    NB:
    Voor het gemak wordt de informatie in deze subsectie herhaald op alle pagina's die functies beschrijven in de categorie Datum en Tijd.

    • Intern in Calc, een datum/tijd-waarde wordt behandeld als een reëel getal en dit wordt soms aangeduid met de term datum-tijd serienummer. 2021-02-08 12:00:00 komt bijvoorbeeld overeen met het datum-tijd serienummer 44235.5. Het gehele deel van een datum-tijd-serienummer (vóór de komma) is het aantal dagen sinds een gedefinieerde startdatum. Het fractionele deel van een datum-tijd-serienummer (achter de komma) is de tijd van de dag uitgedrukt als een fractie van een dag. 0,25 is bijvoorbeeld gelijk aan 06:00:00 en 0,75 is gelijk aan 18:00:00.
    • Calc gebruikt 1899-12-30 als standaard startdatum (dag 0) maar u kunt naar Extra ▸ Opties ▸ LibreOffice Calc ▸ Berekenen gaan om alternatieve startdatums te selecteren; we raden u echter aan deze instelling niet te wijzigen, tenzij u specifieke vereisten heeft voor compatibiliteit met oudere werkbladtoepassingen. Als u cellen met datumwaarden kopieert en plakt tussen verschillende werkbladen, controleer dan of beide documenten zijn ingesteld om dezelfde startdatum te gebruiken om onverwachte wijzigingen in de weergegeven datums te voorkomen.
    • Negatieve datum-tijd serienummers komen overeen met datums eerder dan de startdatum van Calc. Calc berekent alle datums terug tot 15 oktober 1582 met behulp van de Gregorian calendar. De dag ervoor is 4 oktober 1582 en Calc gebruikt de Julian calendar voor eerdere data.
    • Een serienummer voor datum en tijd is hetzelfde als elk ander getal, behalve dat we er meestal voor kiezen om het in de vorm van een datum/tijd weer te geven. U kunt een getal in een cel invoeren en vervolgens de opmaak van de cel wijzigen om de waarde als datum/tijd weer te geven. U kunt ook een datum/tijd in een cel invoeren en vervolgens de opmaak van de cel wijzigen om het datum-tijd-serienummer weer te geven.
    • Voor de duidelijkheid: de beschrijvingen van de Calc-functies op deze wiki-pagina's gebruiken het standaard ISO 8601-formaat voor datum en tijd omdat dit onafhankelijk moet zijn van de door u geselecteerde landinstellingen. Het standaard datumformaat op uw computer kan anders zijn. Bij het invoeren van datums als onderdeel van formules, kunnen schuine strepen of streepjes die als datumscheidingsteken worden gebruikt, worden geïnterpreteerd als rekenkundige operatoren. Daarom worden datums die in dit formaat zijn ingevoerd, niet herkend als datums en resulteren in foutieve berekeningen. Om te voorkomen dat datums worden geïnterpreteerd als onderdelen van formules, gebruikt u de functie DATUM of plaatst u de datum tussen aanhalingstekens en gebruikt u de ISO 8601-notatie. Vermijd het gebruik van locale-afhankelijke datumnotaties die fouten kunnen veroorzaken als het document onder verschillende locale-instellingen wordt geladen.
    • Tijdzone-informatie wordt niet gebruikt door de datum- en tijdfuncties van Calc.
    • Als u alleen twee cijfers van het jaar wilt invoeren (bijvoorbeeld 21 in plaats van 2021), moet Calc weten of u 2021 of 1921 bedoelt. Ga naar Extra ▸ Opties ▸ LibreOffice ▸ Algemeen om het bereik van jaren te bekijken of aan te passen dat Calc zal gebruiken om tweecijferige jaarwaarden te interpreteren.
    • Calc bevat logica om te beslissen hoe tekst moet worden behandeld wanneer het wordt aangetroffen als een opdrachtelement in een rekenkundige bewerking of als een argument voor een functie die in plaats daarvan een getal verwacht. In deze context is eenduidige conversie mogelijk voor ISO 8601 datums en tijden in hun uitgebreide formaten met scheidingstekens. De eenvoudige formule =1 + "2021-02-08" geeft bijvoorbeeld meestal het resultaat 2021-02-09 (wanneer opgemaakt als een datum). Deze logica kan echter worden beïnvloed door de instellingen in het dialoogvenster Gedetailleerde berekeningsinstellingen, toegankelijk door Extra ▸ Opties ▸ LibreOffice Calc ▸ Formule te selecteren en op de knop Details te drukken in het gebied "Gedetailleerde berekeningsinstellingen". Als een #WAARDE! fout optreedt, kan het zijn dat de optie Algemene fout #WAARDE! is geselecteerd, in welk geval u moet experimenteren met één van de andere opties in de keuzelijst Van tekst naar getal converteren.

    Voorbeelden:

    Formule Beschrijving Retourneert
    =WERKDAG("2021-02-10"; 10) De functie retourneert de waarde 44251, wat het datum-tijd-serienummer is voor 2021-02-24. De dag die 10 werkdagen is na 2021-02-10 is 2021-02-24. 44251
    =WERKDAG(44256; -5.8) De functie retourneert de waarde 44249, wat het datum-tijd-serienummer is voor 2021-02-22. De waarde 44256 is het datum-tijd-serienummer voor 2021-03-01. Calc kapt de reële waarde -5,8 af tot het gehele getal -5. De dag die 5 werkdagen voor 2021-03-01 valt, is 2021-02-22. 44249
    =WERKDAG("2020-01-01"; 254; {"2020-01-01"; "2020-04-10"; "2020-04-13"; "2020-05-08"; "2020-05-25"; "2020-08-31"; "2020-12-25"; "2020-12-28"}) De functie retourneert de waarde 44196, wat het datum-tijd-serienummer is voor 2020-12-31. De dag die 254 werkdagen later is dan 2020-01-01 is 2020-12-31, rekening houdend met de genoemde vakantiedagen. 44196
    =WERKDAG(G1; G2; G3:G7) waarbij cel G1 de datum 2001-12-01 bevat, cel G2 de waarde 17 en cellen G3 tot G7 de datums 2001-12-24, 2001-12-25, 2001-12-26, 2001-12-31, 2002-01-01. De functie retourneert de waarde 37253, wat het datum-tijd-serienummer is voor 2001-12-28. 2001-12-28 was de datum die 17 werkdagen na 2001-12-01 viel. 37253

    Gerelateerde LibreOffice-functies:

    WERKDAG.INTL

    ODF standaard:

    Geen

    Gerelateerde (of gelijkwaardige) Excel-functies:

    WORKDAY