Dokumentation/Calc Funktionen/INDEX

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/INDEX and the translation is 100% complete.
    Other languages:


    Funktionsname:

    INDEX

    Kategorie:

    Tabelle

    Zusammenfassung:

    In seiner einfachsten Form wird INDEX genutzt, um den Wert in einer durch relative Zeilen- und Spaltennummern bestimmten Zelle zu erhalten. Abhängig vom Kontext wird INDEX auch genutzt, um den Zellbezug am Schnittpunkt zwischen der angegebenen Zeile und Spalte zu bestimmen.

    INDEX ist eine mächtige Funktion, die genutzt werden kann, um Werte in mehreren, nicht zusammenhängenden Zellen zu erhalten und um mehrere Werte aus einem Zellbereich zu erhalten. Die Flexibilität wird erhöht, wenn INDEX zusammen mit der Funktion VERGLEICH genutzt wird, um den Formeln eine bessere Reaktion auf Änderungen der Eingabedaten zu ermöglichen.

    Syntax:

    Die allgemeine Syntax für die Funktion INDEX ist:

    • INDEX(Referenz[; Zeile[; Spalte[; Bereich]]])

    Im speziellen Fall, dass das erste Argument nur eine einzelne Spalte enthält, kann die folgende vereinfachte Syntax genutzt werden:

    • INDEX(Referenz; Zeile)

    Im speziellen Fall, dass das erste Argument lediglich eine einzelne Zeile beinhaltet, kann die folgende alternative Syntax genutzt werden:

    • INDEX(Referenz; Spalte)

    Rückgabewerte:

    Theoretisch gibt INDEX einen Zellbezug zurück. Abhängig von der genutzten Funktion kann der Rückgabewert auch als Daten Wert (wobei der Typ von den Eingabedaten bestimmt wird) oder als Zellbezug gesehen werden.

    Argumente:

    Referenz ist eine Referenzliste die den/die Zellbereich(e), die von der/den Eingabetabelle(n) belegt sind angibt. Dabei werden folgende Formen verwendet:

    • Ein einzelner Zellbereich (z. Bsp. A1:E10).
    • Mehrere Zellbereiche können in einem einzelnen Argument mitgegeben werden, indem Sie in einer eigenen Liste in Klammern angegeben werden - z.Bsp. =INDEX((A1:B6; C2:D7; E3:F8); …). In diesem Fall formatiert Calc den Funktionsaufruf mit dem Bereichsverbinder, also der Tilde, um - z. Bsp. in =INDEX((A1:B6~ C2:D7~ E3:F8)). Alternativ kann der Bereichsverbinder, die Tilde, direkt ohne die Klammern verwendet werden- z. Bsp. =INDEX(A1:B6~C2:D7~E3:F8).
    • Ein einzelner Zellbereich mit dem Namen eines Datenbankbereiches adressiert (definiert durch die Auswahl Daten ▸ Bereich festlegen... in der Menüzeile).
    • Ein oder mehrere Zellbereich(e) referenziert durch den Namen eines benannten Bereiches. Benannte Bereiche können durch Tabelle ▸ benannte Bereiche ▸ Festlegen... in der Menüzeile angelegt werden, um mehrere Bereiche mit dem Verbindungsoperator Tilde im Bereich oder Formelausdruck im Dialog Namen festlegen festzulegen.
    • Eine Aufzählung (z. Bsp. {1, 2, 3; 4, 5, 6}).

    Zeile ist eine nicht-negative Ganzzahl oder eine Refrerenz, die die Ganzzahl enthält. Diese Ganzzahl ist der erforderliche Zeilen-Abstand von oben links der Datentabelle. Im Fall einer Matrix-Formel kann die Zeile als Aufzählung angegeben werden, um mehrere Werte zu erhalten. Wenn im Feld-Kontext die Zeile fehlt (mit zwei aufeinander folgenden Strichpunkten) oder indem sie direkt auf den Wert 0 (Null) gesetzt wird, heißt das, dass Werte aus allen Zeilen für die angegebene Spalte zurückgegeben werden sollen.

    Spalte ist eine nicht-negative Ganzzahl oder eine Refrerenz, die die Ganzzahl enthält. Diese Ganzzahl ist der erforderliche Spalten-Abstand von oben links der Datentabelle. Im Fall einer Matrix-Formel kann die Spalte als Aufzählung angegeben werden, um mehrere Werte zu erhalten. Wenn im Feld-Kontext die Spalte fehlt (mit zwei aufeinander folgenden Strichpunkten) oder indem sie direkt auf den Wert 0 (Null) gesetzt wird, heißt das, dass Werte aus allen Spalten für die angegebene Zeile zurückgegeben werden sollen.

    Bereich ist eine positive Ganzzahl (Standardwert 1) oder eine Referenz auf eine Zelle mit dieser Ganzzahl. Diese Ganzzahl zeigt den Unterbereich an, wenn die Referenz mehrere Bereiche angibt. Wenn z. Bsp. für die Referenz A1:B6~C2:D7~E3:F8 angegeben ist, dann wird der Bereich für den Zellbereich A1:B6 auf 1, für den Zellbereich C2:D7 auf 2 und für den Zellbereich E3:F8 auf 3 gesetzt. Im Fall einer Matrix-Formel kann der Bereich als Aufzählung angegeben werden, um mehrere Werte zu erhalten.

    Die folgenden Fälle können auftreten:

    • Falls entweder die Zeile, die Spalte oder der Bereich nicht numerisch ist, dann meldet INDEX einen #WERT!-Fehler.
    • Falls entweder die Zeile, die Spalte oder der Bereich kein ganzzahliger Wert ist, verkürzt ihn INDEX auf einen ganzzahligen Wert.
    • Falls nach einer eventuellen Verkürzung entweder die Zeile oder die Spalte ein negativer Wert ist, meldet INDEX einen invalid argument error (Fehler:502).
    • Falls nach einer eventuellen Verkürzung die Zeile größer als die Anzahl der Zeilen im Zellbereich des Bereiches ist, meldet INDEX einen invalid argument error (Fehler:502).
    • Falls nach einer eventuellen Verkürzung die Spalte größer als die Anzahl der Spalten im Zellbereich des Bereiches ist, meldet INDEX einen invalid argument error (Fehler:502).
    • Falls nach einer eventuellen Verkürzung der Bereich kleiner als 1 oder größer als die Anzahl der Zellbereiche in der Referenz ist, meldet INDEX einen #BEZUG! Fehler.

    Zusätzliche Informationen:

    • INDEX kann in einer Matrix-Formel verwendet werden. Zum Beispiel wird die Formel { =INDEX($A$1:$D$4; {1;3}; 2) } unter Verwendung von Strg + Umschalt + Enter ("SUE") statt nur Enter. Es werden zwei Werte zurückgegeben - der Wert aus Zelle B1 wird in der Formelzelle angezeigt und der Wert aus Zelle B3 wird in der Zelle darunter angezeigt.
    • Für Aufzählungen kann das Trennzeichen in Formeln unter Extras ▸ Optionen ▸ LibreOffice Calc ▸ Formel im Bereich Trennzeichen eingestellt werden.

    Beispiele:

    Der erste Stapel Beispiele nutzt die folgende Datentabelle:

    A B C D
    1
    2 4 5 6
    3 rot grün blau
    4 WAHR FALSCH WAHR
    Formel Beschreibung Ergebnis
    =INDEX(B2:D4; 1; 1) Gibt die Daten in Zelle B2 zurück. Die Zeile und Spalte sind relative Abstände zum angegebenen Zellbereich, nicht zur Tabelle. 4
    =INDEX(Datentabelle; G1; G2)

    wobei die Datentabelle der Name des Datenbankbereichs B2:D4 ist und die Zellen G1 und G2 jeweils die Zahl 2 enthalten.

    Gibt den Wert in Zelle C3, dem Schnittpunkt zwischen der zweiten Zeile und der zweiten Spalte in der Datentabelle, zurück. grün
    =INDEX(C3:D4; 2; 2) Gibt den Wert in Zelle D4 zurück. WAHR
    =INDEX(B2:B4; 3) Gibt den Wert in der dritten Zelle, B4, zurück. Dabei wird die vereinfachte Syntax für ein einspaltiges Daten-Set verwendet. WAHR
    =INDEX(B3:D3; 2) Gibt den Wert in der zweiten Zelle, C3, zurück. Dabei wird die vereinfachte Syntax für ein einzeiliges Daten-Set verwendet. grün
    =INDEX(B2:D4; 2; 0) }

    Verwendung von SUE.

    Gibt eine Zeile von drei Werten aus der zweiten Zeile der Eingabedaten zurück.

    Der Text "rot" erscheint in der Formelzelle; "grün" erscheint in der nächsten Zelle rechts und "blau" in der Zelle rechts davon.

    rot grün blau
    =INDEX(B2:D4; 0; 2) }

    Verwendung von SUE.

    Gibt eine Spalte von drei Werten aus der zweiten Spalte der Eingabedaten zurück.

    Die Zahl 5 erscheint in der Formelzelle; "grün" erscheint in der nächsten Zelle darunter und die Zahl 0 (Null) in der Zelle darunter. Der originale Wahrheitswert FALSCH wird in diesem Szenario in seinen numerischen Wert konvertiert.

    5
    grün
    0
    =INDEX(B2:D4; {2; 3}; 3) }

    Verwendung von SUE.

    Gibt eine Spalte aus dem zweiten und dem dritten Wert aus der dritten Spalte des Referenzbereiches, der Zellen D3 und D4 der Eingabedaten, zurück. Der Text "blau" erscheint in der Formelzelle und der Wert 1 in der Zelle darunter.

    Der originale Wahrheitswert WAHR wird in diesem Szenario in seinen numerischen Wert konvertiert.

    blau
    1

    Die folgende Tabelle gibt zusätzliche Beispiele, die nichts mit der Beispielstabelle oben zu tun haben.

    Formel Beschreibung Ergebnis
    =INDEX(A1:C3~A5:C7~A9:C11; 1; 1)

    =INDEX(A1:C3~A5:C7~A9:C11; 1; 1; 1)

    Wenn im Bereich nichts angegeben ist, wird der Standardwert 1 verwendet.

    Gibt die Daten im Schnittpunkt zwischen Zeile 1 und Spalte 1 des ersten Bereiches der Referenz zurück.

    Inhalte der Zelle A1
    =INDEX(A1:C3~A5:C7~A9:C11; 1; 1; 2) Gibt die Daten im Schnittpunkt zwischen Zeile 1 und Spalte 1 des zweiten Bereiches der Referenz zurück. Inhalte der Zelle A5
    =INDEX(DreiBereiche; 3; 3; 3)

    wobei DreiBereiche als benannter Bereich mit der Referenz $A$1:$C$3~$A$5:$C$7~$A$9:$C$11 definiert wurde.

    Gibt die Daten in der Zelle im Schnittpunkt der Zeile 3 und Spalte 3 im dritten Bereich der Referenz zurück. Inhalte der Zelle C11
    =INDEX(DreiBereiche; 2; 2; {1;2;3}) }

    unter Verwendung von SUE. DreiBereiche wurde als benannter Bereich mit der Referenz $A$1:$C$3~$A$5:$C$7~$A$9:$C$11 definiert. {1;2;3} ist eine einspaltige Aufzählung aus drei Zeilen für den Bereich unter Verwendung des Strichpunktes als Zeilentrenner.

    Gibt die Daten in der Zelle im Schnittpunkt der Zeile 2 und Spalte 2 in jeder der drei Bereiche der Referenz zurück. Die drei Werte werden in einer Spalte angeordnet zurückgegeben.

    Inhalte der Zellen B2, B6 und B10
    =INDEX({1,3,5; 7,9,10}; {2;1}; 1; 1) }

    unter Versendung von SUE. {1,3,5; 7,9,10} ist eine 3-spaltige und 2-zeilige Aufzählung mit einem Strichpuknt als Zeilentrenner und einem Komma als Spaltentrenner.

    Organisiert in einer Spalte mit zwei Zeilen: aus der zweiten Zeile wird der erste Wert und aus der ersten Zeile wird der erste Wert zurückgegeben.
    7
    1
    =ZELLE("address"; INDEX(A2:C6; 2; 2))

    Die Funktion INDEX gibt die Referenz auf Zelle B3 zurück. Die Funktion ZELLE gibt dann die absolute Adresse der Zelle B3 zurück.

    $B$3

    Ähnliche LibreOffice Funktionen:

    BEREICHE

    WAHL

    VERGLEICH

    ODF Standard:

    Kapitel 6.14.6, Teil 2.

    Tippfehler in INDEX() Beschreibung für einen eindimensionalen Zeilen-Vektor

    Betroffene (oder ähnliche) EXCEL-Funktionen:

    INDEX