Jump to content

Documentation/Fonctions Calc/ZONES

From The Document Foundation Wiki
This page is a translated version of the page Documentation/Calc Functions/AREAS and the translation is 100% complete.


Nom de la fonction :

ZONES

Catégorie :

Feuille de calcul

Résumé :

Détermine le nombre de zones individuelles dans une référence donnée. Une référence peut comprendre une ou plusieurs zones, chaque zone étant constituée d'une cellule unique ou d'un bloc de cellules contiguës.

Syntaxe :

ZONES(Référence)

Renvoie :

Renvoie un entier positif qui correspond au nombre de zones dans la référence fournie.

Arguments :

Référence est la référence à analyser.

  • Les références uniques peuvent prendre la forme d'une référence de cellule spécifique (par exemple, "$Feuille1.A1"), d'une plage de cellules spécifique (par exemple, "$Feuille1.$C$28:$H$29") ou du nom d'une plage nommée ou d'une plage de base de données. ZONES est particulièrement utile avec les plages nommées définies à l'aide de Feuille ▸ Expressions et plage nommées ▸ Définir dans la barre de menus, car elles peuvent être configurées pour inclure plusieurs zones à l'aide de l'opérateur de concaténation de référence tilde dans le champ Plage ou expression de formule de la boîte de dialogue Définir un nom.
  • Vous pouvez passer plusieurs références comme argument unique en les fournissant dans une liste séparée, entre parenthèses (par exemple, =ZONES((A1:B6; C2:D7; E3:F8))). Dans ce cas, Calc reformatera l'appel de fonction pour utiliser l'opérateur de concaténation de références tilde (par exemple, =ZONES((A1:B6~ C2:D7~ E3:F8))). Vous pouvez également utiliser l'opérateur de concaténation de références tilde directement, sans parenthèses (par exemple, =ZONES(A1:B6~C2:D7~E3:F8)).
  • ZONES compte les zones répétées ou superposées comme des entités distinctes. Par exemple, =ZONES(A1~A1~A1:C3) renvoie 3.
  • Si Référence n'est pas une liste de référence valide, alors ZONES signale une erreur de liste de paramètres (Err :504).

Détails complémentaires :

Aucun.

Exemples :

Formule Description Renvoie
=ZONES(A5:B7) Ici, la fonction renvoie 1 pour refléter le fait que l'argument représente une seule zone. 1
=ZONES(A1:C6~D4:E7) Ici, la fonction renvoie 2 pour refléter le fait que l'argument représente deux zones. 2
=ZONES(plagenommée) où plagenommée est une plage nommée définie comme $Feuille1.$A$1:$B$7~$Feuille1.$C$12:$D$15~$Feuille1.$E$5:$F$7. Ici, la fonction renvoie 3 pour refléter le fait que l'argument représente trois zones. 3
=ZONES(plagedebasededonnées~A16) où plagedebasededonnées est une plage de base de données définie comme $Feuille1.$A$1:$C$3. Ici, la fonction renvoie 2 pour refléter le fait que l'argument représente deux zones. 2
=ZONES((A1:B3; F2; G1)) Ici, la fonction accepte la liste des références séparées par des points-virgules et entourées de parenthèses supplémentaires, et renvoie 3 pour indiquer que l'argument représente trois zones. Calc convertit la formule en =ZONES((A1:B3~ F2~ G1)) 3
=ZONES(A2:B4 ! B3:D6) Ici, la référence fournie implique deux plages jointes par l'opérateur d'intersection de références (!), ce qui génère une référence à une seule plage contenant toutes les cellules situées à la fois dans les références gauche et droite. Ici, la fonction renvoie 1. Notez que la formule =ZONES(A2:B4 ! B5:D8) génère une erreur #REF !, car aucune cellule ne se trouve dans les deux plages. 1
=ZONES($Feuille1.A1:$Feuille3.C5) Ici, la fonction renvoie 1. Malgré la référence spécifiée incluant des cellules de plusieurs feuilles, elles sont considérées comme contiguës et ZONES ne compte qu'une seule zone. 1

Fonctions LibreOffice associées :

INDEX

Standard ODF :

Section 6.13.2, part 2

Fonctions Excel relatives (ou similaires) :

AREAS