Documentation/Calc Functions/ISNUMBER

From The Document Foundation Wiki
Jump to navigation Jump to search
This page contains changes which are not marked for translation.
Other languages:
English • ‎Nederlands



Function name:

ISNUMBER

Category:

Information

Summary:

Determines whether the supplied argument results in a number.

Syntax:

ISNUMBER(Value)

Returns:

Returns TRUE if the argument evaluates to a number and FALSE otherwise.

Arguments:

Value is an expression, or a reference to a cell containing an expression, that is to be tested to determine if it evaluates to a number.

  • If Value evaluates to a logical value (TRUE or FALSE) or a date-time, then ISNUMBER returns TRUE.

Additional details:

  • ISNUMBER does not propagate errors. If Value evaluates to a number, then ISNUMBER returns TRUE and returns FALSE otherwise.
  • For arguments that evaluate to logical values, Calc's ISNUMBER function differs from the corresponding Microsoft Excel function (presumably because the two applications handle logical values in different ways). While Calc returns the value TRUE for the formula =ISNUMBER(TRUE()), Excel returns FALSE for the same formula.

Examples:

Formula Description Returns
=ISNUMBER(83.94) Here the function returns TRUE because the argument is a number. TRUE
=ISNUMBER(FALSE()) Here the function returns TRUE because internally Calc represents logical values as numbers. TRUE
=ISNUMBER(TODAY()) Here the function returns TRUE because internally Calc represents dates as numbers. TRUE
=ISNUMBER(D1) where cell D1 contains the string "LibreOffice Calc". Here the function returns FALSE because the argument is a reference to a cell containing a text string. FALSE
=ISNUMBER(D2) where cell D2 is empty. Here the function returns FALSE because the argument is a reference to an empty cell. FALSE
=ISNUMBER(SQRT(-2)) Here the function returns FALSE because SQRT(-2) returns an error condition (Err:502) rather than a number. FALSE

Related LibreOffice functions:

ISLOGICAL

ISTEXT

ODF standard:

Section 6.13.22, part 2

Equivalent Excel functions:

ISNUMBER