Dokumentation/Calc Funktionen/WVERWEIS

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/HLOOKUP and the translation is 100% complete.
    Other languages:


    Funktionsname:

    WVERWEIS

    Kategorie:

    Tabelle

    Zusammenfassung:

    Führt eine waagerechte Suche auf eine spezifizierte Datentabelle aus. Vergleicht ein gegebenes Suchkriterium mit den Einträgen in der ersten Zeile der Datentabelle und, wenn ein Treffer gefunden wird, wird der Inhalt der Zelle in der selben Spalte wie der Treffer aber in einer anderen Zeile zurückgegeben.

    Der Suchprozess verwendet entweder Platzhalter oder reguläre Ausdrücke. Standardmässig ist die Suche nicht case-sensitiv. Eine case-sensitive Suche kann unter Verwendung eines regulären Ausdruckes durchgeführt werden.

    Falls die Daten senkrecht organisiert sind und Vergleichsdaten in der ersten Spalte haben, wird SVERWEIS statt WVERWEIS verwendet.

    Syntax:

    WVERWEIS(Suchkriterium; Feld; Index[; sortierter Suchbereich])

    Rückgabewerte:

    Gibt den Inhalt einer Zelle zurück, die in der selben Spalte wie die Trefffer-Zelle liegt, aber in einer anderen Zeile. Die zurückgegebenen Daten können numerisch oder nicht numerisch sein.

    Argumente:

    Suchkriterium ist ein Text (in Anführungszeichen), eine Zahl oder eine Referenz auf eine Zelle mit einer dieser Typen. Suchkriterium wird mit den Inhalten der Zellen in der ersten Zeile des Arrays verglichen, um die interessante Spalte zu ermitteln.

    Feld spezifiziert den Zellbereich, den die Datentabelle belegt. Dieser Bereich kann durch Eingabe des Zellbezuges der Zelle oben links, gefolgt von einem Doppelpunkt (:) und dem Zellbezug der Zelle unten rechts (z. Bsp. A1:E10) definiert werden. Feld kann auch durch Angabe des benannten Bereiches oder des Datenbankbereiches spezifiziert werden. Es ist auch möglich, das Feld als Aufzählung anzugeben.

    Index ist eine positive Ganzzahl oder eine Referenz auf eine Zelle, die diese Zahl enthält Diese Zahl zeigt die Zeile, die die zurückzugebenden Daten enthält. Die erste Zeile hat den Index 1. Index kann nicht größer als die Anzahl der Zeilen im Feld sein.

    Der sortierte Suchbereich ist ein logischer Wert (WAHR oder FALSCH) oder eine Referenz auf eine Zelle mit dem Wert. Dieser Wert zeigt, ob die Daten in der ersten Zeile des Feldes korrekt sortiert sein sollten (wie im Abschnitt #Zusätzliche Informationen: beschrieben).

    • Falls der sortierte Suchbereich auf 0 oder FALSCH steht, dann sind die Daten in der ersten Zeile des Feldes unsortiert und WVERWEIS sucht nach einem exakten Treffer.
    • Falls der sortierte Suchbereich entweder fehlt oder auf WAHR oder auf irgendeinem anderen numerischen Wert als 0 steht, dann sind die Daten in der ersten Zeile des Feldes sortiert und WVERWEIS kann sowohl nach exakten oder nach ungefähren (best-fit; entweder exakt oder nicht) Treffern suchen.

    Die folgenden Fälle können eintreten:

    • Falls der Index nicht-numerisch ist, dann meldet WVERWEIS einen #WERT! Fehler.
    • Falls der Index keine Ganzzahl ist, dann verkürzt sie WVERWEIS auf eine Ganzzahl.
    • Falls der Index nach einer Verkürzung kleiner als 1 oder größer als die Anzahl an Zeilen im Index ist, dann meldet WVERWEIS einen invalid argument error (Fehler:502).
    • Falls der sortierte Suchbereich WAHR ist, aber die Zellen in der ersten Zeile nicht wie erwartet sortiert sind, ist das Ergebnis von WVERWEIS nicht vorhersehbar. In solchen Fällen kann es sein, dass kein Fehler gemeldet wird und das Ergebnis nicht offensichtlich bedeutungslos ist.
    • Falls der sortierte Suchbereich FALSCH ist und kein exakter Treffer für das Suchkriterium gefunden wird, meldet WVERWEIS einen #NV (Wert nicht verfügbar) Fehler.
    • Falls der sortierte Suchbereich WAHR ist und das Suchkriterium vor der ersten Zelle in der ersten Zeile der Datentabelle fündig würde, dann meldet WVERWEIS einen #NV (Wert nicht verfügbar) Fehler.

    Zusätzliche Informationen:

    Spezifische Eigenheiten der Funktion WVERWEIS

    • Falls der sortierte Suchbereich FALSCH ist und die erste Zeile der Tabelle mehrere Zellen mit dem gleichen Inhalt hat, wird WVERWEIS nur den Eintrag in der ersten Zelle (der ersten Zeile im Feld) als Treffer liefern.
    • Falls der sortierte Suchbereich WAHR ist, muss die erste Zeile der Datentabelle sortiert sein. Zunächst kommen also die Zahlen in aufsteigender Folge, dann die Texte in alphabetischer Reihenfolge. Falls die erste Zeile nicht wirklich sortiert ist, ist das Ergebnis unberechenbar. WVERWEIS berechnet, wo in der ersten Zeile das Suchkriterium in der (erwartet) sortierten Reihenfolge auftaucht.
      • Falls es einen exakten Treffer des Suchkriteriums in der ersten Zeile gibt, wird diese Spalte genutzt, um den Rückgabewert zu ermitteln.
      • Falls es keinen genauen Treffer zwischen Suchkriterium und den Einträgen der ersten Zeile gibt, wird die Spalte links vom Suchkriterium genutzt.
    • Falls ein regulärer Ausdruck im Bereich Platzhalter in Formeln im Dialog Extras ▸ Optionen... ▸ LibreOffice Calc ▸ Berechnen (oder LibreOffice ▸ Preferences ▸ LibreOffice Calc ▸ Berechnen unter macOS) ermöglicht wurde, dann wird WVERWEIS exakte Trefffer für den regulären Ausdruck als Suchkriterium finden. Das macht nur Sinn wenn der sortierte Suchbereich FALSCH ist.
    • Falls Platzhalter im Bereich Platzhalter in Formeln im Dialog Extras ▸ Optionen... ▸ LibreOffice Calc ▸ Berechnen (oder LibreOffice ▸ Preferences ▸ LibreOffice Calc ▸ Berechnen unter macOS) ermöglicht wurden, dann findet WVERWEIS exakte Treffer für das Suchktiterium als regulärer Ausdruck. Das macht nur Sinn wenn der sortierte Suchbereich FALSCH ist.
    • Falls die Option Suchkriterien = und <> müssen auf ganze Zellen zutreffen in den Allgemeinen Berechnungen im Dialog Extras ▸ Optionen... ▸ LibreOffice Calc ▸ Berechnen (oder LibreOffice ▸ Preferences ▸ LibreOffice Calc ▸ Berechnen unter macOS) angekreuzt ist, dann muss das Suchkriterium mit dem ganzen Text in der Zelle übereinstimmen. Wenn nicht, dann reicht es, wenn ein Teil des Textes stimmt.
    • Die Option Groß- und Kleinschreibung in den Allgemeinen Berechnungen im Dialog Extras ▸ Optionen... ▸ LibreOffice Calc ▸ Berechnen (oder LibreOffice ▸ Preferences ▸ LibreOffice Calc ▸ Berechnen unter macOS) hat keine Auswirkung auf die Operation WVERWEIS. Standartdmäßig ist WVERWEIS nicht case-sensitiv, es sei denn eine case-sensitive Suche wird durch einen spezifischen regulären Ausdruck angestossen.


    Allgemeine Informationen über die regulären Ausdrücke in Calc

    Note pin.svg

    Anmerkung:
    Der Einfachheit halber werden die Informationen dieses Unterabschnittes auf allen Seiten der Funktionen in Calc wiederholt, die reguläre Ausdrücke bearbeiten.

    • Ein regulärer Ausdruck ist eine Zeichenkette die ein Textmuster beschreibt. Genauere allgemeine Hintergrundinformationen finden sich in der Wiki Regulärer Ausdruck
    • Reguläre Ausdrücke sind weit verbreitet. Dabei gibt es viele Prozessoren für reguläre Ausdrücke. Calc nutzt den open source Regular Expressions package from the International Components for Unicode (ICU). Siehe bitte unter deren Dokumentation zu den regulären Ausdrücken für weitergehende Informationen inklusive der volständigen Beschreibung zur Syntax der ICU Regular Expressions.
    • Zusätzlich stellt die LibreOffice Hilfe eine umfangreiche Liste der regulären Ausdrücke zur Verfügung.
    • Calcs Generator für reguläre Ausdrücke unterstützt zahlreiche Erfassungs Möglichkeiten, welche es Untergruppen in einem Bereich erlauben innerhalb eines Treffers identifiziert zu werden und in einem Text ersetzt werden können. Runde Klammern werden genutzt um Komponenten eines regulären Ausdruckes zu gruppieren und eine nummerierte Treffer-Liste zu erzeugen. Um eine solche Treffer-Liste in einen Text einzufügen, verwenden Sie bitte das Kürzel "$n", wobei n die Zahl der Treffer-Liste ist.

    Allgemeine Informationen über die Platzhalter in Calc

    Platzhalter sind spezielle Zeichen für Suchtexte in Argumenten für einige Funktionen in Calc; sie können auch im Suchdialog verwendet werden. Der Gebrauch von Platzhaltern ermöglicht fortgeschrittenere Suchparamter bei einer einfachen Textsuche.

    Calc unterstützt entweder Platzhalter oder reguläre Ausdrücke abhängig von den Einstellungen der aktuellen Applikation. Standardmäßig werden Platzhalter statt regulärer Ausdrücke unterstützt.

    Um sicherzustellen, dass Platzhalter unterstützt werden, rufen Sie Extras ▸ Optionen... ▸ LibreOffice Calc ▸ Berechnen auf. Überprüfen Sie hier, ob die Einstellung Platzhalter in Formeln ermöglichen ausgewählt ist. Beachten Sie auch, dass reguläre Ausdrücke durch Auswählen von Reguläre Ausdrücke in Formeln ermöglichen unterstüzt werden können. Genauso können Sie weder Platzhalter noch reguläre Ausdrücke unterstützen lassen.

    Die folgende Tabelle zeigt die Platzhalter, die Calc unterstützt.

    Calc wildcards
    Platzhalter Beschreibung
    ? (Fragezeichen) Vertritt ein einzelnes Zeichen. Zum Beispiel kann der Suchtext "b?g" "bag" oder "beg" heißen, aber nicht "boog" oder "mug".

    Beachte, dass es auch nicht "bg" heißen kann, da "?" genau ein Zeichen sein muss. Der Platzhalter "?" vertritt kein fehlendes Zeichen.
    * (Asterisk) Vertritt eine Reihe von Zeichen inklusive dem Leer-Text. Zum Beispiel vertritt der Text "*cast" "cast", "forecast" und "outcast", aber nicht "forecaster" unter Verwendung der Standardeinstellungen von Calc.

    Falls die Einstellung Suchkriterien = und <> müssen auf ganze Zellen zutreffen in Extras ▸ Optionen ▸ LibreOffice Calc ▸ Berechnen ausgeblendet ist, dann wird "forecaster" auch durch *cast vertreten.
    ~ (Tilde) Unterdrückt die Sonderbehandlung des Fragezeichens Asterisken oder der Tilde, welche direkt nach der Tilde kommen.

    Zum Beispiel, stellt der Suchstring "why~?" nur "why?" und nicht "whys" oder "why~s" dar.

    Platzhalter sind nicht case sensitiv, also "A?" heißt sowohl "A1" also auch "a1".

    Diese Platzhalter werden sowohl in Calc als auch in Microsoft EXCEL unterstützt. Wenn also Kompatibilität zwischen den beiden Anwendungen erforderlich ist, arbeiten Sie mit Platzhaltern anstatt mit regulären Ausdrücken. Wenn dagegen Kompatibilität nicht notwendig ist, arbeiten Sie stattdessen mit regulären Ausdrücken für mächtigere Möglichkeiten.

    Beispiele:

    Die folgende Tabelle ist ein echtes Beispiel einer unsortierten Tabelle mit Daten aus dem Periodensystem der chemischen Elemente.

    A B C D E F G H I J K
    1 Element Wasserstoff Helium Lithium Beryllium Bor Kohlenstoff Stickstoff Sauerstoff Flour Neon
    2 Symbol H He Li Be B C N O F Ne
    3 Kernladungszahl 1 2 3 4 5 6 7 8 9 10
    4 Relative Atommasse 1,008 4,003 6,94 9,012 10,81 12,011 14,007 15,999 18,998 20,18

    Die folgenden Beispiele nutzen die obige Tabelle. In den meisten Fällen steht der sortierte Suchbereich auf 0 (FALSCH), so dass WVERWEIS nach einer exakten Übereinstimmung in der unsortierten Tabelle sucht.

    Formel Beschreibung Ergebnis
    =WVERWEIS("Helium"; $B$1:$K$4; 2; 0)

    Die Funktion findet den Text "Helium" in der ersten Zeile der Datentabelle (Zelle C1) und gibt die Daten aus der Zelle im Schnittpunkt dieser Spalte und der zweiten Zeile der Tabelle (Zelle C2) zurück. Das Symbol für Helium wird zurückgegeben.

    He
    =WVERWEIS("Kohlenstoff"; $B$1:$K$4; 3; 0)

    Die Funktion findet den Text "Kohlenstoff" in der ersten Zeile der Datentabelle (Zelle G1) und gibt die Daten aus der Zelle im Schnittpunkt dieser Spalte und der dritten Zeile der Tabelle (Zelle G3) zurück. Die Kernladungszahl für Kohlenstoff wird zurückgegeben.

    6
    =WVERWEIS("Sauerstoff"; $B$1:$K$4; 4,6; 0)

    Die Funktion findet den Text "Sauerstoff" in der ersten Zeile der Datentabelle (Zelle I1) und gibt die Daten aus der Zelle im Schnittpunkt dieser Spalte und der vierten Zeile der Tabelle (Zelle I4) zurück - der Index von 4,6 wird verkürzt auf 4. Die relative Atommasse von Sauerstoff wird zurückgegeben.

    15,999
    =WVERWEIS("Neon"; $B$1:$K$4; 2; WAHR())

    Dieses Beispiel zeigt die Verwirrung, die auftritt, wenn der sortierte Suchbereich (standardmässig) auf WAHR gesetzt ist und die Tabelle nicht in der erwarteten Reihenfolge sortiert ist. Die Formel gibt den (unvorhersehbaren) Text "C" statt dem erwarteten "Ne" zurück.

    C

    =WVERWEIS("^bo.*"; $B$1:$K$4; 4; 0)
    mit ermöglichten regulären Ausdrücken.

    Die Funktion findet den Text "^bo.*" in der ersten Zeile der Datentabelle (Zelle F1) und gibt die Daten aus der Zelle im Schnittpunkt dieser Spalte und der vierten Zeile der Tabelle (Zelle F4) zurück. Die relative Atommasse für Bor wird zurückgegeben.

    10,81

    =WVERWEIS("sti*"; $B$1:$K$4; 4; 0)
    mit ermöglichten Platzhaltern.

    Die Funktion findet den Text "sti*" in der ersten Zeile der Datentabelle (Zelle H1) und gibt die Daten aus der Zelle im Schnittpunkt dieser Spalte und der vierten Zeile der Tabelle (Zelle H4) zurück. Die relative Atommasse für Stickstoff wird zurückgegeben.

    14,007

    Die folgende Tabelle zeigt die Verkaufsdaten für eine kleine Firma. Vier Spalten (benannt mit 1 bis 4) zeigen die gesamten Verkäufe in jedem Quartal des Jahres und die Namen der Top Verkäufer des Quartals. Vier Spalten (benannt mit E_reg, N_reg, S_reg und W_reg) zeigen die gesamten Verkäufe in jedem Gebiet in diesem Jahr und die Namen der Top Verkäufer in diesem Gebiet in diesem Jahr. Die Daten in der ersten Zeile sind in der beschriebenen Reihenfolge sortiert und spezifizieren in den folgenden Beispielen keinen Wert für den soritierten Suchbereich, wenn WVERWEIS den Standardwert WAHR verwendet.

    A B C D E F G H I
    1 Kategorie 1 2 3 4 E_reg N_reg S_reg W_reg
    2 Endsumme $27.094 $96.516 $82.485 $48.487 $99.908 $83.535 $46.553 $24.586
    3 Top Verkäufer Samuel Aaron Pippa Ollie Lillian George Zara Kristina
    Formel Beschreibung Ergebnis
    =WVERWEIS(0; $B$1:$I$3; 2)

    Die Funktion sucht die Zahl 0 in der ersten Zeile in der Datentabelle, aber da 0 kleiner als die erste Zahl (1) in der Zeile ist, meldet die Formel einen #NV Fehler.

    #NV
    =WVERWEIS(2,5; $B$1:$I$3; 2)

    Die Funktion sucht die Zahl 2,5 in der ersten Zeile der Datentabelle. Da 2,5 größer als 2 und kleiner als 3 ist, nimmt WVERWEIS die Zahl 2 (entsprechend der Spalte C). Die Formel gibt die Daten aus der Zelle im Schnittpunkt dieser Spalte und der zweiten Zeile der Tabelle (Zelle C2) zurück. Die gesamten Verkäufe für das zweite Quartal werden zurückgegeben.

    96516
    =WVERWEIS(3; $B$1:$I$3; 2)

    Die Funktion sucht die Zahl 3 in der ersten Zeile der Datentabelle (Zelle D1) und gibt die Daten im Schnittpunkt dieser Spalte und der zweiten Zeile der Tabelle (Zelle D2). Die gesamten Verkäufe aus dem dritten Quartal werden zurückgegeben. Die Formel =WVERWEIS("3"; $B$1:$I$3; 2) gibt einen #NV Fehler zurück.

    82485
    =WVERWEIS(123; $B$1:$I$3; 2)

    Die Funktion sucht die Zahl 123 in der ersten Zeile der Datentabelle. Da 123 größer als die (anderen) Zahlen ist, verwendet WVERWEIS Spalte E. Die Formel gibt die DAten aus der Zelle im Schnittpunkt dieser Spalte mit der zweiten Zeile der Tabelle (Zelle E2) zurück. Die gesamten Verkäufe des vierten Quartals wird zurückgegeben.

    48487
    =WVERWEIS("C_reg"; $B$1:$I$3; 3)

    Die Funktion sucht den Text "C_reg" in der ersten Zeile in der Datentabelle, aber da "C_reg" alphabetisch vor dem ersten Eintrag "E_reg" in der Zeile kommt, meldet die Formel einen #NV Fehler.

    #NV
    =WVERWEIS("F_reg"; $B$1:$I$3; 3)

    Die Funktion sucht den Text "F_reg" in der ersten Zeile der Datentabelle. Da "F_reg" alphbetisch nach "E_reg" aber vor "N_reg" kommt, verwendet WVERWEIS die vorherige Spalte F. Die Daten im Schnittpunkt dieser Spalte und der dritten Zeile der Tabelle (Zelle F3) werden zurückgegeben. Der Top-Verkäufer aus dem Gebiet "E_reg" wird zurückgegeben.

    Lillian
    =WVERWEIS("S_reg"; $B$1:$I$3; 3)

    Die Funktion findet den Text "S_reg" in der ersten Zeile der Datentabelle (Zelle H1) und gibt die Daten aus der Zelle im Schnittpunkt dieser Spalte und der dritten Zeile der Tabelle (Zelle H3) zurück. Der Top-Verkäufer aus dem Gebiet "S_reg" wird zurückgegeben.

    Zara
    =WVERWEIS("Zagreb"; $B$1:$I$3; 3)

    Die Funktion sucht den Text "Zagreb" in der ersten Zeile der Datentabelle. Da "Zagreb" alphabetisch nach den aktuellen Texten kommt, verwendet WVERWEIS den letzten Eintrag in der Liste (Spalte I). Die gesamten Verkäufe im Schnittpunkt dieser Spalte und der dritten Zeile der Tabelle (Zelle I3) werden zurückgegeben. Der Top-Verkäufer aus dem Gebiet "W_reg" wird zurückgegeben.

    Kristina

    Das letzte Beispiel zeigt, dass das Feld auch eine Aufzählung sein kann. In diesem Fall ist das Komma als Spaltentrenner und ein Strichpunkt als Zeilentrenner verwendet. Diese Feldtrenner können über den Abschnitt Trennzeichen im Dialog Extras ▸ Optionen... ▸ LibreOffice Calc ▸ Formel (oder LibreOffice ▸ Preferences ▸ LibreOffice Calc ▸ Formel unter macOS) geändert werden

    Formel Beschreibung Ergebnis
    =WVERWEIS(5, {1, 2, 3, 4, 5, 6, 7; "Montag", "Dienstag", "Mittwoch", "Donnerstag", "Freitag", "Samstag", "Sonntag"}; 2)

    Die Funktion findet die Zahl 5 in der ersten Zeile des Feldes und gibt die Daten im Schnittpunkt dieser Spalte und der zweiten Zeile des Feldes zurück.

    Freitag

    Ähnliche LibreOffice Funktionen:

    WAHL

    INDEX

    VERWEIS

    VERGLEICH

    VERSCHIEBUNG

    SVERWEIS

    ODF Standard:

    Kapitel 6.14.5, Teil 2.

    Betroffene (oder ähnliche) EXCEL-Funktionen:

    HLOOKUP