Jump to content

Documentation/Fonctions Calc/CHOISIR

From The Document Foundation Wiki
This page is a translated version of the page Documentation/Calc Functions/CHOOSE and the translation is 100% complete.


Nom de la fonction :

CHOISIR

Catégorie :

Feuille de calcul

Résumé :

Accepte une liste de 30 valeurs maximum et renvoie l'une d'entre elles. La valeur à renvoyer est sélectionnée à l'aide d'un argument d'index supplémentaire.

Syntaxe :

CHOISIR(Index; Valeur 1 [; Valeur 2 [; ... [; Valeur 30]]])

Renvoie :

Renvoie l'une des valeurs fournies, sélectionnée à l'aide de l'index donné. Le type de valeur renvoyée dépend du type de l'argument indexé.

Arguments :

Index est un entier compris dans la plage 1 ≤ Index ≤ 30, ou une référence à une cellule contenant un tel entier, qui détermine la valeur à sélectionner dans la liste et à renvoyer. Si Index est égal à 1, la fonction renvoie la première valeur de la liste ; si Index est égal à 2, elle renvoie la deuxième valeur de la liste ; et ainsi de suite.

Valeur 1', Valeur 2, ..., Valeur 30 sont des valeurs parmi lesquelles une valeur doit être sélectionnée et renvoyée. Chacune peut être du texte, un nombre (réel ou entier), une date, une valeur logique, une référence ou une formule.

  • Si Index n'est pas numérique, alors CHOISIR signale une erreur #VALEUR !.
  • Si Index est une valeur non entière, alors CHOISIR tronque la valeur en un entier.
  • Si, après troncature, Index est inférieur à 1 ou supérieur au nombre de valeurs fournies, alors CHOISIR signale une erreur argument non valide (Err :502).
  • Si plus de 30 arguments Valeur n sont fournis, alors CHOISIR signale une erreur de liste de paramètres (Err :504).

Détails complémentaires :

  • À condition que des séparateurs soient présents, des valeurs peuvent être omises dans la liste. CHOISIR renvoie 0 si une telle valeur manquante est indexée. Par exemple, la formule =CHOISIR(2; "str1"; ; "str3") renvoie 0.
  • CHOISIR peut être utilisé dans une formule matricielle. Par exemple, sélectionnez les cellules D1 à D6 et saisissez la formule matricielle {=CHOISIR(1; A1:A6)} dans les cellules sélectionnées (en utilisant la touche Ctrl + ⇧ Maj + ↵ Entrée plutôt que la touche ↵ Entrée). La cellule D1 prend la valeur de A1, la cellule D2 celle de A2, et ainsi de suite.
  • Les arguments autres que celui choisi ne sont ni calculés ni évalués pour détecter les effets secondaires. Par exemple, la formule =CHOISIR(1; 2; RACINE(-1)) renvoie la valeur 2, mais la formule =CHOISIR(2; 2; RACINE(-1)) génère une erreur d'argument non valide (Err :502) indiquant que l'opération RACINE n'est tentée que lorsque cet argument est indexé.

Exemples :

Données à titre d'exemple
A B C
1 2 1,234 2
2 =PI() 2022-02-17 7
3 =VRAI() 13
4 =RACINE(64) 19
Formule Description Renvoie
=CHOISIR(1,34; "Base"; "Calc"; "Writer")

Tronque la valeur 1,34 et renvoie la première entrée dans la liste des valeurs de renvoie possibles.

Base
=CHOISIR(C1; B1; B2; B3; B4)

La fonction indexe la deuxième entrée de la liste des valeurs de renvoie possibles. Elle est équivalente à =B2.

17/02/2022
=SOMME(CHOISIR(1; C2:C4; B12))

Renvoie la somme des nombres de la plage C2:C4. Il est possible d'inclure une plage de cellules comme valeur, mais cela doit être fait dans le bon contexte. =CHOISIR(1; C2:C4; B12) génère une erreur #VALEUR !.

39
=CHOISIR(A1; B1; A2; B3; "Aujourd'hui"; "Hier"; "Demain")

La fonction indexe la deuxième entrée de la liste des valeurs de renvoie possibles et renvoie la valeur approximative de π. Si la valeur de la cellule A1 est modifiée en 4, le texte "Aujourd'hui" est renvoyé à la place.

3,14159265358979

Fonctions LibreOffice associées :

SI

SI.CONDITIONS

SI.MULTIPLE

Standard ODF :

Section 6.14.3, part 2

Fonctions Excel relatives (ou similaires) :

CHOOSE