Documentatie/Calc-functies/KIEZEN
TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren
Functienaam:
KIEZEN
Categorie:
Werkblad
Samenvatting:
Accepteert een lijst met maximaal 30 waarden, waarvan er één wordt geretourneerd. De waarde die moet worden geretourneerd, wordt geselecteerd met behulp van een extra indexargument.
Syntaxis:
KIEZEN(Index; Waarde 1 [; Waarde 2 [; ... [; Waarde 30]]])
Retourneert:
Retourneert één van de opgegeven waarden, geselecteerd met behulp van de opgegeven index. Het type waarde dat wordt geretourneerd, is afhankelijk van het type van het geïndexeerde argument.
Argumenten:
Index is een geheel getal in het bereik 1 ≤ Index ≤ 30 of een verwijzing naar een cel die zo'n geheel getal bevat, dat bepaalt welke waarde uit de lijst moet worden geselecteerd en geretourneerd.
Als Index 1 is, retourneert de functie de eerste waarde in de lijst; als Index 2 is, wordt de tweede waarde in de lijst geretourneerd; enzovoort.
Waarde 1, Waarde 2, ..., Waarde 30 zijn waarden waaruit een moet worden geselecteerd en geretourneerd. Elk kan tekst, een getal (reëel of geheel getal), een datum, een logische waarde, een verwijzing of een formule zijn.
- Als Index niet-numeriek is, dan retourneert KIEZEN als fout #WAARDE!.
- Als Index een niet-gehele waarde is, dan kapt KIEZEN de waarde af tot een geheel getal.
- Als, na afkapping, Index kleiner is dan 1, of groter is dan het aantal opgegeven waarden, dan retourneert KIEZEN als fout Ongeldig argument (Fout:502).
- Als er meer dan 30 Waarde n-argumenten zijn opgegeven, retourneert KIEZEN fout in de lijst met parameters (Fout:504).
Aanvullende details:
- Op voorwaarde dat er scheidingstekens aanwezig zijn, kunnen waarden uit de lijst worden weggelaten. KIEZEN retourneert 0 als een dergelijke ontbrekende waarde is geïndexeerd. De formule
=KIEZEN(2; "reeks1"; ; "reeks3")retourneert bijvoorbeeld 0. - KIEZEN kan worden gebruikt in een matrixformule. Selecteer bijvoorbeeld de cellen D1 t/m D6 en voer de matrixformule
{=KIEZEN(1; A1:A6)}in de geselecteerde cellen in (met Ctrl + ⇧ Shift + ↵ Enter in plaats van alleen ↵ Enter). Cel D1 neemt de waarde in A1 aan, cel D2 neemt de waarde in A2 aan, enzovoort. - Andere argumenten dan de gekozen argumenten worden niet berekend of beoordeeld op bijwerkingen. De formule
=KIEZEN(1; 2; WORTEL(-1))retourneert bijvoorbeeld de waarde 2, maar de formule=KIEZEN(2; 2; WORTEL(-1))geeft als fout Ongeldig argument (Fout:502) die aangeeft dat de bewerking WORTEL alleen wordt geprobeerd wanneer dat argument is geïndexeerd.
Voorbeelden:
| A | B | C | |
|---|---|---|---|
| 1 | 2 | 1,234 | 2 |
| 2 | =PI() | 2022-02-17 | 7 |
| 3 | =WAAR() | 13 | |
| 4 | =WORTEL(64) | 19 |
| Formule | Beschrijving | Retourneert |
|---|---|---|
| =KIEZEN(1,34; "Base"; "Calc"; "Writer") |
Hier kapt de functie de waarde 1,34 af en retourneert het eerste item in de lijst met mogelijke retourwaarden. |
Base |
| =KIEZEN(C1; B1; B2; B3; B4) |
Hier indexeert de functie het tweede item in de lijst met mogelijke retourwaarden.
Het is gelijk aan |
17-02-2022 |
| =SOM(KIEZEN(1; C2:C4; B12)) |
Hier retourneert de formule de som van de getallen in het bereik C2:C4.
Het is mogelijk om een celbereik als één van de waarden op te nemen, maar dit moet in de juiste context staan.
|
39 |
| =KIEZEN(A1; B1; A2; B3; "Vandaag"; "Gisteren"; "Morgen") |
Hier indexeert de functie het tweede item in de lijst met mogelijke retourwaarden en retourneert de geschatte waarde van π. Als de waarde in cel A1 wordt gewijzigd in 4, wordt in plaats daarvan de tekst "Vandaag" geretourneerd. |
3,14159265358979 |
Gerelateerde LibreOffice-functies:
ODF standaard:
Gerelateerde (of gelijkwaardige) Excel-functies:
CHOOSE