Dokumentation/Calc Funktionen/WAHL
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende
Funktionsname:
WAHL
Kategorie:
Tabelle
Zusammenfassung:
Akzeptiert eine Liste mit bis zu 30 Werten und gibt eine davon zurück. der zurückzugebende Wert wird durch einen zusätzlichen Index ausgewählt.
Syntax:
WAHL(Index; Wert 1 [; Wert 2 [; ... [; Wert 30]]])
Rückgabewerte:
Gibt einen der angegebenen Werte zurück. Dieser wird durch den Index festgelegt. Der Typ des zurückgegebenen Wertes hängt von der Natur des Wertes ab.
Argumente:
Index ist eine Ganzzahl aus dem Bereich 1 ≤ Index ≤ 30 oder eine Referenz auf eine Zelle, die diese Ganzzahl enthält. Diese bestimmt den auszuwählenden Wert und gibt ihn zurück.
Falls Index 1 ist, gibt die Funktion den ersten Wert aus der Liste zurück; falls der Wert 2 ist, gibt sie den zweiten Wert aus der Liste zurück und so weiter.
Wert 1, Wert 2, ..., Wert 30 sind Werte, aus denen einer ausgewählt und zurückgegeben wird. Jeder kann ein Text, eine Zahl (Dezimalzahl oder Ganzzahl), ein Datum, ein logischer Wert, eine Referenz oder eine Formel sein.
- Falls Index nicht numerisch ist, dann meldet WAHL einen #WERT! Fehler.
- Falls Index keine Ganzzahl ist, dann verkürzt ihn WAHL auf eine Ganzzahl.
- Falls Index nach einer Verkürzung kleiner als 1 oder größer als die Anzahl der angegebenen Werte ist, meldet WAHL einen invalid argument error (Fehler:502).
- Falls mehr als 30 Wert n Argumente angegeben sind, dann meldet WAHL einen parameter list error (Fehler:504).
Zusätzliche Informationen:
- Bei Angabe der Trennzeichen können Werte in der Liste fehlen. WAHL gibt 0 zurück, falls ein solcher fehlender Wert indiziert wird. Zum Beispiel gibt die Formel
=WAHL(2; "str1"; ; "str3")0 zurück. - WAHL kann in einer Matrix-Formel verwendet werden. Wenn zum Beispiel die Zellen D1 bis D6 angewählt werden und die Matrix-Formel
{=WAHL(1; A1:A6)}für die gewählten Zellen eingegeben wird (unter Verwendung von Strg + ⇧ Umschalt + ↵ Enter statt nur ↵ Enter). Zelle D1 zeigt den Wert in A1, Zelle D2 den Wert in A2 und so weiter. - Nur die ausgewählten Argumente werden berechnet oder für Nebeneffekte berücksichtigt. Zum Beispiel gibt die Formel
=WAHL(1; 2; WURZEL(-1))2 zurück, jedoch meldet die Formel=WAHL(2; 2; WURZEL(-1))einen invalid argument error (Fehler:502) da die Operation WURZEL nur ausgewertet wird, wenn sie indiziert wird.
Beispiele:
| A | B | C | |
|---|---|---|---|
| 1 | 2 | 1,234 | 2 |
| 2 | =PI() | 2022-02-17 | 7 |
| 3 | =WAHR() | 13 | |
| 4 | =WURZEL(64) | 19 |
| Formel | Beschreibung | Ergebnis |
|---|---|---|
| =WAHL(1,34; "Base"; "Calc"; "Writer") |
Hier kürzt die Funktion den Wert 1,34 und gibt den ersten Eintrag in der Liste der möglichen Rückgabewerte aus. |
Base |
| =WAHL(C1; B1; B2; B3; B4) |
Hier indiziert die Funktion den zweiten Eintrag in der Liste der möglichen Rückgabewerte.
Sie ist äquivalent zu |
17.02.2022 |
| =SUMME(WAHL(1; C2:C4; B12)) |
Hier gibt die Formel die Summe der Zahlen im Bereich C2:C4 zurück.
Es ist möglich, einen Zellbereich als einer der Werte anzugeben, aber das benötigt den korrekten Kontext.
|
39 |
| =WAHL(A1; B1; A2; B3; "Heute"; "Gestern"; "Morgen") |
Hier indiziert die Funktion den zweiten Eintrag in der Liste der möglichen Rückgabewerte und gibt den ungefähren Wert von π zurück. Falls dere Wert in Zelle A1 auf 4 geändert wird, dann wird stattdessen der Text "Heute" zurückgegeben. |
3,14159265358979 |
Ähnliche LibreOffice Funktionen:
ODF Standard:
Betroffene (oder ähnliche) EXCEL-Funktionen:
CHOOSE