RECHERCHEV

Renvoie une valeur à partir d'une colonne de table dans la ligne trouvée par la recherche dans la première colonne.

Syntaxe

RECHERCHEV(valeur_recherchée; table; index_colonne; mode)

valeur_recherchée est une valeur (nombre, texte ou valeur logique) à rechercher dans la colonne de gauche de la plage/matrice table. Quand une valeur est correspondante dans la colonne de gauche, RECHERCHEV renvoie une valeur correspondante (dans la même ligne) dans l'index_colonne^eme colonne de table, où index_colonne = 1 est la colonne de gauche.

Si mode est 0 ou FAUX, la colonne de gauche de table peut ne pas être triée et la première correspondance exacte est trouvée (la recherche commençant par le haut).

Si mode est 1 ou VRAI, ou est omise, la colonne de gauche de table doit être triée, avec des nombres en ordre ascendants apparaissant avec les valeur de texte en ordre alphabétique. RECHERCHEV décide où dans la colonne de gauche valeur_recherché devait apparaître. S'il y a une correspondance exacte, c'est la ligne trouvée ; s'il y a plus d'une correspondance, la ligne trouvée n'est pas nécessairement près du haut. S'il n'y a pas de correspondance exacte, la ligne en-dessous d'où valeur devrait apparaître dans la colonne de gauche est trouvée; il résulte une erreur #N/A si cette ligne n'est pas dans la table.

Si les expressions régulières sont activées dans la boîte de dialogue Outils - Options - LibreOffice Calc - Calcul, RECHERCHEV trouvera les correspondances exactes en traitant valeur_recherchée comme une expression régulière. Cela n'a de sens et doit uniquement être utilisé que si mode est 0 ou FAUX.

Si 'Critères de recherche = et <> doivent correspondre à des lignes entières' est activé dans la boîte de dialogue Outils - Options - LibreOffice Calc - Calcul, valeur_recherchée doit correspondre au texte complet dans la cellule ; sinon elle peut correspondre à une partie du texte.

La correspondance est toujours insensible à la casse - le paramètre de casse dans la boîte de dialogue Outils - Options - LibreOffice Calc - Calcul ne s'applique pas.

Exemples

Dans ces exemples, les cellules A1 à A5 contiennent 3, 5, chat, mat, matter, et les cellules B1 à B5 contiennent A, B, C, D, E.

RECHERCHEV(3; A1:B5; 2; 0)

renvoie A. La cellule A1 dans la colonne de gauche correspond à 3. Le contenu de la cellule correspondante dans la 2^eme colonne (c'est à dire, B1) est renvoyé. La colonne de gauche est triée mais ce n'est pas nécessaire en mode 0.

RECHERCHEV(4; A1:B5; 2; 0)

renvoie #N/A. Il n'y a pas de correspondance pour 4.

RECHERCHEV("CHAT"; A1:B5; 2; 0)

renvoie C. La différence entre les majuscules et minuscules est ignorée donc CHAT correspond à chat.

RECHERCHEV("ch.t"; A1:B5; 2; 0)

renvoie C si les expressions régulières sont activées (et #N/A sinon). Le point '.' signifie 'n'importe quel caractère unique' dans une expression régulière donc ch.t correspond à chat.

RECHERCHEV(".at"; A1:B5; 2; 0)

renvoie D si les expressions régulières sont activées. La correspondance la plus proche du haut est toujours trouvée en mode 0.

RECHERCHEV("at"; A1:B5; 2; 0)

renvoie #N/A si 'Critère de recherche = <> doivent correspondre à une ligne entière' est activée et C sinon. at ne correspond pas à un contenu de cellule complet mais correspond à une partie de chat.

RECHERCHEV(3; A1:B5; 2; 1)

renvoie A. La cellule A1 dans la colonne de gauche correspond à 3. La colonne de gauche doit être triée en mode 1, avec le texte venant après les nombres. matter suit mat parce que même si les premières lettres sont les mêmes, matter a plus de lettres.

RECHERCHEV(4; A1:B5; 2; 1)

renvoie A. 4 apparaîtra entre 3 et 5 dans la colonne de gauche donc la position au-dessus est trouvée.

RECHERCHEV(1; A1:B5; 2; 1)

renvoie #N/A. 1 apparaîtra avant 3 dans la colonne de gauche et il n'y a pas de position au-dessus dans la table.

RECHERCHEV(7; A1:B5; 2; 1)

renvoie B. 7 apparaîtra entre 5 et chat dans la colonne de gauche donc la position au-dessus est trouvée.

RECHERCHEV("abricot"; A1:B5; 2; 1)

renvoie B. abricot apparaîtra entre 5 et chat dans la colonne de gauche donc la position au-dessus est trouvée.

RECHERCHEV("mate"; A1:B5; 2; 1)

renvoie D. mate apparaîtra entre mat et matter dans la colonne de gauche donc la position au-dessus est trouvée.

RECHERCHEV("rat"; A1:B5; 2; 1)

renvoie E. rat apparaîtra après matter dans la colonne de gauche donc la position au-dessus est trouvée.

RECHERCHEV("at"; A1:B5; 2; 1)

renvoie B, même si 'critère de recherche = et <> doivent s'appliquer à des lignes entières' est désactivé. Dans ce cas, les correspondances entre at et chat sont ignorée en faveur de traiter at comme un mot venant entre 5 et chat.