Documentation/Fonctions Calc/AGREGAT

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/AGGREGATE and the translation is 47% complete.
    Other languages:


    Nom de la fonction :

    AGREGAT

    Catégorie :

    Mathématique

    Résumé :

    AGREGAT est une fonction puissante mais complexe qui calcule un nombre unique en appliquant une fonction d'agrégation sélectionnée à un ensemble de données spécifié. Dix-neuf fonctions d'agrégation différentes sont disponibles.

    Contrairement à de nombreuses autres fonctions qui effectuent des calculs similaires, AGREGAT fournit des options pour omettre certains types de données indésirables dans son traitement. Des options sont disponibles pour ignorer les erreurs, les lignes masquées, les SOUS.TOTAL imbriqués et les autres résultats de la fonction AGREGAT.

    Syntaxe :

    AGREGAT(Function; Option; Number1[; Number2[; ... [; Number253]]])

    ou

    AGREGAT(Function; Option; Array; k)

    La première syntaxe est destinée à être utilisée avec les valeurs de Fonction de 1 à 13, tandis que la deuxième syntaxe est destinée à être utilisée avec les valeurs de Fonction de 14 à 19.

    Renvoie :

    Renvoie une valeur numérique qui est le résultat de l'application de la fonction d'agrégation sélectionnée et ignore les options à l'ensemble de données spécifié.

    Arguments :

    Fonction est une valeur entière dans la plage [1, 19], ou une référence à une cellule contenant ce nombre, qui spécifie la fonction d'agrégation à utiliser. Le tableau suivant montre le mappage de ces valeurs aux fonctions d'agrégation.

    Index des fonctions Fonction appliquée
    1 MOYENNE
    2 NB
    3 NBVAL
    4 MAX
    5 MIN
    6 PRODUIT
    7 ECARTYPE.S
    8 ECARTYPE.P
    9 SOMME
    10 VAR.S
    11 VAR.P
    12 MEDIANE
    13 MODE.SIMPLE
    14 GRANDE.VALEUR
    15 PETITE.VALEUR
    16 CENTILE.INCLURE
    17 QUARTILE.INCLURE
    18 CENTILE.EXCLURE
    19 QUARTILE.EXCLURE

    Option est une valeur entière dans la plage [0, 7], ou une référence à une cellule contenant ce nombre, qui spécifie l'option ignorée à utiliser. Le tableau suivant montre quels types de données sont ignorés pour chaque valeur.

    Index des options Option appliquée
    0 Ignorer uniquement les fonctions SOUS.TOTAL imbriqué et AGREGAT
    1 Ignorer uniquement les lignes masquées, les fonctions SOUS.TOTAL imbriqué et AGREGAT.
    2 Ignorer uniquement les erreurs, les fonctions SOUS.TOTAL imbriqué et AGREGAT
    3 Ignorer uniquement les lignes masquées, les erreurs, les fonctions SOUS.TOTAL imbriqué et AGREGAT
    4 Ne rien ignorer
    5 Ignorer uniquement les lignes masquées
    6 Ignorer uniquement les erreurs
    7 Ignorer uniquement les lignes masquées et les erreurs

    Nombre1, Nombre2, ..., Nombre253 sont les arguments numériques devant être calculés lorsque Fonction est dans la plage [1, 13]. Ceux-ci sont similaires à ceux des fonctions seules utilisées pour l'agrégation, voir par exemple MOYENNE, NB, and MAX. Chaque argument peut prendre l'une des formes suivantes :

    • Un nombre ou une expression dont la valeur est un nombre.
    • Une référence à une seule cellule contenant un nombre.
    • Une simple référence à une plage de cellules contenant des nombres (par exemple, A1:B9).
    • Le nom d'une plage nommée, comprenant des cellules contenant des nombres.
    • Le nom d'une plage de base de données, comprenant des cellules contenant des nombres.
    • Une matrice de nombres en ligne (par exemple, {1, 2, 3, 4}).
    • Le texte de l'étiquette d'en-tête au-dessus d'une colonne de nombres, entouré de guillemets simples - uniquement disponible si l'option Outils ▸ Options ▸ LibreOffice Calc ▸ Calculer ▸ Rechercher automatiquement les étiquettes de colonne et de ligne est activée (LibreOffice ▸ Préférences ▸ LibreOffice Calc ▸ Calculer ▸ Rechercher automatiquement les étiquettes de colonne et de ligne sur macOS).

    Array contains the numeric arguments to be processed when Function is in the range [14, 19]. This argument is similar to the Data argument of the standalone functions used for aggregation, see GRANDE.VALEUR, CENTILE.EXCLURE, CENTILE.INCLURE, QUARTILE.INCLURE, QUARTILE.EXCLURE, and PETITE.VALEUR. The Array argument may take one of the forms listed above for Number1, Number2, ..., Number253.

    k is required when Function is in the range [14, 19] and specifies the second argument required by the standalone aggregation function. These are as follows:

    The following error conditions may be encountered:

    • If either Function or Option is non-numeric, then AGREGAT reports an invalid argument error (Err :502).
    • If either Function or Option is not an integer, the value is truncated to its floor value.
    • If Function is less than 1 or greater than 19, then AGREGAT reports an invalid argument error (Err :502).
    • If Option is less than 0 or greater than 7, then AGREGAT reports an invalid argument error (Err :502).
    • Other errors may be generated depending on the aggregate function selected and the data supplied. For example, a #DIV/0 ! error is generated if Function is set to 7 (ECARTYPE.S) and only one data value is supplied. Another example occurs when a #VALEUR ! error is generated if Function is set to 13 (MODE.SIMPLE) and the supplied data contains no duplicate data points. More information about such error conditions can be found on the wiki pages for the standalone versions of the aggregate functions.

    Détails complémentaires :

    The AGREGAT function is best used for columns of data, rather than rows of data, because hiding columns does not have any effect on the results of AGREGAT.

    Exemples :

    The following table shows sample data that is used in the subsequent examples of the AGREGAT function.

    A B C
    1 ColumnOne ColumnTwo ColumnThree
    2 34 11 12
    3 10 56 35
    4 #DIV/0 ! 5 3
    5 20 8 1
    6 0 8 9
    7 #VALEUR ! 20 21
    8 5 7 8
    9 14 0 5
    Formule Description Renvoie
    =AGREGAT(1; 4; 1; 2; 3; 4; 5; 6) Here the function returns the average value (Function set to 1) of the six supplied numbers (1 to 6, specified in the third to eighth arguments), ignoring nothing (Option set to 4). 3,5
    =AGREGAT(4; 2; A2:A9)

    Here the function returns the maximum value (Function set to 4) across the cell range A2:A9, ignoring hidden rows, and nested SOUS.TOTAL and AGREGAT functions (Option set to 2).

    This example demonstrates the power of AGREGAT in comparison to the equivalent standalone functions. The formula =MAX(A2:A9) returns a #DIV/0 ! error, propagating the error in cell A4. If this error is fixed by some change to cell A4, then the formula =MAX(A2:A9) returns a #VALEUR ! error, propagating the error in A7. Using AGREGAT avoids some of the data cleansing activity that might otherwise be required.

    || 34
    =AGREGAT(9; 5; A5:C5) Here the function returns the sum (Function set to 9) across the cell range A5:C5, ignoring only hidden rows (Option set to 5). Note that the result remains unchanged as some or all of columns A-C are hidden. 29
    =AGREGAT(9; 5; B2:B9) Here the function returns the sum (Function set to 9) across the cell range B2:B9, ignoring only hidden rows (Option set to 5). Note that the result changes as any of rows 2:9 are hidden - for example, hiding row 7 changes the result to 95. 115
    =AGREGAT(2; 3; Sheet1.B2:Sheet3.B9) It is assumed that the document contains three sheets – with adjacent tabs Sheet1, Sheet2, and Sheet3 in the Sheet tabs area. It is further assumed that all these three tabs contain the same data in cells A1 to C9.

    Here the function returns the count (Function set to 2) across the three dimensional cell range Sheet1.B2:Sheet3.B9, ignoring hidden rows, errors, and nested SOUS.TOTAL and AGREGAT functions (Option set to 3).
    24
    =AGREGAT(E3; E5; 'ColumnTwo') where cells E3 and E5 contain the numbers 13.3 and 4.7 respectively.

    It is assumed that the option Tools ▸ Options ▸ LibreOffice Calc ▸ Calculate ▸ Automatically find column and row labels is enabled (LibreOffice ▸ Preferences ▸ LibreOffice Calc ▸ Calculate ▸ Automatically find column and row labels on macOS).

    Here the function returns the mode (Function set to truncated value of 13) of the values in ColumnTwo (cells B2:B9), ignoring nothing (Option set to truncated value of 4).

    || 8
    =AGREGAT(15; 4; C2:C9, 3)

    Here the function returns the third (k set to 3) smallest (Function set to 15) of the values in the cell range C2:C9, ignoring nothing (Option set to 4).

    || 5

    Fonctions LibreOffice associées :

    MOYENNE

    NB

    NBVAL

    GRANDE.VALEUR

    MAX

    MEDIANE

    MIN

    MODE.SIMPLE

    CENTILE.EXCLURE

    CENTILE.INCLURE

    PRODUIT

    QUARTILE.EXCLURE

    QUARTILE.INCLURE

    PETITE.VALEUR

    ECARTYPE.P

    ECARTYPE.S

    SOMME

    VAR.P

    VAR.S

    Standard ODF :

    None

    Fonctions Excel équivalentes :

    AGGREGATE since v.2010.