Documentazione/Funzioni di Calc/INDICE
TDF LibreOffice Document Liberation Project Blog comunitari Weblate Nextcloud Redmine Ask LibreOffice Donazione
Nome funzione:
INDICE
Categoria:
Foglio di calcolo
Riepilogo:
Nella sua forma più semplice, INDICE può essere utilizzato per recuperare il valore in una cella particolare, specificata dai relativi numeri di riga e colonna all'interno di una tabella di dati. A seconda del contesto, è anche possibile utilizzare INDICE per determinare il riferimento della cella all'intersezione della riga e della colonna specificate.
INDICE è una potente funzione che può essere utilizzata per cercare valori in più intervalli di celle non contigui e può essere utilizzata in un contesto di matrice per restituire più valori. La flessibilità aumenta quando INDICE viene utilizzato insieme a Funzione CONFRONTA, che consente alle formule di reagire meglio ai cambiamenti nei dati di input.
Sintassi:
La sintassi generale della funzione INDICE è:
- INDICE(Riferimento[; Riga[; Colonna[; Intervallo]]])
Nel caso speciale in cui il primo argomento ha una sola colonna, è possibile utilizzare la seguente sintassi semplificata:
- INDICE(Riferimento; Riga)
Nel caso speciale in cui il primo argomento ha una sola riga, è possibile utilizzare la seguente sintassi alternativa:
- INDICE(Riferimento; Colonna)
Restituisce:
Tecnicamente, INDICE restituisce un riferimento di cella. Tuttavia, a seconda della formula utilizzata, il valore restituito può essere utilizzato come valore di dati (il cui tipo è determinato dal set di dati di input) o come riferimento di cella.
Argomenti:
Riferimento è un elenco di riferimento che specifica gli intervalli di celle occupati dalle tabelle dei dati di input. Assume una delle seguenti forme:
- Un intervallo di celle singolo (ad esempio A1:E10).
- È possibile passare più intervalli di celle come un singolo argomento fornendoli in un elenco separato, racchiuso tra parentesi, ad esempio
=INDEX((A1:B6; C2:D7; E3:F8); …). In questo caso Calc riformatterà la chiamata alla funzione per utilizzare l'operatore di concatenazione del riferimento tilde, ad esempio=INDICE( (A1:Si6~Do2:Re7~Mi3:F8)…). In alternativa, è possibile utilizzare l'operatore di concatenazione dei riferimenti tilde direttamente senza parentesi, ad esempio=INDICE(A1:B6~C2: D7~E3:F8…)</codice>. - Un singolo intervallo di celle a cui fa riferimento il nome di un intervallo di database (definito selezionando ▸ sulla barra dei menu).
- Uno o più intervalli di celle a cui fa riferimento il nome di un intervallo denominato. Gli intervalli denominati definiti utilizzando ▸ ▸ sulla barra dei menu possono essere configurati per comprendere più aree utilizzando l'operatore di concatenazione del riferimento tilde nel campo Intervallo o espressione formula della sezione Definisci Finestra di dialogo Nome.
- Una matrice lineare (ad esempio, {1, 2, 3; 4, 5, 6}).
Riga è un valore intero non negativo o un riferimento a una cella contenente tale valore, ovvero l'offset di riga richiesto dall'angolo superiore sinistro della tabella dati.
Nel caso di una formula di matrice, l'argomento Riga può essere inserito come array in linea per recuperare più valori.
Nel contesto della matrice, omettere l'argomento Riga (con due punti e virgola consecutivi) o impostarlo sul valore speciale 0 (zero) indica che i valori per tutte le righe dovrebbero essere restituiti per la colonna specificata.
Colonna è un valore intero non negativo o un riferimento a una cella contenente tale valore, ovvero l'offset della colonna richiesto dall'angolo superiore sinistro della tabella dati.
Nel caso di una formula di matrice, l'argomento Colonna può essere inserito come array in linea per recuperare più valori.
Nel contesto della matrice, omettere l'argomento Colonna (con due punti e virgola consecutivi) o impostarlo sul valore speciale 0 (zero) indica che i valori per tutte le colonne dovrebbero essere restituiti per la riga specificata.
Intervallo è un valore intero positivo (il valore predefinito è 1), o un riferimento a una cella contenente tale valore, che indica il sottointervallo da utilizzare quando l'argomento Riferimento comprende più aree.
Ad esempio, se Riferimento è impostato su A1:B6~C2:D7~E3:F8, imposta Intervallo su 1 per l'intervallo di celle A1: B6, imposta Intervallo su 2 per l'intervallo di celle C2:D7 e imposta Intervallo su 3 per l'intervallo di celle E3:F8.
Nel caso di una formula di matrice, l'argomento Intervallo può essere inserito come matrice lineare per recuperare più valori.
Possono verificarsi le seguenti condizioni:
- Se un valore qualsiasi di Riga, Colonna o Intervallo non è numerico, allora INDICE riporta un #VALORE! errore.
- Se un valore qualsiasi di Riga, Colonna o Intervallo non è un numero intero, allora INDICE lo tronca a un numero intero.
- Se, dopo qualsiasi troncamento, Riga o Colonna è un valore negativo, allora INDICE riporta un errore di argomento non valido (Err:502).
- Se, dopo qualsiasi troncamento, Riga è maggiore del numero di righe nell'intervallo di celle indicizzato dall'argomento Intervallo, allora INDICE segnala un errore di argomento non valido (Err:502).
- Se, dopo qualsiasi troncamento, Colonna è maggiore del numero di colonne nell'intervallo di celle indicizzato dall'argomento Intervallo, allora INDICE segnala un errore di argomento non valido (Err:502).
- Se, dopo qualsiasi troncamento, Intervallo è inferiore a 1 o maggiore del numero di intervalli di celle definiti in Riferimento, allora INDICE riporta un errore #RIF!.
Dettagli aggiuntivi:
- INDICE può essere utilizzato in una formula di matrice. Ad esempio, inserisci la formula in forma di matrice {
=INDICE($A$1:$D$4; {1;3}; 2) } utilizzando Ctrl+Shift+Enter ("CSE") anziché semplicemente Inserisci. Vengono restituiti due valori: il valore della cella B1 viene visualizzato nella cella della formula e il valore della cella B3 viene visualizzato nella cella sotto la cella della formula.
- Per i valori delle matrici lineari, i rispettivi separatori da utilizzare nelle formule possono essere configurati in ▸ ▸ ▸ , nell'area Separatori.
Esempi:
La prima serie di esempi utilizza la seguente tabella di dati:
A
B
C
D
1
2
4
5
6
3
rosso
verde
blu
4
VERO
FALSO
VERO
Formula
Descrizione
Restituisce
=INDICE(B2:D4; 1; 1)
Restituisce i dati nella cella B2. Gli argomenti Riga e Colonna sono offset relativi all'intervallo di celle fornito, non relativi al foglio di calcolo.
4
=INDICE(DataTable; G1; G2)
dove DataTable è il nome di un intervallo di database che comprende l'intervallo di celle B2:D4 e dove le celle G1 e G2 contengono entrambe il numero 2.
Restituisce il valore nella cella C3, che è l'intersezione della seconda riga con la seconda colonna all'interno di DataTable.
verde
=INDICE(C3:D4; 2; 2)
Restituisce il valore della cella D4.
VERO
=INDICE(B2:B4; 3)
Restituisce il valore nella terza cella, B4. Utilizza la sintassi semplificata disponibile per un set di dati a colonna singola.
VERO
=INDICE(B3:D3; 2)
Restituisce il valore nella seconda cella, C3. Utilizza la sintassi semplificata disponibile per un set di dati a riga singola.
verde
{ =INDICE(B2:D4; 2; 0) }
usando CSE.
Restituisce una riga dei tre valori dalla seconda riga dei dati di input.
Nella cella della formula appare la stringa "rossa"; "verde" appare nella cella successiva a destra, mentre "blu" nella cella a destra.
rosso
verde
blu
{ =INDICE(B2:D4; 0; 2) }
usando CSE.
Restituisce una colonna dei tre valori dalla seconda colonna dei dati di input.
Nella cella della formula appare il numero 5; "verde" appare nella cella sottostante, con il numero 0 (zero) nella cella sottostante.
Il valore booleano originale FALSO viene convertito nel suo valore numerico in questo scenario.
5
verde
0
{ =INDICE(B2:D4; {2; 3}; 3) }
usando CSE.
Restituisce una colonna del secondo e del terzo valore dalla terza colonna dell'intervallo di riferimento; celle D3 e D4 dei dati di input.
La stringa "blu" appare nella cella della formula e il valore 1 appare nella cella sottostante.
Il valore booleano originale VERO viene convertito nel suo valore numerico in questo scenario.
blu
1
La tabella seguente fornisce esempi aggiuntivi non correlati alla tabella dei dati dell'esempio precedente.
Formula
Descrizione
Restituisce
=INDICE(A1:C3~A5:C7~A9:C11; 1; 1)
=INDICE(A1:C3~A5:C7~A9:C11; 1; 1; 1)
Quando non viene specificato alcun valore per l'argomento Intervallo, viene utilizzato il valore predefinito 1.
Restituisce i dati nella cella che risiede all'intersezione tra riga 1 e colonna 1, nella prima area definita nell'argomento Riferimento.
Contenuto della cella A1
=INDICE(A1:C3~A5:C7~A9:C11; 1; 1; 2)
Restituisce i dati nella cella che risiede all'intersezione tra riga 1 e colonna 1, nella seconda area definita nell'argomento Riferimento.
Contenuto della cella A5
=INDICE(TreAree; 3; 3; 3)
dove TreAree è stato definito come un intervallo denominato utilizzando l'espressione di riferimento $A$1:$C$3~$A$5:$C$7~$A$9:$C$11.
Restituisce i dati nella cella che risiede all'intersezione tra riga 3 e colonna 3, nella terza area definita nell'argomento Riferimento.
Contenuto della cella C11
{ =INDICE(TreAree; 2; 2; {1;2;3}) }
utilizzando CSE.
TreAree è stato definito come un intervallo denominato utilizzando l'espressione di riferimento $A$1:$C$3~$A$5:$C$7~$A$9:$C$11.
{1;2;3} è un array in linea di una colonna di 3 righe per l'argomento Intervallo, utilizzando il punto e virgola come separatore di riga.
Restituisce i dati nella cella che risiede all'intersezione tra riga 2 e colonna 2, in ciascuna delle tre aree definite nell'argomento Riferimento.
Vengono restituiti i tre valori, disposti in una colonna.
Contenuto delle celle B2, B6 e B10
{ =INDICE({1,3,5; 7,9,10}; {2;1}; 1; 1) }
utilizzando CSE.
<codice>{1,3,5; 7,9,10} è una matrice in linea di 3 colonne per 2 righe, che utilizza il punto e virgola come separatore di riga e la virgola come separatore di colonna.
Organizzato in una colonna di due righe: dalla seconda riga, restituisce il primo valore; dalla prima riga, restituisce il primo valore.
7
1
=CELLA("address"; INDICE(A2:C6; 2; 2))
La funzione INDICE restituisce il riferimento alla cella B3.
La funzione CELLA restituisce quindi l'indirizzo assoluto della cella B3.
$B$3
Funzioni di LibreOffice correlate:
Standard ODF:
Tipo di INDICE() descrizione per un vettore riga unidimensionale
Funzioni equivalenti (o simili) di Excel:
INDEX