User:Naruoga/LibreLogo

From The Document Foundation Wiki
Jump to: navigation, search

Contents

日本語版 LibreLogo のページ

LibreLogo はシンプルで、自然な、Logo に似たプログラミング環境で、タートルベクターグラフィックスを備え、コンピューティング (プログラミングと文書作成の両方)、DTP、グラフィックデザインなどの教材となるものです。http://www.numbertext.org/logo/librelogo.pdf (英語) をご覧ください。 LibreLogo はハンガリー人の László Németh 氏によって開発されています。本マニュアルは Nemeth 氏による英文マニュアルをもとに、日本語で LibreLogo を使う方法と、日本語 LibreLogo のコマンドを解説するものです。

なお LibreLogo の日本語コマンドについては議論を募集しています。本ページの Discussion もご覧になってください。

インストール

LibreLogo は LibreOffice 4.0.0 から標準で搭載され、4.0.1 からアジア系、RTL 系言語がサポートされるようになりました。もしみなさんが 4.0.1 以降をお使いなら、インストールは不要です。

本稿執筆時点の2013年3月11日、Ubuntu Raring (13.04) には LibreOffice 4.0.1 が収録されていますが、下の操作の通りに行なってもツールバーの候補に "Logo" はありません。Ubuntu Raring では LibreLogo は別パッケージとして供給されています (これが暫定的なのか、恒久的な決定なのかは、筆者は現時点では知りません)。

$ sudo apt-get install libreoffice-librelogo

でインストールを行なってください。

LibreLogo ツールバー

LibreLogo ツールバー (表示 ▸ ツールバー ▸ Logo) にはタートルの移動、プログラムの実行と停止、ホーム(もとの位置に戻る)、画面のクリアなどのアイコンと、入力バー(コマンドライン)があります。

タートル移動アイコン

それぞれのボタンは Logo のコマンドの“すすむ 10”、“もどる 10”、“右 15”、“左 15”と同じ意味です。ボタンをクリックすると、タートルが今いる場所にページをスクロールして表示をするという働きもあります。

プログラムの実行と開始

アイコン「実行」は Writer 文書のテキストを LibreLogo のテキストとみなして実行します。 アイコン「停止」はプログラムの実行を停止します。

ホーム(もとの位置に戻る)

「ホーム」アイコンをクリックすると、タートルの場所と設定は最初の状態に戻ります。

画面のクリア

「画面を消す」アイコンをクリックすると、文書中の描画されたオブジェクトが削除されます。

コマンドライン

コマンドライン内で Enter を押すと、その内容を実行します。プログラムの停止には「停止」ボタンを使います。 Enter を押しっぱなしにするとコマンドラインの内容を繰り返し続けます。例えば、次のようなコマンド列を入力して試してみてください:

すすむ 200 左 89

コマンドラインの中身を消すにはトリプルクリックをするか、Ctrl-A を押して全コマンドを選択し、新たなコマンドを入力してください。

プログラムの編集

LibreLogo の描画結果とプログラムは同じ Writer 文書になります。LibreLogo のキャンバスは Writer 文書の最初のページになります。LibreLogo のプログラムの前に改ページを挿入して、拡大率やフォントサイズを適切に設定すると、2画面レイアウトで LibreLogo プログラミングをするのにいいでしょう。左の (最初の) ページはキャンバスで、右の (二番目の) ページは LibreLogo プログラムとするわけです。

LibreLogo は自然に読み書きでき、各言語対応も簡単な、Logo ライクなプログラミング言語です (日本語化されたコマンド一覧はこちら)。教育における単純な Logo プログラムについては、懐かしの Logo システムと互換性があります。例えば:

TO triangle :size
REPEAT 3 [
  FORWARD :size
  LEFT 120
]
END

と定義しておいて:

triangle 10 triangle 100 triangle 200

と書くことができます。

LibreLogo の日本語化

LibreLogo の標準言語 (コマンド) を日本語にする方法があります。これは LibreOffice 4.0.1 以降から有効です。ただし、LibreOffice 4.0.1 および 4.0.2 ではコマンドを日本語化すると一部の英語のコマンドが逆に使えなくなるので (ローカライズの不具合です)、テスト目的以外では英語で利用することをオススメします。

有効にするには、「ツール」-「オプション」-「言語設定」-「言語」の「ドキュメントの標準言語」で「西欧諸言語」を”[なし]"にしてアジア諸言語を"標準 - 日本語"にしてください。なお、常にこうすると多分(ですけど)和欧混在の文書が変になるので、「現在のドキュメントのみに適用」をオンにしておくのをオススメします。こんな感じ。

20130304210117.png


このページの以下の記述では、コマンドを日本語化した LibreLogo について説明します。 なおコマンドを日本語化していなくても、先に説明した LibreLogo ツールバーなどは日本語化されています。

もちろんコマンドを英語版のままに LibreLogo を用いることもできます。英語版のコマンドについては、オリジナルのドキュメント をご覧ください。

オリジナルの Logo 言語のと違い

  • リストのメンバーはカンマ区切りです: 位置 [0, 0]
  • プログラムブロックとリストに違いがあります
    • プログラムブロックでは、カッコの前に空白や改行が必要です: くりかえす 10 [ すすむ 10 左 36 ]
    • リストは閉じカッコが必要です: 位置 [0, 0], そして次のようにカッコに空白を入れてはいけません: 位置 [ 0 , 0 ]
  • 1行で関数を定義する構文はまだサポートされていません(動きを作る と おわり の間には改行がなければいけません)。

LibreLogo のその他の機能

  • 引数の前のコロンは省略可能です (Berkeley Logo のように):
動きを作る triangle size
繰り返す 3 [ すすむ size 左 120 ]
おわり
  • 文字列の記法としては正字式 (二重引用符で括る) と Python 文法もサポートしています:
表示 "word   ; もとの Logo の文法
表示 “Arbitrary text.”    ; 正字式, Writer
表示 'Arbitrary text.'    ; Python の文法
  • Python のリストおよび文字列操作が可能です
表示 “text”[2]               ; print “x”
表示 “text”[1:3]          ; print “ex”
  • Python 式の FOR (ひとつずつ) ループのサポート
  • Python 式の変数宣言:
x = 15
表示 x
  • 関数呼び出しのときにカッコをつけて呼び出すことが可能
動きを作る star size color
塗りつぶしの色 color
繰り返し 5 [ 左 72 進む size 右 144 進む size ]
塗りつぶし
おわり

star 100 “赤”
star (100, “緑”)
star(100, “青”)

LibreLogo のコマンド

基本の文法

大文字小文字の区別

コマンドと色定数を英語で記述する場合には大文字小文字は区別しません:

PRINT “Hello, World!”
print “Hello, World, again!”

変数名は大文字小文字を区別します:

a = 5
A = 7
PRINT a
PRINT A

※なお、いわゆる全角と半角は区別されます。つまり、変数として半角の a と全角の a は区別されますし、英語コマンドで「PRINT」とタイプしてもコマンドとして認識されません。

プログラムの行

LibreLogo の行は LibreOffice Writer 文書の段落に対応します。プログラムの1行には複数のコマンドを書くことができます:

表示 “1970年のこんにちは” PRINT “LibreLogo”

コメント

行(段落)または行の途中にセミコロンがある場合、そこから行末まではコメントとなります:

; コメントの例
PRINT 5 * 5     ; これもコメント

複数の段落にプログラムの行を分割する

プログラムの行末に、チルダ (~) 文字をつけることで、プログラムの途中で段落を分けることができます:

表示 “と〜〜〜〜〜〜〜っても長い ” + ~
     “警告メッセージですよ!!!!”

タートルの移動

すすむ (FORWARD/fd)

すすむ 10     ; 10 ポイント前にすすむ (1 ポイント (pt) = 1/72 インチ (inch))
すすむ 10pt        ; 上と同じ
すすむ 0.5in       ; 0.5 インチ前に進む (1 インチ = 2.54 cm)
すすむ 1"  ; 1 インチ前に進む (in = ")
FD 1mm         ; 1 ミリ進む (の省略形)
FD 1cm         ; 1 センチ進む (の省略形)

もどる (BACK/bk)

もどる 10 ; 10 ポイント後ろに進む

左 (LEFT/lt)

左 90               ; 半時計回りに 90 度回る
左 90°           ; 同じ
LT 3h           ; 上と同じ (時計の文字盤で角度を指定)
LT any          ; でたらめな角度 (any) だけ回転する

右 (RIGHT/rt)

右 90       ; 時計回りに 90 度回る

ペンをあげる (PENUP/pu)

ペンをあげる     ; タートルが動いても軌跡が描かれなくなる

ペンをおろす (PENDOWN/pd)

ペンをおろす     ; タートルが動いた軌跡が描かれるようになる

位置 (POSITION/pos)

位置 [0, 0]  ; ページの左上角の方を向きそこまで移動する
位置 pagesize     ; ページの右下角の方を向きそこまで移動する
位置 [pagesize[0], 0] ; ページの右上角の方を向きそこまで移動する
位置 any         ; どこか適当な位置 (any) を向きそこまで移動する

進む向き (HEADING/seth)

進む向き 0             ; 北 (上) を向く
進む向き 12h                ; 同じ
進む向き any                ; 適当な方向を向く

その他タートル関係のコマンド

タートルを隠す (HIDETURTLE/ht)

タートルを隠す    ; タートルを隠す (「タートルを出す」が実行されるまで)

タートルを出す (SHOWTURTLE/st)

タートルを出す    ; タートルを表示する

もとの位置へ (HOME)

もとの場所へ     ; タートルの設定を元に戻して、最初の位置に移動

画面を消す (CLEARSCREEN/cs)

画面を消す      ; 文書中の描かれたオブジェクトをすべて消す

塗りつぶし (FILL) と 折れ線を閉じる (CLOSE)

塗りつぶし      ; 折れ線を閉じ、その内部を塗りつぶす
折れ線を閉じる ; 折れ線を閉じる

ペンの設定

ペンの太さ (PENSIZE/ps)

ペンの太さ 100  ; 線の太さを 0.1 インチに
ペンの太さ なんでも ; PENSIZE RANDOM 10 と同じ

ペンの色 (PENCOLOR/pc)

ペンの色 “赤”   ; ペンの色を赤に設定 (色の名前による設定、「色の定数」を参照)
ペンの色 [255, 255, 0]      ; ペンの色を黄色に (RGB のリスト)
ペンの色 0xffff00   ; ペンの色を黄色に (16進指定)
ペンの色 0          ; ペンの色を黒に (0x000000)
ペンの色 なんでも       ; でたらめな色
ペンの色 [5]                ; ペンの色を赤に指定 (色識別子による設定、「色の定数」を参照)
ペンの色 “見えない”     ; 枠線なしの図形を書くための見えないペン

ペンのつなぎ方 (PENJOINT)

ペンのつなぎ方 “角を丸くする”   ; 丸まった角(デフォルト)
ペンのつなぎ方 “角をとがらせる”       ; 尖った角
ペンのつなぎ方 “角を落とす”         ; 尖った部分を落とした角
ペンのつなぎ方 “なし”            ; 線を繋げない角

ペンの種類 (PENSTYLE)

ペンの種類 “実線” ; 実線(デフォルト)
ペンの種類 “点線”      ; 点線
ペンの種類 “破線”      ; 破線

; 自作の点線-破線パターン:引数として与えられたリストによって定義される:
; – 並ぶ点の数
; – 並んでいる点の長さ
; – 並ぶ破線 (短い線) の数
; – 並んでいる破線の長さ
; – 点線と破線の間の距離
; – タイプ (オプション):
;   0 = 点は長方形 (デフォルト)
;   2 = 点は正方形 (長さと距離は「ペンの大きさ」の相対値)

ペンの種類 [3, 1mm, 2, 4mm, 2mm, 2]  ; ...––...––...––

塗りつぶしの設定

塗りつぶしの色 (FILLCOLOR/fc)

塗りつぶしの色 “青”        ; 青色で塗りつぶす。「ペンの色」も参照のこと
塗りつぶしの色 “invisible” CIRCLE 10   ; unfilled circle

塗りつぶしの模様 (FILLSTYLE)

塗りつぶしの模様 0         ; ベタ塗り(デフォルト)
塗りつぶしの模様 1              ; 黒の一本線 (水平方向)
塗りつぶしの模様 2              ; 黒の一本線 (45 度方向)
塗りつぶしの模様 3              ; 黒の一本線 (-45 度方向)
塗りつぶしの模様 4              ; 黒の一本線 (垂直方向)
塗りつぶしの模様 5              ; 赤の十字線 (45 度方向)
塗りつぶしの模様 6              ; 赤の十字線 (0 度方向)
塗りつぶしの模様 7              ; 青の十字線 (45 度方向)
塗りつぶしの模様 8              ; 青の十字線 (0 度方向)
塗りつぶしの模様 9              ; 青の三角パターン (縦横斜め)
塗りつぶしの模様 10             ; 黒の線の間が広いパターン (45 度)

; 自作のパターンは次の引数のリストによって指定可能:
; – スタイル (1 = 一本線, 2 = 二本線, 3 = 三角パターン)
; – 色
; – 距離
; – 角度

塗りつぶしの模様 [2, “緑”, 3pt, 15°]     ; 緑の十字線 (15 度方向)

オブジェクトの描画

円 (CIRCLE)

円 100      ; 円の形を描く (直径 = 100pt)

楕円 (ELLIPSE)

楕円 [50, 100]                       ; 短径 50、長径 100 の楕円を描く
楕円 [50, 100, 2h, 12h]           ; 楕円の一部分(扇形)を描く (時計の2時方向から12時方向に)
楕円 [50, 100, 2h, 12h, 2]        ; 楕円の一部分を切り落とした図形を描く
楕円 [50, 100, 2h, 12h, 3]        ; 楕円の一部分を切り落とした外周を描く

正方形 (SQUARE)

正方形 100    ; 正方形を描く (サイズ = 100pt)

長方形 (RECTANGLE)

長方形 [50, 100]      ; 長方形を描く (50×100pt)
長方形 [50, 100, 50]       ; 角を丸めた長方形を描く (第三引数は角の半径)

点 (POINT)

点          ; ペンで指定された大きさと色で点を描く

ラベル (LABEL)

ラベル “あいうえお”        ; タートルの位置に文字を書く
ラベル 'あいうえお'     ; 上と同じ
ラベル "あいうえお      ; 上と同じ (空白を含まないものに限る

文字 (TEXT)

円 10 文字 “あいうえお”    ; 描かれたオブジェクトの真上に文字を乗せる

文字(フォント)の設定

文字の色 (FONTCOLOR)

文字の色 “緑”   ; 文字の色を設定

文字の種類 (FONTFAMILY)

文字の種類 “Linux Libertine G”          ; 文字の種類 (フォントファミリー) を設定
文字の種類 “Linux Libertine G:smcp=1”        ; 同じく文字種の設定 (スモールキャップス = 字体はすべて大文字で小文字に)
文字の種類 “Linux Libertine G:smcp=1&onum=1”; スモールキャップス + オールドスタイル

文字の大きさ (FONTSIZE)

文字の大きさ 12  ; 大きさ (高さ) を 12pt にセット

文字の太さ (FONTWEIGHT)

文字の太さ “太く” ; 太字に設定
文字の太さ “ふつう”     ; 普通の文字に設定

文字の書き方 (FONTSTYLE)

文字の書き方 “斜め”                ; 斜体を指定
文字の書き方 “ふつう”    ; ふつうの文字を指定

図 (PICTURE)

図は以下のように使われます:

  • 描画した図形をグルーピングする
  • 線を一旦区切る
  • 左端の図形の場所と線の形を確実にする

図形のグルーピング

; 図 [ LibreLogo_のコマンド ]
図 [ すすむ 100 円 100 ]     ; 木のような形をグループに

LibreOffice Writer のヘルプの「グループ」も参照のこと

動きを作る tree location
ペンを上げる 位置 location 進む向き 0 ペンを下ろす
図 [ すすむ 100 円 100 ]     ; 木のような形をグループに
おわり

図 [ tree [30, 50] tree [100, 50] ]      ; グループ化した図形をさらにグループ化

線を一旦区切る

図                          ; 新しい線を始める
すすむ 10 図 すすむ 10 ; 二個目の「図」で線が別れる

左端からはみ出ないようにする

図形と線の形状を Writer の左端からはみ出ないようにする

図 [ 円 20 位置 [-100, 100] 円 20 ] ; 位置 [-100, 100] でもはみ出ないように「図」全体を調整してくれる

ループ(繰り返し)

くりかえす (REPEAT)

; くりかえす <数> [ <コマンド> ]

くりかえす 10 [ すすむ 10 左 45 円 10 ]   ; 10 回繰り返す
; 数値は省略できる

くりかえす [ 位置 なんでも ]       ; 終わらない繰り返し

くりかえした数 (REPCOUNT)

くりかえし変数 (ひとつずつ (FOR) と くりかえすのは次の間 (WHILE) でも有効)。

くりかえす 100 [ すすむ くりかえした数 左 90 ]

ひとつずつ … を次から取り出して (FOR IN)

リストの各要素に対して繰り返しを行う:

ひとつずつ i を次から取り出して [1, 5, 7, 9, 11] [
  すすむ i
  左 90
]

文字の並びから一文字ずつ取り出して繰り返す:

ひとつずつ i を次から取り出して “text” [
  ラベル i
  すすむ 10
]

くりかえすのは次の間 (WHILE)

くりかえすのは次の間 真 [ 位置 なんでも ]   ; 終わらない繰り返し
くりかえすのは次の間 くりかえした数 <= 10 [ すすむ 50 左 36 ]     ; くりかえす 10 [ ... ] と同じ

くりかえしから出る (BREAK)

くりかえしをやめる。

くりかえす [                    ; 終わらない繰り返し
  位置 なんでも
  もし くりかえした数 = 100 [ くりかえしから出る ]  ; くりかえす 100 [ ... ] と同じ
]

はじめにもどる (CONTINUE)

次のくりかえしを頭から始める

くりかえす 100 [
  位置 なんでも
  もし くりかえした数 % 2 <> 0 [ はじめにもどる ]
  円 10  ; 2回に1回、円を描く
]

条件判断など

もし (IF)

; もし condition [ 真のときのブロック ]
; もし condition [ 真のときのブロック ] [ 偽のときのブロック ]

もし a < 10 [ 表示 “小さい” ]
もし a < 10 [ 表示 “小さい” ] [ 表示 “大きい” ]

と、または、次が正しくない (AND, OR, NOT)

論理演算子

もし a < 10 と 次が正しくない a < 5 [ 表示 “5 または, 6, 7, 8, 9” ]

サブルーチン

動きを作る、おわり (TO, END)

新しい「語」(プロシージャ)を作る (日本語注:残念ながら日本語の「語(動き)」は作ることができません。)

動きを作る triangle
くりかえす [ すすむ 100 右 120 ] 塗りつぶす
おわり

くりかえす 10 [ triangle ペンを上げる 場所 なんでも ペンを下ろす ]

値を返す (OUTPUT)

変数の値を返す

動きを作る randomletter
値を返す でたらめな数 “qwertzuiopasdfghjklyxcvbnm”


表示 randomletter + randomletter + randomletter   ; でたらめな文字を3文字表示する

動きから出る (STOP)

プロシージャから帰る

動きを作る example number
  もし number < 0 [ 動きから出る ]
  表示 平方根 number         ; 平方根を表示する
]

example 100
example -1      ; 「動きから出る」がなかったらエラーになる
example 25

標準の定数

なんでも (ANY)

色や場所など、でたらめな値

ペンの色 何でも   ; でたらめなペンの色

真 (TRUE)

論理値

くりかえすのは次の間 真 [ 位置 なんでも ]   ; いつまでもくりかえす
表示 真    ; 「真」を表示する

偽 (FALSE)

論理値

くりかえすのは次の間 次が正しくない 偽 [ 位置 なんでも]    ; いつまでもくりかえす
表示 偽    ; 「偽」を表示する

ページサイズ (PAGESIZE)

表示 ページサイズ  ; ポイントで表現されたページサイズを表示する。例えば: [595.30, 841.89]

円周率 (PI/π)

表示 円周率     ; 3.14159265359 を表示

入出力

表示 (PRINT)

表示 “ほげ”    ; “ほげ”をダイアログボックスとして表示
表示 5 + 10       ; 15 を表示

値を聞く (INPUT)

表示 値を聞く “入力する値は?”  ; 問い合わせ用のダイアログボックスを表示し、その入力結果をダイアログボックスに表示する
表示 小数 (値を聞く “最初の値は?”) + 小数 (値を聞く “二番目の値は”) ; 簡単な電卓プログラム

次の間待つ (SLEEP)

次の間待つ 1000 ; 1000 ms (= 1 秒) の間待つ

どこからでも見える (GLOBAL)

プロシージャ内で宣言した変数をどこからでも(グローバルに)参照できるようにする

どこからでも見える about
about = “LibreLogo”

動きを作る example
  表示 about
  どこからでも見える about       ; 新しい値に更新したいときにはこう書く
  about = “どこからでも見える変数に新しい値を設定”
END

example
表示 about

組み込み関数

でたらめな数 (RANDOM)

表示 でたらめな数 100              ; でたらめな浮動小数点数 (0 <= x < 100)
表示 でたらめな数 “text”        ; “text”内の適当な文字一つ
表示 でたらめな数 [1, 2]        ; リストの要素のなかで適当な一つ (1 または 2)

切り捨て (INT)

表示 切り捨て 3.8                        ; 3 が表示される (3.8 の整数部)
表示 切り捨て でたらめな数 100      ; でたらめな整数 (0<= x < 100)
表示 切り捨て “7”                     ; 文字パラメータを整数に変換する

小数 (FLOAT)

; 文字列を浮動小数点数に
表示 2 * 小数 “5.5” ; 11.0 が表示される

文字列 (STR)

; 数値パラメータを文字列にする
表示 “結果:” + STR 5        ; 表示 “結果:5”
表示 10 * STR 5           ; 表示 5555555555

平方根 (SQRT)

表示 平方根 100                 ; 100の平方根は10なので10が表示される

SIN

表示 SIN 90 * PI/180 ; 表示 1.0 (ラジアンの 90 * PI/180 = 90°で、その sin なので)

COS

表示 COS 0 * PI/180  ; 表示 1.0 (ラジアンの 0 * PI/180 = 0°で、その cos なので)

四捨五入 (ROUND)

表示 四捨五入 3.8                        ; 表示 4 (3.8 の四捨五入)
表示 四捨五入 でたらめな数 100      ; でたらめな整数 (0<= x <= 100)

絶対値 (ABS)

表示 絶対値 -10         ; 表示 10, -10 の絶対値

文字数 (COUNT)

表示 文字数 “text”      ; 表示 4, “text”の文字数
表示 文字数 [1, 2, 3]        ; 表示 3, リストの大きさ

集合 (SET)

; リストを Python の集合に変換
表示 集合 [4, 5, 6, 6]      ; 表示 {4, 5, 6}
表示 集合 [4, 5, 6, 6] | 集合 [4, 1, 9]       ; 表示 {1, 4, 5, 6, 9} "|" は和集合
表示 集合 [4, 5, 6, 6] & 集合 [4, 1, 9]   ; 表示 {4} "&" は積集合
表示 集合 ([4, 5, 6, 6]) - 集合 [4, 1, 9]     ; 表示 {5, 6} "-" は差集合 List の演算子でもあるので () でくくる必要あり
表示 集合 [4, 5, 6, 6] ^ 集合 [4, 1, 9]       ; 表示 {1, 5, 6, 9}, "^" は対称差 

範囲 (RANGE)

; Python 風にリストを作る
表示 範囲 10                ; 表示 [0, 1, 2, 3, 4, 5, 6, 7, 8, 9]
表示 範囲 3 10              ; 表示 [3, 4, 5, 6, 7, 8, 9]
表示 範囲 3 10 3    ; 表示 [3, 6, 9]

ひとつずつ i を次から取り出して 範囲 10 50 10 [ ; [10, 20, 30, 40] を順にくりかえす
  すすむ i
  左 90
]

リスト (LIST)

; 同じ要素を一度集合にしてからリストに再変換することで消去する
表示 リスト (集合 [1, 3, 5, 5, 2, 1])  ; 表示 [1, 3, 5, 2]

変更できないリスト (TUPLE)

Python のタプル (変更不能のリスト) に変換する

表示 変更できないリスト [4, 5]

並び替える (SORTED)

並び替えられたリストを返す

表示 並べ替える [5, 1, 3, 4]      ; 表示 [1, 3, 4, 5]

文字のおきかえ (SUB)

正規表現 (regex; regular expression) のパターンを用いて文字列を置き換える

表示 文字のおきかえ (“t”, “T”, “text”)      ; 表示 “Text”, 文字“t”が“T”に置き換えられている
表示 文字のおきかえ (“(.)”, “\\1\\1”, “text”) ; 表示 “tteexxtt”, "(.)" は「任意の一文字にマッチ」、"\\1" は「マッチした文字列」なので文字の重ね打ちになる

探す (SEARCH)

正規表現 (regex; regular expression) のパターンを用いて文字の並びを探す

もし 探す (“\w”, word) [ 表示 “word 変数の中に単語があります。” ]

見つかったものを全部ならべる (FINDALL)

正規表現 (regex; regular expression) のパターンを用いて、与えられた文字列中にマッチするものをすべてリストで列挙する

表示 見つかったものを全部ならべる(“\w+”, “Dogs, cats.”)    ; 表示 [“Dogs”, “cats”], "\w+" は単語を示すパターンなのですべての単語を列挙

いちばん小さな数 (MIN)

表示 いちばん小さな値 [1, 2, 3]      ; 表示 1, リスト中で最小の要素

いちばん大きな数 (MAX)

表示 いちばん大きな値 [1, 2, 3]      ; 表示 3, リスト中で最大の要素

色定数

ペンの色 “銀”   ; 文字列での指定
ペンの色 [1]                ; 番号による指定
0 黒 (BLACK)
1 銀 (SILVER)
2 灰色 (GRAY)
3 白 (WHITE)
4 くり色 (MAROON)
5 赤 (RED)
6 紫 (PURPLE)
7 明るい紫 (MAGENTA)
8 緑 (GREEN)
9 明るい緑 (LIME)
10 柿色 (OLIVE)
11 黄 (YELLOW)
12 濃い青 (NAVY)
13 青 (BLUE)
14 マガモ色 (TEAL)
15 アクア (AQUA)
16 ピンク (PINK)
17 トマト (TOMATO)
18 オレンジ (ORANGE)
19 金 (GOLD)
20 すみれ色 (VIOLET)
21 空色 (SKYBLUE)
22 薄い茶色 (CHOCOLATE)
23 茶色 (BROWN)
24 見えない (INVISIBLE)