Documentatie/Calc-functies/BEREIKEN

From The Document Foundation Wiki
Jump to navigation Jump to search
This page is a translated version of the page Documentation/Calc Functions/AREAS and the translation is 100% complete.
Other languages:
English • ‎Nederlands



Functienaam:

BEREIKEN

Categorie:

Werkblad

Samenvatting:

Bepaalt het aantal afzonderlijke gebieden in een bepaalde verwijzing. Een verwijzing kan één of meer bereiken omvatten, waarbij elk bereik een enkele cel of een blok aangrenzende cellen omvat.

Syntaxis:

BEREIKEN(Verwijzing)

Retourneert:

Retourneert een positief geheel getal dat het aantal bereiken binnen de opgegeven verwijzing is.

Argumenten:

Verwijzing is de te analyseren verwijzing.

  • Enkele verwijzingen hebben de vorm van een specifieke celverwijzing (bijvoorbeeld "$Blad1.A1"), een specifiek celbereik (bijvoorbeeld "$Blad1.$C$28:$H$29") of de naam van een genoemd of databasebereik. BEREIKEN is met name handig met benoemde bereiken die zijn gedefinieerd met Blad ▸ Benoemde bereiken en expressies ▸ Definiëren op de menubalk, omdat ze kunnen worden geconfigureerd om meerdere gebieden te omvatten met behulp van de tilde-referentie-aaneenschakelingsoperator in de Bereik of formule-expressie van het dialoogvenster Bereik definiëren.
  • Meerdere verwijzingen kunnen als één argument worden doorgegeven door ze in een gescheiden lijst te plaatsen, omringd door haakjes, bijvoorbeeld =BEREIKEN((A1:B6; C2:D7; E3:F8)). In dit geval zal Calc de functieaanroep opnieuw opmaken om de tilde referentie-aaneenschakelingsoperator te gebruiken – bijvoorbeeld =BEREIKEN((A1:B6~ C2:D7~ E3:F8)). Als alternatief kunt u de tilde referentie-aaneenschakelingsoperator rechtstreeks zonder haakjes gebruiken – bijvoorbeeld =BEREIKEN(A1:B6~C2:D7~E3:F8).
  • BEREIKEN telt herhaalde of overlappende gebieden als afzonderlijke entiteiten. Bijvoorbeeld, =BEREIKEN(A1~A1~A1:C3) geeft als resultaat 3.
  • Als Verwijzing geen geldige verwijzing is, dan retourneert BEREIKEN fout in lijst met parameters (Fout:504).

Aanvullende details:

Geen

Voorbeelden:

Formule Beschrijving Retourneert
=BEREIKEN(A5:B7) Hier retourneert de functie 1 om aan te geven dat het argument een enkel bereik vertegenwoordigt. 1
=BEREIKEN(A1:C6~D4:E7) Hier retourneert de functie 2 om aan te geven dat het argument twee bereiken vertegenwoordigt. 2
=BEREIKEN(BenoemdBereik) waarbij BenoemdBereik een benoemd bereik is gedefinieerd als $Blad1.$A$1:$B$7~$Blad1.$C$12:$D$15~$Blad1.$E$5:$F$7. Hier retourneert de functie 3 om aan te geven dat het argument drie bereiken vertegenwoordigt. 3
=BEREIKEN(DatabaseBereik~A16) waarbij DatabaseBereik een databasebereik is gedefinieerd als $Blad1.$A$1:$C$3. Hier retourneert de functie 2 om aan te geven dat het argument twee bereiken vertegenwoordigt. 2
=BEREIKEN((A1:B3; F2; G1)) Hier accepteert de functie de lijst met verwijzingen, gescheiden door puntkomma's en tussen extra ronde haakjes en retourneert 3 om aan te geven dat het argument drie bereiken vertegenwoordigt. Calc converteert de formule naar =AREAS((A1:B3~ F2~ G1)) 3
=BEREIKEN(A2:B4 ! B3:D6) Hier heeft de opgegeven verwijzing betrekking op twee bereiken die zijn samengevoegd door de operator voor referentie-doorsnijding (!), wat resulteert in een verwijzing naar een enkel bereik dat alle cellen bevat die zowel in de linker- als in de rechterverwijzing liggen. Hier retourneert de functie 1. Merk op dat de formule =BEREIKEN(A2:B4 ! B5:D8) als fout #VERW! weergeeft omdat er geen cellen zijn die in beide bereiken liggen. 1
=BEREIKEN($Blad1.A1:$Blad3.C5) Hier retourneert de functie 1. Ondanks dat de opgegeven verwijzing cellen op meerdere bladen bevat, worden ze als aaneengesloten beschouwd en telt BEREIKEN slechts één bereik. 1

Gerelateerde LibreOffice-functies:

INDEX

ODF standaard:

Section 6.13.2, part 2

Gelijkwaardige Excel-functies:

BEREIKEN