Documentatie/Calc-functies/ADRES

This page is a translated version of the page Documentation/Calc Functions/ADDRESS and the translation is 100% complete.

TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren

Other languages:

Deutsch
English
Nederlands
italiano

Startpagina Calc-functies | Lijst met functies | Afkortingen

Functienaam:

ADRES

Categorie:

Werkblad

Samenvatting:

Stelt een celverwijzing samen op basis van de opgegeven rij- en kolomnummers (en optioneel worksheet en bestandsnamen) retourneert de verwijzing als een tekenreeks. Optionele argumenten controle:

Of de celverwijzing relatieve of absolute adressering moet gebruiken (zie de helppagina Addresses and References, Absolute and Relative voor meer bijzonderheden).
Of de celverwijzing de formulesyntaxis van Calc A1 of Excel R1C1 moet gebruiken (zie de helppagina Formule voor meer details).
Of de naam van een blad moet worden opgenomen in de celverwijzing.

De functie ADRES wordt gebruikt om dynamisch de referentie van een van toepassing zijnde cel te bepalen. De resulterende tekenreeks kan vervolgens worden doorgegeven aan de INDIRECT om de inhoud van de cel op te halen.

Syntaxis:

ADRES(Rij; Kolom[; Abs[; A1[; Blad]]])

Retourneert:

Retourneert een tekenreeks die een celverwijzing is die wordt gemaakt met de opgegeven argumenten.

Argumenten:

Rij is een geheel getal of een verwijzing naar een cel die een geheel getal bevat, wat het rijnummer is dat moet worden gebruikt. Een Calc-werkblad kan maximaal 1.048.576 rijen bevatten. (Hieronder staan wat aanvullende beperkingen.)

Kolom is een geheel getal of een verwijzing naar een cel die een geheel getal bevat, wat het kolomnummer is dat moet worden gebruikt. Hoewel Calc standaard naar kolommen verwijst met letters (vanaf "A", wat dan kolom "1" is), ADRES accepteert alleen getallen voor dit argument. Een Calc werkblad kan tot 16384 kolommen bevatten (Hieronder staan wat aanvullende beperkingen).

Aanvullende beperkingen:

XLS(X) beperkingen
Bestand Formaat	max RIJEN			max KOLOMMEN				Opmerking
XLSX	`1048576`	2^20	2²⁰	`16384`	2^14	2¹⁴	XFD	Excel 2007 en nieuwer
XLS	`65536`	2^16	2¹⁶	`256`	2^8	2⁸	IV	Vanaf Excel 97 tot 2003
XLS	`16384`	2^14	2¹⁴	`256`	2^8	2⁸	IV	Voor Excel 5 en 95

ODS beperkingen
Bestand Formaat	max RIJEN			max KOLOMMEN				Opmerking
ODS	`1048576`	2^20	2²⁰	`16384`	2^14	2¹⁴	XFD	LibreOffice vanaf versie 7.4
ODS	`1048576`	2^20	2²⁰	`1024`	2^10	2¹⁰	AMJ	LibreOffice voor versie 7.4
ODS	`1048576`	2^20	2²⁰	`1024`	2^10	2¹⁰	AMJ	OOo vanaf versie 3.3
ODS	`65536`	2^16	2¹⁶	`1024`	2^10	2¹⁰	AMJ	OOo vanaf versie 3.0, voor 3.3
ODS	`65536`	2^16	2¹⁶	`256`	2^8	2⁸	IV	OOo voor versie 3.0

Abs is een geheel getal in het bereik van 1 tot 8 of een verwijzing naar een cel met een geheel getal in dat bereik, die bepaalt hoe absolute of relatieve adressering wordt gebruikt. Als Abs wordt weggelaten, gebruikt de functie de waarde 1. Hoewel er acht acceptabele waarden zijn voor dit argument, zijn er slechts vier mogelijke betekenissen, zoals weergegeven in de onderstaande tabel.

A1 is een logische waarde of een verwijzing naar een cel die een logische waarde bevat, die de syntaxis van de formule bepaalt die in de geretourneerde tekenreeks moet worden gebruikt. Als A1 is ingesteld op 0 of ONWAAR, wordt de Excel R1C1-formulesyntaxis gebruikt. Als A1 wordt weggelaten of op een andere waarde wordt ingesteld, wordt de syntaxis van de Calc A1-formule gebruikt.

De volgende tabel toont de betekenis van de verschillende opties voor het argument Abs en toont typische outputs voor verschillende combinaties van de argumenten Abs en A1, ervan uitgaande dat de Rij en Kolom argumenten elk zijn ingesteld op 1.

Celreferentie syntaxis van de argumenten **Abs** en A1
Abs	Betekenis	A1 = WAAR	A1 = ONWAAR
1, 5, of weggelaten	Volledig absoluut	$A$1	R1C1
2 of 6	Rij absoluut, kolom relatief	A$1	R1C[1]
3 of 7	Rij relatief, kolom absoluut	$A1	R[1]C1
4 of 8	Volledig relatief	A1	R[1]C[1]

Blad is een tekenreeks (tussen dubbele aanhalingstekens) of een verwijzing naar een cel die een tekenreeks bevat, wat de naam is van het blad dat aan het begin van de geretourneerde celverwijzing moet worden toegevoegd. De bladnaam kan de naam en locatie van een afzonderlijk document bevatten.

Als het argument Blad wordt weggelaten, wordt er geen bladnaam (en geen bladscheidingsteken) opgenomen in de geretourneerde tekenreeks, en de resulterende celreferentie wordt geacht relatief te zijn ten opzichte van het huidige blad.

Calc controleert niet of er momenteel een blad met de opgegeven naam bestaat. Houd er rekening mee dat als de syntaxis van de Excel Excel R1C1-formule is geselecteerd (A1 ingesteld op ONWAAR of 0) en Blad is niet weggelaten noch een lege tekenreeks, dan ADRES Retourneert een tekenreeks met een uitroepteken (!) als bladscheiding, in plaats van de punt (.) scheidingsteken gebruikt met de syntaxis van de Calc A1 -formule.

De volgende voorwaarden kunnen zich voordoen:

Als Rij niet-numeriek is, dan rapporteert ADRES als fout #WAARDE!
Als Rij een niet-geheel getal is, dan kapt ADRES de waarde af tot het dichtstbijzijnde gehele getal.
In de meeste gevallen, als na afkapping Kolom buiten het bereik 1 ≤ Kolom ≤ max ligt, retourneert ADRES als fout Ongeldig argument (Fout:502).
Het toegestane bereik van waarden voor Rij verandert echter als de Excel R1C1-formulesyntaxis is geselecteerd (A1 ingesteld op ONWAAR of 0) en relatieve rijadressering is geselecteerd (Abs ingesteld op 3, 4, 7 of 8). In deze gevallen kunnen negatieve rij-verschuivingen worden opgegeven (bijvoorbeeld R[-1]C[1]).

Als nu Rij na afkapping buiten het bereik -(max-1) ≤ Rij ≤ (max-1) ligt, retourneert ADRES als fout Ongeldig argument (Fout:502).
Bovendien kan dezelfde fout worden geretourneerd als een waarde in dit bereik lijkt te verwijzen naar een rij die niet in het blad voorkomt (bijvoorbeeld de formule =ADRES(-1; 1; 4; 0) geplaatst in cel A1 veroorzaakt Fout:502 maar veroorzaakt geen fout bij plaatsing in cel A2).
Met andere woorden, het resulterende absolute adres moet nog steeds geldig zijn, binnen de normale beperkingen voor Rij van 1 ≤ Rij ≤ max; anders wordt een fout gemeld.

Als Kolom niet-numeriek is, dan rapporteert ADRES als fout #WAARDE!
Als Kolom een niet-geheel getal is, dan kapt ADRES de waarde af tot het dichtstbijzijnde gehele getal.
In de meeste gevallen, als na afkapping Kolom buiten het bereik 1 ≤ Kolom ≤ max ligt, retourneert ADRES als fout Ongeldig argument (Fout:502).
Het toegestane bereik van waarden voor Kolom verandert echter als de Excel R1C1-formulesyntaxis is geselecteerd (A1 ingesteld op ONWAAR of 0) en relatieve kolomadressering is geselecteerd (Abs ingesteld op 2, 4, 6 of 8). In deze gevallen kunnen negatieve kolomverschuivingen worden opgegeven (bijvoorbeeld R[1]C[-1]).

Als nu Kolom na afkapping buiten het bereik -(max-1) ≤ Kolom ≤ (max-1) ligt, retourneert ADRES als fout Ongeldig argument (Fout:502).
Bovendien kan dezelfde fout worden geretourneerd als een waarde in dit bereik lijkt te verwijzen naar een kolom die niet in het blad voorkomt (bijvoorbeeld de formule =ADRES(1; -1; 4; 0) geplaatst in cel A1 veroorzaakt Fout:502 maar veroorzaakt geen fout bij plaatsing in cel B1).
Met andere woorden, het resulterende absolute adres moet nog steeds geldig zijn, binnen de normale beperkingen voor Kolom van 1 ≤ Kolom ≤ max; anders wordt een fout gemeld.

Als Abs niet-numeriek is, dan retourneert ADRES als fout #WAARDE!.
Als Abs een niet-geheel getal is, dan kapt ADRES de waarde af tot het dichtstbijzijnde gehele getal.
Als na afkapping Abs buiten het bereik 1 ≤ Abs ≤ 8 ligt, dan meldt ADRES als fout #WAARDE!.

Als A1 niet-numeriek (en niet-logisch) is, dan retourneert ADRES als fout #WAARDE!

Aanvullende details:

De functie ADRES retourneert een tekenreeks en geen echte verwijzing. Als de cel waarnaar wordt verwezen daadwerkelijk wordt verplaatst (waardoor de verwijzing wordt gewijzigd), wordt heeft de functie ADRES geen automatische methode om een dergelijke beweging bij te houden. De ADRES functie bouwt de resulterende tekenreeks alleen afhankelijk van de eigen argumenten.
De functies ADRES van Calc en INDIRECT zijn nauw verwant. ADRES retourneert een celverwijzing als tekst, die als argument kan worden doorgegeven aan INDIRECT om de inhoud van de cel waarnaar wordt verwezen op te halen.
Als u een tekenreeks doorgeeft aan INDIRECT die is gegenereerd door ADRES, moet u ervoor zorgen dat de twee functies dezelfde instelling gebruiken voor het argument A1. Als de twee functies een verschillende formulesyntaxis aannemen, kunnen er fouten optreden.
In versies van de ODF vóór 1.2 bevatte de specificatie voor de functie ADRES niet het argument A1 om onderscheid te maken tussen de formulesyntaxis van Calc A1 en Excel R1C1.
- Bij het openen van een document dat is opgeslagen in ODF 1.0/1.1-indeling, wordt bij de functie-aanroepen van ADRES die een bladnaam als vierde argument hebben, die bladnaam verschoven om het vijfde argument te worden. Een nieuw vierde argument met de waarde 1 wordt ingevoegd om de standaard syntaxis van de Calc A1-formule te selecteren.
- Bij het opslaan van een document in ODF 1.0/1.1-indeling, wordt het vierde argument van de functie-aanroepen van ADRES verwijderd. Op deze manier zullen alle functie-aanroepen die eerder de Excel R1C1-formulesyntaxis gebruikten, terugkeren naar de standaard Calc A1-formulesyntaxis.
Microsoft Excel behandelt sommige celverwijzingen anders dan Calc, dus deze functie is niet altijd overdraagbaar. Bijvoorbeeld, de formule ADRES(1; 1; 4; ; "Blad2") retourneert "Blad2.A1" in Calc, terwijl het equivalent in Excel "Blad2!A1" retourneert.

Voorbeelden:

Gegevens voor voorbeelden
	A	B	C	D
1
2				4
3				3
4				4
5				0
6				Blad2
7
8				`'file:///C:/my-spreadsheets/my-test.ods'#$Blad1`

Formule	Beschrijving	Retourneert
=ADRES(4; 3) =ADRES(4; 3; 1; WAAR(); "")	Pas de standaardinstellingen toe voor de argumenten Abs (1: volledig absoluut) en A1 (WAAR: `Calc A1` formulesyntaxis). Er wordt geen waarde opgegeven voor het argument Blad en daarom wordt er geen bladinformatie opgenomen in de geretourneerde celverwijzing.	$C$4
=ADRES(4; 3; ; ; "Blad2")	De Abs en A1 argumenten zijn weggelaten en dus worden hun standaard instellingen weer toegepast. In dit geval wordt een tekenreeks geleverd voor het argument Blad zodat bladinformatie wordt opgenomen in de geretourneerde celverwijzing.	Blad2.$C$4
=ADRES(4; 3; 2; ; "Blad2") =ADRES(4; 3; 6; ; "Blad2")	Het argument A1 weggelaten en wordt de standaardinstelling opnieuw toegepast. Met het argument Abs ingesteld op 2 of 6, wordt een celverwijzing geretourneerd die gebruikmaakt van rij absolute / kolom relatieve adressering.	Blad2.C$4
=ADRES(D2; D3; D4; D5; D6)	Alle argumenten zijn aanwezig en gebruiken ze waarden die in cellen zijn opgeslagen. Aangezien het argument A1 is ingesteld op 0, retourneert de functie een celverwijzing op basis van de `Excel R1C1`-formulesyntaxis.	Blad2!R[4]C[3]
=ADRES(10; 5; 1; ; D8)	Retourneert een celverwijzing die een op Windows gebaseerde bestandsnaam en bladnaam bevat binnen de tekenreeks die is gedefinieerd voor het argument Blad (vermeld in cel D8). Omdat Abs `1` is, resulteren de argumenten (R10C5) result in the string "`$E$10` Als cel $E$10 van het opgegeven blad en bestand het getal 123 bevat, retourneert de formule `=INDIRECT(ADRES(10; 5; 1; ; D8))` de waarde 123.	`'file:///C:/my-spreadsheets/my-test.ods'#$Blad1.$E$10`

Gerelateerde LibreOffice-functies:

ODF standaard:

Section 6.14.2, part 2

Gerelateerde (of gelijkwaardige) Excel-functies:

ADDRESS