Documentatie/Calc-functies/BOVENGRENS.WISKUNDIG

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/CEILING.MATH and the translation is 100% complete.
    Other languages:


    Functienaam:

    AFRONDEN.BOVEN.WISK

    Categorie:

    Wiskundig

    Samenvatting:

    Rondt een getal af op het dichtstbijzijnde veelvoud van een significantiewaarde. In de meeste gevallen wordt het getal naar boven afgerond (richting +∞). Er is echter een modusparameter beschikbaar en wanneer deze is ingesteld op een waarde die niet nul is, worden negatieve getallen naar beneden afgerond (in de richting van -∞).

    Syntaxis:

    AFRONDEN.BOVEN.WISK(Getal [; Stapgrootte [; Modus]])

    Retourneert:

    Retourneert een reëel getal dat de afgeronde waarde is en een geheel veelvoud is van de waarde van de stapgrootte.

    Argumenten:

    Getal is een reëel getal of een verwijzing naar een cel die dat getal bevat, dat is de waarde die moet worden afgerond.

    Stapgrootte is een reëel getal of een verwijzing naar een cel die dat getal bevat, dat wil zeggen de waarde van de stapgrootte die moet worden gebruikt. Indien weggelaten, wordt Stapgrootte standaard ingesteld op 1. Het teken Stapgrootte wordt genegeerd.

    Modus is een reëel getal of een verwijzing naar een cel die dat getal bevat, dat is een Booleaanse modusindicator. Modus is alleen effectief als Getal negatief is. Als Modus aanwezig is en gelijk is aan een waarde die niet nul is (inclusief WAAR), worden negatieve getallen naar beneden afgerond (in de richting van -∞). Als Modus wordt weggelaten, of gelijk is aan nul of ONWAAR, worden negatieve getallen naar boven afgerond (in de richting van +∞).

    • Als een argument niet-numeriek is, retourneert AFRONDEN.BOVEN.WISK als fout #WAARDE!
    • Als ofwel Getal of Stapgrootte gelijk is aan 0, dan geeft AFRONDEN.BOVEN.WISK 0 als resultaat.

    Aanvullende details:

    Details specifiek voor de functie AFRONDEN.BOVEN.WISK

    • Met Stapgrootte ingesteld op -1 of +1 of standaard ingesteld op 1 en Modus ingesteld of standaard ingesteld op 0 of ONWAAR, biedt AFRONDEN.BOVEN.WISK functionaliteit die de standaard wiskundige definitie van een bovengrenswaarde.
    • AFRONDEN.BOVEN.WISK is vergelijkbaar met de functie AFRONDEN.BOVEN, het verschil tussen de twee ligt in de interpretatie van het Stapgrootte-argument. De functie AFRONDEN.BOVEN vereist dat de argumenten Stapgrootte en Getal hetzelfde teken hebben, terwijl voor AFRONDEN.BOVEN.WISK het teken van het argument Stapgrootte wordt genegeerd.


    Algemene informatie over de functies afronden in Calc

    Note pin.svg

    NB:
    Voor het gemak wordt de informatie in dit subgedeelte herhaald op alle pagina's die de functies bovengrens van Calc beschrijven.

    Algemene inleidende informatie over functies bovengrens is te vinden op Wikipedia's Floor and ceiling functions pagina.

    Calc biedt vijf functies die kunnen worden gebruikt om de van de afronding van een getal te berekenen, en dit zijn:

    De belangrijkste hiervan voor veel gebruikers is de functie AFRONDEN.BOVEN, die de vereisten implementeert die zijn uiteengezet in /v1.2/os/OpenDocument-v1.2-os-part2.html#CEILING Paragraaf 6.17.1 van ODF 1.2, deel 2.

    Calc biedt de AFRONDEN.BOVEN.WISK, AFRONDEN.BOVEN.NAUWKEURIG en ISO.AFRONDEN.BOVEN om de interoperabiliteit met Microsoft Excel te vergroten, dat drie vergelijkbare functies met dezelfde naam biedt. AFRONDEN.BOVEN.NAUWKEURIG en ISO.AFRONDEN.BOVEN van Calc voeren identieke functies uit.

    De AFRONDEN.BOVEN-functie van Microsoft Excel accepteert twee argumenten en is dus niet compatibel met ODF 1.2. Dit verschil in gedrag kan leiden tot interoperabiliteitsproblemen, maar deze worden vermeden door de functie AFRONDEN.BOVEN.EXCEL als volgt aan te bieden:

    • Wanneer Calc een werkblad opslaat in Excel 2007-365 (*.xlsx)-indeling, wordt elke aanroep naar de functie AFRONDEN.BOVEN van Calc geconverteerd naar een aanroep naar de functie AFRONDEN.BOVEN.WISK van Excel en elke aanroep van de functie AFRONDEN.BOVEN.EXCEL van Calc wordt geconverteerd naar een aanroep naar de functie AFRONDEN.BOVEN van Excel.
    • Wanneer Calc een werkblad opent in Excel 2007-365 (*.xlsx)-indeling, wordt elke aanroep naar de functie AFRONDEN.BOVEN van Excel geconverteerd naar een aanroep naar de functie AFRONDEN.BOVEN.EXCEL.

    Voorbeelden:

    Formule Beschrijving Retourneert
    =AFRONDEN.BOVEN.WISK(11,5) Stapgrootte is standaard 1 en Modus is standaard 0. De functie rondt 11,5 af naar boven op het dichtstbijzijnde gehele veelvoud van 1. 12
    =AFRONDEN.BOVEN.WISK(−11,5) Stapgrootte is standaard 1 en Modus is standaard 0. De functie rondt -11,5 naar boven af op het dichtstbijzijnde gehele veelvoud van 1. −11
    =AFRONDEN.BOVEN.WISK(7; 2,3) Modus is standaard 0. De functie rondt 7 naar boven af op het dichtstbijzijnde gehele veelvoud van 2,3. 9,2
    =AFRONDEN.BOVEN.WISK(−7; −2,3) Modus is standaard 0. De functie rondt -7 af naar het dichtstbijzijnde gehele veelvoud van 2,3 (het teken van de significantiewaarde wordt genegeerd). −6,9
    =AFRONDEN.BOVEN.WISK(D1; D2; D3) waarbij de cellen D1, D2 en D3 respectievelijk de nummers 10, 3 en 1 bevatten. De functie rondt de waarde 10 af naar het dichtstbijzijnde gehele veelvoud van 3. De waarde van Modus is niet significant voor een positief getal. 12
    =AFRONDEN.BOVEN.WISK(−10; −3; 0) Met Modus ingesteld op 0, rondt de functie de waarde -10 af naar het dichtstbijzijnde gehele veelvoud van 3 (het teken van de waarde van de stapgrootte wordt genegeerd). −9
    =AFRONDEN.BOVEN.WISK(−10; −3; 7,6) Als Modus is ingesteld op een waarde die niet nul is, rondt de functie de waarde van -10 af naar het dichtstbijzijnde gehele veelvoud van 3 (het teken van de waarde van de stapgrootte wordt genegeerd). −12
    =AFRONDEN.BOVEN.WISK(−3,6; ; WAAR()) Stapgrootte is standaard ingesteld op 1. Met Modus ingesteld op een waarde die niet nul is, rondt de functie de waarde van -3,6 af naar het dichtstbijzijnde gehele veelvoud van 1. −4

    Gerelateerde LibreOffice-functies:

    AFRONDEN.BOVEN

    AFRONDEN.BOVEN.NAUWKEURIG

    AFRONDEN.BOVEN.EXCEL

    AFRONDEN.BENEDEN

    AFRONDEN.BENEDEN.WISK

    AFRONDEN.BENEDEN.NAUWKEURIG

    AFRONDEN.BENEDEN.EXCEL

    INTEGER

    ISO.AFRONDEN.BOVEN

    ODF standaard:

    Geen

    Gerelateerde (of gelijkwaardige) Excel-functies:

    CEILING.MATH sinds v.2013