Documentazione/Funzioni di Calc/NUM.CED

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/COUPNUM and the translation is 100% complete.
    Other languages:

    Nome funzione:

    NUM.CED

    Categoria:

    Analisi finanziaria

    Riepilogo:

    Calcola il numero di pagamenti di cedole in sospeso da effettuare nel periodo compreso tra la data di regolamento di un'obbligazione e la sua data di scadenza.

    Sintassi:

    NUM.CED(Liquidazione; Scadenza; Frequenza[; Base])

    Restituisce:

    Restituisce un numero intero positivo, ovvero il numero di date della cedola tra la data di regolamento e la data di scadenza.

    Argomenti:

    Liquidazione è una data (tra virgolette) o un numero seriale data-ora, o un riferimento a una cella contenente uno di questi tipi, che specifica quando un'operazione è "regolata". In questa data il venditore completa il trasferimento dell'obbligazione all'acquirente e l'acquirente effettua il pagamento appropriato al venditore.

    Scadenza è una data (tra virgolette) o un numero seriale data-ora, o un riferimento a una cella contenente uno di quei tipi, che specifica quando l'obbligazione scade. Alla scadenza, l'emittente dell'obbligazione deve rimborsare al detentore dell'obbligazione l'intero importo dell'obbligazione.

    Frequenza è un numero intero positivo, o un riferimento a una cella contenente tale numero intero, ovvero il numero di cedole pagate all'anno. I valori validi sono 1 (annuale), 2 (semestrale) o 4 (trimestrale).

    Base è un numero intero da 0 a 4 o un riferimento a una cella contenente quell'intero, che viene scelto da un elenco di opzioni e indica come calcolare l'anno. Per ulteriori informazioni, visitate la pagina [1] di Wikipedia.

    Base Calcolo
    0 o omesso Metodo USA (NASD), 12 mesi di 30 giorni ciascuno
    1 Numero esatto di giorni nei mesi, numero esatto di giorni nell'anno.
    2 Il numero esatto di giorni nel mese, l'anno ha 360 giorni.
    3 Il numero esatto di giorni nel mese, l'anno ha 365 giorni.
    4 Metodo europeo, 12 mesi da 30 giorni ciascuno.
    • Se Liquidazione o Scadenza non è un'espressione di data valida, allora NUM.CED riporta un errore #VALORE!.
    • Se la data Liquidazione è uguale o successiva alla data Scadenza allora NUM.CED riporta un errore di argomento non valido (Err:502).
    • Se Frequenza non è numerica, allora NUM.CED riporta un errore #VALORE!.
    • Se Base non è numerico, allora NUM.CED riporta un errore di argomento non valido (Err:502).
    • Se Base o Frequenza è un valore non intero, allora NUM.CED lo tronca a un valore intero.
    • Se, dopo ogni troncamento, Frequenza non è uguale a 1, 2 o 4, allora NUM.CED riporta un errore di argomento non valido (Err:502).
    • Se, dopo ogni troncamento, Base non è uguale a 0, 1, 2, 3 o 4, allora NUM.CED riporta un errore di argomento non valido (Err:502).

    Altri dettagli:

    • NUM.CED esegue il seguente calcolo:
    • Richiama la funzione DATA.CED.PREC per determinare la data dell'ultima cedola prima o nella data di liquidazione.
    • Calcola il numero di mesi tra la data della cedola e la data di scadenza dell'obbligazione.
    • Calcola il numero di periodi cedolari tra la data di regolamento e la data di scadenza come:
    [math]\displaystyle{ Coupon~Periods~Remaining~=~Months \times \frac {Frequency}{12} }[/math]


    • Gli esempi in questa pagina usano il formato standard ISO 8601 per le date in quanto questo dovrebbe essere indipendente dalla impostazioni locali selezionate. Il formato predefinito per le date sul vostro computer potrebbe essere diverso. Evitate di usare dei formati per le date dipendenti dalle impostazioni locali che possono generare degli errori nel caso in cui il documento venisse caricato con impostazioni locali differenti. Spesso è buona pratica utilizzare la funzione DATA anziché digitare dei valori formattati per le date.
    • Se uno tra Liquidazione o Scadenza comprende dei componenti relativi all'orario, questi sono ignorati dalla GIORNI.CED.INIZ.LIQ.
    • Per maggiori informazioni relative alle cedole, visitate la pagina di Wikipedia Obbligazione (finanza).

    Esempi:

    Formula Descrizione Restituisce
    =NUM.CED(A1; A2; A3; A4) dove la cella A1 contiene la data 01-09-2022, la cella A2 contiene la data 15-11-2025, la cella A3 contiene il numero 2 e la cella A4 contiene il numero 3. Un investitore acquista un'obbligazione con una data di scadenza del 15-11-2025, con l'operazione regolata il 01-09-2022. L'obbligazione paga interessi ogni sei mesi e la convenzione di conteggio dei giorni applicabile è la base 3 (numero esatto di giorni nel mese, 365 giorni nell'anno). Qui la funzione calcola che restano da effettuare sette pagamenti di cedole dopo la data di regolamento e prima o alla data di scadenza. 7
    =NUM.CED("2022-09-01"; "2025-11-15"; 2) Un investitore acquista un'obbligazione con una data di scadenza del 15-11-2025, con l'operazione regolata il 01-09-2022. L’obbligazione paga interessi ogni sei mesi. Poiché il quarto argomento viene omesso, NUM.CED utilizza per impostazione predefinita una convenzione di conteggio dei giorni su base 0 (12 mesi di 30 giorni ciascuno). Anche in questo caso la funzione calcola che restano da effettuare sette pagamenti di cedole dopo la data di regolamento e prima o alla data di scadenza. 7
    =NUM.CED(DATA(2022; 9; 1); DATA(2025; 11; 15); 2) Qui la formula esegue la stessa funzione dell'esempio precedente ma utilizza la funzione DATA invece di digitare valori di data formattati. 7
    =NUM.CED(44805; 45976; 2) Calc tratta le date come numeri, dove ogni data corrisponde a un numero seriale data-ora. Supponendo che l'opzione Data in Strumenti ▸ Opzioni ▸ LibreOffice Calc ▸ Calcola (LibreOffice ▸ Preferenze ▸ LibreOffice Calc ▸ Calcola su macOS) sia impostata sul suo valore predefinito, 44805 è il numero di serie data-ora per 01-09-2022 e 45976 è il numero di serie data-ora per 15-11-2025. Qui la formula svolge la stessa funzione dell'esempio precedente. 7

    Funzioni di LibreOffice correlate:

    GIORNI.CED.INIZ.LIQ

    GIORNI.CED

    GIORNI.CED.NUOVA

    DATA.CED.SUCC

    DATA.CED.PREC

    Standard ODF:

    Section 6.12.9, part 2

    Funzioni equivalenti (o simili) di Excel:

    COUPNUM