Documentation/Calc Functions/FORECAST.ETS.STAT.MULT

From The Document Foundation Wiki
Jump to navigation Jump to search


Function name:

FORECAST.ETS.STAT.MULT

Category:

Statistical Analysis

Summary:

Returns statistical value(s) that are results of the ETS (Exponential Triple Smoothing) or EDS (Exponential Double Smoothing) algorithms.

Syntax:

FORECAST.ETS.STAT.MULT (values, timeline, stat_type, [period_length], [data_completion], [aggregation])

Returns:

Returns a real number giving the value for the specified statistic.

Arguments:

values is a numeric array or range. values are the historical values, for which you want to forecast the next points.

timeline is a real number or dates or time array or a reference to the range to cells containing them. The timeline (x-value) range for historical values.

Note pin.svg

The timeline doesn't have to be sorted, the function will sort it for calculations. The timeline values must have a consistent step between them.


stat_type is a numerical value from 1 to 9. A value indicating which statistic will be returned for the given values and x-range.

The following statistics can be returned:

stat_type Statistics
1 Alpha smoothing parameter of ETS algorithm (base)
2 Gamma smoothing parameter of ETS algorithm (trend)
3 Beta smoothing parameter of ETS algorithm (periodic deviation)
4 Mean absolute scaled error (MASE) - a measure of the accuracy of forecasts.
5 Symmetric mean absolute percentage error (SMAPE) - an accuracy measure based on percentage errors.
6 Mean absolute error (MAE) – a measure of the accuracy of forecasts.
7 Root mean squared error (RMSE) - a measure of the differences between predicted and observed values.
8 Step size detected timeline (x-range). When a stepsize in months/quarters/years is detected, the stepsize is in months, otherwise, the stepsize is in days in case of date(time) timeline and numeric in other cases.
9 Number of samples in period – this is the same as argument period_length, or the calculated number in case of argument period_length being 1.

period_length is a numeric value >= 0, the default is 1. A positive integer indicating the number of samples in a period.

Note pin.svg

A value of 1 indicates that Calc is to determine the number of samples in a period automatically. A value of 0 indicates no periodic effects, a forecast is calculated with EDS algorithms. For all other positive values, forecasts are calculated with ETS algorithms.


data_completion is a logical value TRUE or FALSE, a numeric 1 or 0, default is 1 (TRUE). A value of 0 (FALSE) will add missing data points with zero as historical value. A value of 1 (TRUE) will add missing data points by interpolating between the neighboring data points.

Note pin.svg

Although the timeline requires a constant step between data points, the function supports up to 30% missing data points and will add these data points.


aggregation is a numeric value from 1 to 7, with default 1. The aggregation parameter indicates which method will be used to aggregate identical time values:

Aggregation Function
1 AVERAGE
2 COUNT
3 COUNTA
4 MAX
5 MEDIAN
6 MIN
7 SUM
Note pin.svg

Although the timeline requires a constant step between data points, the function will aggregate multiple points which have the same timestamp.


  • If a constant step can't be identified in the sorted timeline, the function will return a numeric(#NUM!) error.
  • If the ranges of the timeline and historical values aren't of the same size, the function will return an error value.
  • If the timeline contains less than 2 periods of data, the function will return a value(#VALUE!) Error.
  • For values of period_length that not being a positive whole number, the function will return a numeric(#NUM!) Error.
  • If stat_type is not an integer value then it is truncated to an integer.
  • After truncation if stat_type is less than 1 or greater than or equal to 10 then the function returns an error value.

Additional details:

  • Exponential Smoothing is a method to smooth real values in time series in order to forecast probable future values.
  • Exponential Triple Smoothing (ETS) is a set of algorithms in which both trend and periodical (seasonal) influences are processed. Exponential Double Smoothing (EDS) is an algorithm like ETS, but without the periodical influences. EDS produces linear forecasts.
  • FORECAST.ETS.STAT.MULT calculates with the model:
Forecast.ets.mul.png
  • For more details on exponential smoothing algorithms, visit Wikipedia.

Examples:

The table below contains a timeline and its associated values:

A B
1 Timeline Values
2 01/01/2013 112
3 01/02/2013 118
4 01/03/2013 132
5 01/04/2013 100
6 01/05/2013 121
7 01/06/2013 135
8 01/07/2013 148
9 01/08/2013 148
10 01/09/2013 136
11 01/10/2013 119
12 01/11/2013 104
13 01/12/2013 118
Formula Description Returns
=FORECAST.ETS.STAT.MULT(Values;Timeline;5;1;TRUE();1) with Values and Timeline as the named ranges from the table above The multiplicative statistics based on Values and Timeline named ranges above, with symmetric mean absolute percentage error (SMAPE), one sample per period, no missing data, and AVERAGE as aggregation. 0.084073452803966
=FORECAST.ETS.STAT.MULT(Values;Timeline;7;1;TRUE();7) with Values and Timeline as the named ranges from the table above The multiplicative statistics based on Values and Timeline named ranges above, with root mean squared error, no missing data, and SUM as aggregation. 15.8372533480997
=FORECAST.ETS.STAT.MULT(Values;Timeline;2;1;5;7) with Values and Timeline as the named ranges from the table above

The function returns an error value since data_completion cannot be anything except 0,FALSE,1 or TRUE. || Err:502`

Related LibreOffice functions:

FORECAST

FORECAST.ETS.ADD

FORECAST.ETS.MULT

FORECAST.ETS.PI.ADD

FORECAST.ETS.PI.MULT

FORECAST.ETS.SEASONALITY

FORECAST.ETS.STAT.ADD

FORECAST.LINEAR

ODF standard:

None

Equivalent Excel functions:

None