Documentazione/Funzioni di Calc/INDIRIZZO

This page is a translated version of the page Documentation/Calc Functions/ADDRESS and the translation is 98% complete.

Outdated translations are marked like this.

TDF LibreOffice Document Liberation Project Blog comunitari Weblate Nextcloud Redmine Ask LibreOffice Donazione

Other languages:

Funzioni di Calc | Elenco delle funzioni | Abbreviazioni

Nome funzione:

INDIRIZZO

Categoria:

Foglio di calcolo

Riepilogo:

Costruisce un riferimento di cella in base ai numeri di riga e colonna specificati (e, facoltativamente, nomi di fogli di lavoro e file), restituendo il riferimento come stringa di testo. Controllo degli argomenti facoltativi:

Se il riferimento di cella deve utilizzare l'indirizzamento relativo o assoluto (vedi la pagina di aiuto Indirizzi e riferimenti, assoluti e relativi per dettagli).
Se il riferimento alla cella deve utilizzare la sintassi della formula Calc A1 o Excel R1C1 (consulta la Formula pagina della guida per i dettagli).
Se il nome di un foglio (con o senza nome file) deve essere incluso nel riferimento alla cella.

La funzione INDIRIZZO viene utilizzata per determinare dinamicamente il riferimento di una cella di interesse. La stringa risultante può quindi essere passata al file INDIRETTO funzione per recuperare il contenuto della cella.

Sintassi:

INDIRIZZO(Riga; Colonna[; Abs[; A1[; Foglio]]])

Restituisce:

Restituisce una stringa di testo che rappresenta un riferimento di cella, costruita utilizzando gli argomenti specificati.

Argomenti:

Riga è un valore intero, oppure un riferimento ad una cella contenente tale valore, che è il numero di riga da utilizzare. Un foglio di calcolo Calc può contenere fino a 1 048 576 righe (vedi sotto per ulteriori limitazioni).

Colonna è un valore intero, oppure un riferimento ad una cella contenente tale valore, che è il numero di colonna da utilizzare. Sebbene per impostazione predefinita Calc di solito si riferisca alle colonne utilizzando le lettere (iniziando con "A" che corrisponde alla colonna "1"), INDIRIZZO accetta solo numeri per questo argomento. Un foglio di calcolo Calc può contenere fino a 16384 colonne (vedi sotto per ulteriori limitazioni).

Ulteriori limitazioni:

XLS(X) limitazioni
Formato file	max RIGHE			max COLONNE				Commento
XLSX	`1048576`	2^20	2²⁰	`16384`	2^14	2¹⁴	XFD	Excel 2007 e successivi
XLS	`65536`	2^16	2¹⁶	`256`	2^8	2⁸	IV	Da Excel 97 a 2003
XLS	`16384`	2^14	2¹⁴	`256`	2^8	2⁸	IV	Per Excel 5 e 95

ODS limitazioni
Formato file	max RIGHE			max COLONNE				Commento
ODS	`1048576`	2^20	2²⁰	`16384`	2^14	2¹⁴	XFD	LibreOffice incluso dalla versione 7.4
ODS	`1048576`	2^20	2²⁰	`1024`	2^10	2¹⁰	AMJ	LibreOffice prima della versione 7.4
ODS	`1048576`	2^20	2²⁰	`1024`	2^10	2¹⁰	AMJ	OOo incluso dalla versione 3.3
ODS	`65536`	2^16	2¹⁶	`1024`	2^10	2¹⁰	AMJ	OOo incluso dalla versione 3.0, prima della 3.3
ODS	`65536`	2^16	2¹⁶	`256`	2^8	2⁸	IV	OOo prima della versione 3.0

Abs è un valore intero compreso tra 1 e 8, o un riferimento a una cella contenente un valore intero in quell'intervallo, che determina come viene utilizzato l'indirizzamento assoluto o relativo. Se Abs viene omesso, la funzione utilizza il valore 1. Sebbene esistano otto valori accettabili per questo argomento, ci sono solo quattro significati possibili, come mostrato nella tabella seguente.

A1 è un valore logico, o un riferimento a una cella contenente un valore logico, che determina la sintassi della formula da utilizzare nella stringa restituita. Se A1 è impostato su 0 o FALSO, viene utilizzata la sintassi della formula Excel R1C1. Se A1 viene omesso o impostato su qualsiasi altro valore numerico, viene utilizzata la sintassi della formula Calc A1.

La tabella seguente mostra il significato delle varie opzioni per l'argomento Abs e mostra output tipici per diverse combinazioni degli argomenti Abs e A1, presupponendo che gli argomenti Riga e Colonna siano impostati ciascuno su 1.

Sintassi dell'output del riferimento di cella in base agli argomenti **Abs** e A1
Abs	Significato	A1 = VERO	A1 = FALSO
1, 5, oppure omesso	Completamente assoluto	$A$1	R1C1
2 o 6	Riga assoluta, colonna relativa	A$1	R1C[1]
3 o 7	Riga relativa, colonna assoluta	$A1	R[1]C1
4 o 8	Completamente relativo	A1	R[1]C[1]

Foglio è una stringa di testo (tra virgolette doppie), o un riferimento a una cella contenente una stringa di testo, che è il nome del foglio da aggiungere all'inizio del riferimento di cella restituito. Il nome del foglio può includere il nome e la posizione di un documento separato.

Se l'argomento Foglio viene omesso, nella stringa restituita non verrà incluso il nome del foglio (né il separatore del foglio), e il riferimento di cella risultante verrà considerato relativo al foglio corrente.

Calc non controlla che esista attualmente un foglio con il nome specificato. Tieni presente che se è selezionata la sintassi della formula Excel R1C1 (A1 impostato su FALSO o 0) e Sheet non è né omesso né una stringa vuota, quindi INDIRIZZO restituisce una stringa di testo utilizzando un punto esclamativo (!) come separatore del foglio, invece del separatore punto (.) utilizzato con la sintassi della formula Calc A1.

Si possono verificare le seguenti condizioni:

Se Riga non è numerico, allora INDIRIZZO segnala un errore #VALORE!.
Se Riga è un numero reale non intero, allora INDIRIZZO tronca il valore nella sua parte intera.
Nella maggior parte dei casi, dopo il troncamento, se Riga risiede all'esterno dell'intervallo 1 ≤ Riga ≤ max (vedi le tabelle sopra), quindi INDIRIZZO segnala un errore di argomento non valido (Err:502).
Tuttavia, l'intervallo di valori consentito per Riga cambia se viene selezionata la sintassi della formula Excel R1C1 (A1 impostato su FALSO o 0) e l'indirizzamento relativo della riga è selezionato (Abs impostato su 3, 4, 7 o 8). In questi casi, è possibile specificare offset di riga negativi (ad esempio R[-1]C[1]).

Ora, dopo il troncamento, se Riga risiede all'esterno dell'intervallo -(max-1) ≤ Riga ≤ (max-1), INDIRIZZO segnala un errore di argomento non valido (Err: 502).
Inoltre, lo stesso errore potrebbe essere segnalato se un valore in questo intervallo sembra fare riferimento a una riga che non esiste nel foglio (ad esempio, la formula =INDIRIZZO (-1, 1, 4, 0) inserito nella cella A1 causa Err:502 ma non causa errori se inserito nella cella A2).
In altre parole, l'indirizzo assoluto risultante dovrebbe essere ancora valido, entro i normali vincoli per Riga di 1 ≤ Riga ≤ max; in caso contrario viene segnalato un errore.

Se Colonna non è numerica, allora INDIRIZZO riporta un errore #VALORE!.
Se Colonna è un numero reale non intero, allora INDIRIZZO tronca il valore nella sua parte intera.
Nella maggior parte dei casi, dopo il troncamento, se Colonna non è compreso nell'intervallo 1 ≤ Colonna ≤ max (vedi le tabelle sopra), quindi INDIRIZZO segnala un errore di argomento non valido (Err:502).
Tuttavia, l'intervallo di valori consentito per Colonna cambia se viene selezionata la sintassi della formula Excel R1C1 (A1 impostato su FALSO o 0) e l'indirizzamento relativo della colonna è selezionato (Abs impostato su 2, 4, 6 o 8). In questi casi, è possibile specificare offset di colonna negativi (ad esempio R[1]C[-1]).

Ora, dopo il troncamento, se Colonna risiede all'esterno dell'intervallo -(max-1) ≤ Colonna ≤ (max-1), INDIRIZZO segnala un errore di argomento non valido (Err: 502).
Inoltre, lo stesso errore potrebbe essere segnalato se un valore in questo intervallo sembra fare riferimento a una colonna che non esiste nel foglio (ad esempio, la formula =INDIRIZZO (1, -1, 4, 0) inserito nella cella A1 causa Err:502 ma non causa errori se inserito nella cella B1).
In altre parole, l'indirizzo assoluto risultante dovrebbe essere ancora valido, entro i normali vincoli per Colonna di 1 ≤ Colonna ≤ max; in caso contrario viene segnalato un errore.

Se Abs non è numerico, allora INDIRIZZO segnala un errore #VALORE!.
Se Abs è un numero reale non intero, allora INDIRIZZO tronca il valore nella sua parte intera.
Dopo il troncamento, se Abs non è compreso nell'intervallo 1 ≤ Abs ≤ 8, allora INDIRIZZO segnala un errore di #VALORE!.

Se A1 non è numerico (e non logico), allora INDIRIZZO riporta un #VALORE! errore.

Dettagli aggiuntivi:

La funzione INDIRIZZO restituisce una stringa di testo e non un riferimento reale. Se la cella "referenziata" viene effettivamente spostata (modificandone quindi il riferimento), la funzione INDIRIZZO non dispone di un metodo automatico per tenere traccia di tale spostamento. La funzione INDIRIZZO crea la stringa di testo risultante in base solo ai propri argomenti.
INDIRIZZO di Calc e Le funzioni INDIRETTO sono strettamente correlate. INDIRIZZO restituisce un riferimento di cella come testo, che può essere passato come argomento a INDIRETTO per recuperare il contenuto della cella di riferimento.
Se passi una stringa a INDIRETTO generato da INDIRIZZO, assicurati che le due funzioni utilizzino la stessa impostazione per 'A1' discussione. Se le due funzioni assumono una sintassi della formula diversa, potrebbero verificarsi degli errori.
Nelle versioni di ODF precedenti alla 1.2, la specifica per la funzione INDIRIZZO non includeva l'argomento A1 per distinguere tra Calc A1 e la sintassi delle formule Excel R1C1.
- Quando si apre un documento salvato in formato ODF 1.0/1.1, le chiamate alla funzione INDIRIZZO che hanno un nome di foglio come quarto argomento vedranno il nome del foglio spostato per diventare il quinto argomento. Verrà inserito un nuovo quarto argomento con il valore 1 per selezionare la sintassi predefinita della formula Calc A1.
- Quando si salva un documento in formato ODF 1.0/1.1, alle chiamate alla funzione INDIRIZZO verrà rimosso il quarto argomento. In questo modo, qualsiasi chiamata di funzione che in precedenza utilizzava la sintassi della formula Excel R1C1 verrà ripristinata alla sintassi della formula Calc A1 predefinita.
Microsoft Excel rappresenta alcuni riferimenti di cella in modo diverso da Calc, quindi questa funzione non è sempre portabile. Ad esempio, la formula INDIRIZZO(1; 1; 4; ; "Sheet2") restituisce "Sheet2.A1" in Calc, mentre l'equivalente in Excel restituisce "Foglio2!A1".

Esempi:

Dati per esempi
	A	B	C	D
1
2				4
3				3
4				4
5				0
6				Foglio2
7
8				`'file:///C:/my-spreadsheets/my-test.ods'#$Foglio1`

Formula	Descrizione	Restituisce
=INDIRIZZO(4; 3) =INDIRIZZO(4; 3; 1; VERO(); "")	Applica le impostazioni predefinite per Abs (1: completamente assoluto) e A1 (VERO: `Calc A1` sintassi della formula). Non viene fornito alcun valore per l'argomento Foglio, quindi nessuna informazione sul foglio viene inclusa nel riferimento di cella restituito.	$C$4
=INDIRIZZO(4; 3; ; ; "Foglio2")	Gli argomenti Abs e A1 vengono omessi, quindi vengono nuovamente applicate le loro impostazioni predefinite. Viene fornita una stringa per l'argomento Foglio, in modo che le informazioni sul foglio siano incluse nel riferimento di cella restituito.	Foglio2.$C$4
=INDIRIZZO(4; 3; 2; ; "Foglio2") =INDIRIZZO(4; 3; 6; ; "Foglio2")	L'argomento A1 viene omesso, quindi viene nuovamente applicata la sua impostazione predefinita. Con l'argomento Abs impostato su 2 o 6, viene restituito un riferimento di cella che utilizza l'indirizzamento assoluto di riga/relativo di colonna.	Foglio2.C$4
=INDIRIZZO(D2; D3; D4; D5; D6)	Tutti gli argomenti sono presenti e utilizzano valori memorizzati nelle celle. Poiché l'argomento A1 è impostato su 0, la funzione restituisce un riferimento di cella basato sulla sintassi della formula `Excel R1C1`.	Foglio2!R[4]C[3]
=INDIRIZZO(10; 5; 1; ; D8)	Restituisce un riferimento di cella che include un nome di file basato su Windows e un nome di foglio contenuto nella stringa definita per l'argomento Foglio (contenuta nella cella D8). Poiché Abs è `1`, gli argomenti (R10C5) restituiscono la string "`$E$10`". Se la cella $E$10 del foglio e del file specificati contiene il numero 123, la formula `=INDIRETTO(INDIRIZZO(10; 5; 1; ; D8))` restituisce il valore 123.	`'file:///C:/my-spreadsheets/my-test.ods'#$Foglio1.$E$10`

Funzioni di LibreOffice correlate:

Standard ODF:

Section 6.14.2, part 2

Funzioni equivalenti (o simili) di Excel:

ADDRESS