Dokumentation/Calc Funktionen/VERWEIS
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende
Funktionsname:
VERWEIS
Kategorie:
Tabelle
Zusammenfassung:
Führt eine Suche auf einen eindimensionalen Zellbereich (auch bekannt als Vektor) durch. Vergleicht einen angegebenen Wert mit den Einträgen in dem sortierten Suchvektor und, wenn ein Treffer gefunden wurde, wird der Inhalt der entsprechenden Zelle in einem Ergebnisvektor ausgegeben.
Der Suchprozess verwendet entweder Platzhalter oder reguläre Ausdrücke. Standardmässig ist die Suche nicht case-sensitiv. Eine case-sensitive Suche kann unter Verwendung eines regulären Ausdruckes durchgeführt werden.
Syntax:
VERWEIS(Suchkriterium; Suchvektor[; Ergebnisvektor])
Rückgabewerte:
Gibt den Inhalt einer Zelle im Ergebnisvektor (falls angegeben) oder einen Wert aus dem Suchvektor (kein Ergebnisvektor angegeben) zurück. Die Rückgabedaten sind entweder numerisch oder nicht numerisch, je nach Kontext.
Argumente:
Suchkriterium ist ein Text (in Anführungszeichen), eine Zahl, ein Wahrheitswert oder eine Referenz auf eine Zelle, die einen dieser Typen enthält. Das Suchkriterium wird gegen die Zellinhalte im Suchvektor abgeglichen.
Suchvektor gibt einen Zellbereich an, typischerweise definiert durch Eingabe eines Zellbezuges für die Zelle oben links, gefolgt von einem Doppelpunkt (:), dann dem Zellbezug für die Zelle unten rechts (z. Bsp. A1:E10). Er kann ebenso durch Angabe des Namens eines benannten Bereiches oder eines Datenbankbereiches erfolgen oder durch eine Aufzählung angegeben werden.
Falls der Suchvektor ein multidimensionaler Zellberich ist, untersucht VERWEIS seine Dimensionen wie folgt:
- Falls der Bereich ein Quadrat ist, oder höher als breit, dann prüft VERWEIS das Suchkriterium gegen die Inhalte der ersten Spalte des Suchvektors.
- Falls in diesem Fall der Ergebnisvektor fehlt, wird ein Wert aus der letzten Spalte des Suchvektors zurückgegeben.
- Falls der Bereich breiter als hoch ist, dann prüft VERWEIS das Suchkriterium gegen die Inhalte der ersten Zeile des Suchvektors.
- Falls in diesem Fall der Ergebnisvektor fehlt, wird ein Wert aus der letzten Zeile des Suchvektors zurückgegeben.
Der gesuchte Vektor muss geordnet sein wie im Abschnitt #Zusätzliche Informationen: weiter unten beschrieben. Dies ermöglicht VERWEIS sowohl exakte als auch ungenaue (best-fit) Treffer.
Der Ergebnisvektor gibt einen eindimensionalen Zellbereich mit zurückzugebenden Werten an. Dieser Bereich wird typischerweise definiert durch Eingabe eines Zellbezuges für die Zelle oben links, gefolgt von einem Doppelpunkt (:), dann dem Zellbezug für die Zelle unten rechts (z. Bsp. A1:A10). Er kann ebenso durch Angabe des Namens eines benannten Bereiches oder eines Datenbankbereiches erfolgen oder durch eine Aufzählung angegeben werden.
- Falls der Suchvektor nicht wie erwartet sortiert ist, wird das von VERWEIS zurückgegebene Ergebnis unberechenbar. In solchen Fällen wird kein Fehler gemeldet und es kann ein offensichtlich bedeutungsloses Ergebnis zurückgegeben werden.
- Falls das Suchkriterium vor dem Inhalt der ersten Zelle im Suchvektor liegt, dann meldet VERWEIS einen #NV-Fehler (Wert nicht verfügbar).
- Falls der Ergebnisvektor ein multidimensionaler Zellbereich ist, dann meldet VERWEIS einen Fehler in der Parameterliste (Fehler:504).
- Der Suchvektor und der Ergebnisvektor müssen nicht gleich lang sein. Der eine kann ein Spaltenvektor und der andere ein Zeilenvektor sein.
- Falls der Ergebnisvektor eine Aufzählung ist, und der Treffer außerhalb seiner Länge liegt, dann meldet VERWEIS einen Wert nicht verfügbar Fehler (#NV).
- Falls der Ergebnisvektor ein Zellbereich ist und der Treffer außerhalb seiner Länge liegt, verlängert er sich automatisch bis zur Länge des Suchvektors, aber in Richtung des Ergebnisvektors.
- Falls der Ergebnisvektor eine Referenz auf eine einzelne Zelle ist (und daher keine implizite Richtung hat), verlängert ihn VERWEIS als Spaltenvektor.
Zusätzliche Informationen:
Spezifische Eigenheiten der Funktion VERWEIS
- Falls der gesuchte Vektor mehrere Zellen mit dem gleichen Inhalt enthält, meldet VERWEIS nur eine der Zellen mit dem gemeinsamen Inhalt und das könnte ein Grund zur Verwirrung sein.
- Der gesuchte Vektor muss zunächst nach Zahlen in aufsteigender Reihenfolge, dann alphabetisch aufsteigend sortiert sein. Die Wahrheitswerte FALSCH und WAHR werden wie die Zahlen 0 und 1 behandelt. VERWEIS errechnet, wo das Suchkriterium in der sortierten Reihenfolge auftaucht.
- Falls genau eine Übereinstimmung zwischen dem Suchkriterium und einem der Einträge im Suchvektor existiert, wird diese Position zur Bestimmung des Rückgabewertes verwendet.
- Falls keine Übereinstimmung zwischen dem Suchkriterium und einem der Einträge im Suchvektor existiert, meldet VERWEIS den längsten Eintrag im Suchvektor, der kleiner als das Suchkriterium ist.
- Falls ein multidimensionaler Zellbereich als Suchvektor verwendet werden soll, ist eine der flexibleren Funktionen WVERWEIS und SVERWEIS geeigneter.
- Falls reguläre Ausdrücke im Bereich Platzhalter in Formeln des Dialoges ▸ ▸ ▸ (oder ▸ ▸ ▸ unter macOS) eingeschaltet sind, findet VERWEIS exakte Treffer unter Verwendung des Suchkriteriums als regulären Ausdruck.
- Falls Platzhalter im Bereich Platzhalter in Formeln des Dialoges ▸ ▸ ▸ (oder ▸ ▸ ▸ unter macOS) eingeschaltet sind, findet VERWEIS exakte Treffer unter Verwendung des Suchkriteriums als Platzhalter.
- Falls die Option Suchkriterien = und <> müssen auf ganze Zellen zutreffen in den Allgemeinen Berechnungen des Dialoges ▸ ▸ ▸ (oder ▸ ▸ ▸ unter macOS) angeklickt ist, dann muss das Suchkriterium mit dem ganzen Text in einer Zelle übereinstimmen. Ansonsten kann es auch nur mit einem Teil des Textes übereinstimmen.
- Die Option Groß- und Kleinschreibung im Bereich Allgemeine Berechnungen des Dialoges ▸ ▸ ▸ (oder ▸ ▸ ▸ unter macOS) hat keine Auswirkung auf die Ausführung von VERWEIS.
Allgemeine Informationen über die regulären Ausdrücke in Calc
 |
Anmerkung:
|
- Ein regulärer Ausdruck ist eine Zeichenkette die ein Textmuster beschreibt. Genauere allgemeine Hintergrundinformationen finden sich in der Wiki Regulärer Ausdruck
- Reguläre Ausdrücke sind weit verbreitet. Dabei gibt es viele Prozessoren für reguläre Ausdrücke. Calc nutzt den open source Regular Expressions package from the International Components for Unicode (ICU). Siehe bitte unter deren Dokumentation zu den regulären Ausdrücken für weitergehende Informationen inklusive der volständigen Beschreibung zur Syntax der ICU Regular Expressions.
- Zusätzlich stellt die LibreOffice Hilfe eine umfangreiche Liste der regulären Ausdrücke zur Verfügung.
- Calcs Generator für reguläre Ausdrücke unterstützt zahlreiche Erfassungs Möglichkeiten, welche es Untergruppen in einem Bereich erlauben innerhalb eines Treffers identifiziert zu werden und in einem Text ersetzt werden können. Runde Klammern werden genutzt um Komponenten eines regulären Ausdruckes zu gruppieren und eine nummerierte Treffer-Liste zu erzeugen. Um eine solche Treffer-Liste in einen Text einzufügen, verwenden Sie bitte das Kürzel "$n", wobei n die Zahl der Treffer-Liste ist.
Allgemeine Informationen über die Platzhalter in Calc
Platzhalter sind spezielle Zeichen für Suchtexte in Argumenten für einige Funktionen in Calc; sie können auch im Suchdialog verwendet werden. Der Gebrauch von Platzhaltern ermöglicht fortgeschrittenere Suchparamter bei einer einfachen Textsuche.
Calc unterstützt entweder Platzhalter oder reguläre Ausdrücke abhängig von den Einstellungen der aktuellen Applikation. Standardmäßig werden Platzhalter statt regulärer Ausdrücke unterstützt.
Um sicherzustellen, dass Platzhalter unterstützt werden, rufen Sie ▸ ▸ ▸ auf. Überprüfen Sie hier, ob die Einstellung Platzhalter in Formeln ermöglichen ausgewählt ist. Beachten Sie auch, dass reguläre Ausdrücke durch Auswählen von Reguläre Ausdrücke in Formeln ermöglichen unterstüzt werden können. Genauso können Sie weder Platzhalter noch reguläre Ausdrücke unterstützen lassen.
Die folgende Tabelle zeigt die Platzhalter, die Calc unterstützt.
| Platzhalter | Beschreibung |
|---|---|
| ? (Fragezeichen) | Vertritt ein einzelnes Zeichen. Zum Beispiel kann der Suchtext "b?g" "bag" oder "beg" heißen, aber nicht "boog" oder "mug". Beachte, dass es auch nicht "bg" heißen kann, da "?" genau ein Zeichen sein muss. Der Platzhalter "?" vertritt kein fehlendes Zeichen. |
| * (Asterisk) | Vertritt eine Reihe von Zeichen inklusive dem Leer-Text. Zum Beispiel vertritt der Text "*cast" "cast", "forecast" und "outcast", aber nicht "forecaster" unter Verwendung der Standardeinstellungen von Calc. Falls die Einstellung Suchkriterien = und <> müssen auf ganze Zellen zutreffen in ▸ ▸ ▸ ausgeblendet ist, dann wird "forecaster" auch durch *cast vertreten. |
| ~ (Tilde) | Unterdrückt die Sonderbehandlung des Fragezeichens Asterisken oder der Tilde, welche direkt nach der Tilde kommen. Zum Beispiel, stellt der Suchstring "why~?" nur "why?" und nicht "whys" oder "why~s" dar. |
Platzhalter sind nicht case sensitiv, also "A?" heißt sowohl "A1" also auch "a1".
Diese Platzhalter werden sowohl in Calc als auch in Microsoft EXCEL unterstützt. Wenn also Kompatibilität zwischen den beiden Anwendungen erforderlich ist, arbeiten Sie mit Platzhaltern anstatt mit regulären Ausdrücken. Wenn dagegen Kompatibilität nicht notwendig ist, arbeiten Sie stattdessen mit regulären Ausdrücken für mächtigere Möglichkeiten.
Beispiele:
Die folgende Tabelle zeigt den Namen, Identifikationsnummer und das Testergebnis für zehn Studenten. Die Tabelle ist alphabetisch nach den Namen der Studenten sortiert und daher können die Daten in den Zellen A2:A11 als Suchvektor in der Funktion VERWEIS verwendet werden. Diese einfache Tabelle kann das Verhalten von VERWEIS demonstrieren.
| A | B | C | |
|---|---|---|---|
| 1 | Name | ID des Studenten | Testergebnis |
| 2 | Andrew | 1257 | 32 |
| 3 | Bethany | 1470 | 80 |
| 4 | Charles | 1367 | 42 |
| 5 | David | 1497 | 65 |
| 6 | Emily | 1730 | 50 |
| 7 | Ferdinand | 1414 | 41 |
| 8 | Georgia | 1364 | 17 |
| 9 | Haley | 1778 | 46 |
| 10 | Ian | 1769 | 90 |
| 11 | Jennifer | 1530 | 35 |
| Formel | Beschreibung | Ergebnis |
|---|---|---|
| =VERWEIS("Haley"; A2:C11) | Hier ist der Suchvektor ein multidimensionaler Zellbereich (mit grösserer Höhe als Breite) und der Ergebnisvektor fehlt. Die Funktion findet den Text "Haley" in der ersten Spalte des Suchvektors und gibt dessen Testergebnis von der entsprechenden Position in der letzten Spalte zurück. Die Formel =VERWEIS("Haley"; A2:A11; C2:C11) gibt das gleiche Ergebnis zurück. |
46 |
| =VERWEIS(G2; A2:C11), wobei die Zelle G2 den Text "Ailsa" (ohne die Anführungszeichen) enthält. | Hier ist der Suchvektor wieder ein multidimensionaler Zellbereich (mit grösserer Höhe als Breite) und der Ergebnisvektor fehlt. Die Funktion sucht den Text "Ailsa" in der ersten Spalte des Suchvektors. Aber da "Ailsa" alphabetisch vor dem ersten Namen in der Liste ("Andrew") ist, wird ein Fehler gemeldet. Die Formel =VERWEIS(G2; A2:A11) gibt das selbe Ergebnis. |
#NV |
| =VERWEIS("Ken"; A2:C11) | Hier ist der Suchvektor wieder ein multidimensionaler Zellbereich (mit grösserer Höhe als Breite) und der Ergebnisvektor fehlt. Die Funktion sucht den Text "Ken" in der ersten Spalte des Suchvektors und findet "Ken" alphabetisch hinter dem letzten Namen in der Liste ("Jennifer"). Das Testergebnis der letzten Person in der Liste wird zurückgegeben. Die Formel =VERWEIS("Ken"; A2:A11; C2:C11) gibt das selbe Ergebnis. |
35 |
| =VERWEIS("Evan"; A2:A11) | Hier ist der Suchvektor ein eindimensionaler Zellbereich und der Ergebnisbereich fehlt. Die Funktion sucht nach dem Text "Evan" in der ersten Spalte des Suchvektors und findet "Evan" nach "Emily" aber vor "Ferdinand" in der sortierten Liste. Sie gibt daher den Text "Emily" zurück. | Emily |
| =VERWEIS("David"; A2:A11; B2:B11) | Hier ist der Suchvektor ein eindimensionaler Zellbereich und der Ergebnisvektor ist angegeben. Die Funktion findet den Text "David" im Suchvektor und gibt dessen Identifikationsnummer von der entsprechenden Position im Ergebnisvektor zurück. Die Formeln =VERWEIS("David"; A2:B11) und =VERWEIS("David"; A2:A11; B2:B3) liefern das selbe Ergebnis. |
1497 |
Die folgende Tabelle und die entsprechenden Beispiele nutzen einen Suchvektor der Zahlen, Wahrheitswerte und Texte beinhaltet.
| A | B | C | D | E | F | G | H | |
|---|---|---|---|---|---|---|---|---|
| 1 | −1 | FALSCH | WAHR | 3 | Wolke | Regen | Regenmantel | Sonne |
| 2 | ||||||||
| 3 | Pos. 1 | Pos. 2 | Pos. 3 | Pos. 4 | Pos. 5 | Pos. 6 | Pos. 7 | Pos. 8 |
| Formel | Beschreibung | Ergebnis |
|---|---|---|
| =VERWEIS(−0,5; A1:H1; A3:H3) | Hier erkennt die Funktion, dass das Suchkriterium im Suchvwektor zwischen -1 und FALSCH (0) liegt. VERWEIS nimmt den unteren Wert und übernimmt den korrespondierenden Wert in den Ergebnisvektor. | Pos. 1 |
| =VERWEIS(WAHR; A1:H1; A3:H3) | Hier erkennt die Funktion, dass das Suchkriterium mit dem Wert in Zelle C1 im Suchvektor übereinstimmt. VERWEIS gibt den entsprechenden Eintrag im Ergebnisvektor zurück. | Pos. 3 |
| =VERWEIS("Bereich"; A1:H1; A3:H3) | Hier erkennt die Funktion, dass das Suchkriterium alphabetisch vor jedem anderen Text im Suchvektor liegt und meldet den Fehler #NV. | #NV |
| =VERWEIS("^l.*"; A1:H1; A3:H3), wobei reguläre Ausdrücke zugelassen sind. | Hier wird der reguläre Ausdruck "^l.*" im Suchvektor ("Wolke") fündig und gibt den entsprechenden Eintrag im Ergebnisvektor zurück. | Pos. 5 |
| =VERWEIS("^ra.*"; A1:H1; A3:H3), wobei reguläre Ausdrücke zugelassen sind. | Hier wird der reguläre Ausdruck "^ra.*" im Suchvektor fündig ("Regenmantel") und gibt den entsprechenden Eintrag im Ergebnisvektor zurück. Das muss nicht unbedingt hilfreich sein, vor allem, wenn, wie hier, mehrere Einträge mit dem regulären Ausdruck übereinstimmen. | Pos. 7 |
| =VERWEIS("s*"; A1:H1; A3:H3), wobei Platzhalter zugelassen sind. | Hier wird der Platzhalter "s*" im Suchvektor ("Sonne") fündig und gibt den entsprechenden Eintrag im Ergebnisvektor zurück. | Pos. 8 |
| =VERWEIS("ra*"; A1:H1; A3:H3), wobei Platzhalter zugelassen sind. | Die Funktion findet einen Treffer für den Platzhalter "ra*" im Suchvektor ("Regenmantel") und gibt den entsprechenden Eintrag im Ergebnisvektor zurück. Das muss nicht unbedingt hilfreich sein, vor allem, wenn, wie hier, mehrere Einträge mit dem Platzhalter übereinstimmen. | Pos. 7 |
Das abschliessende Beispiel zeigt die Verwendung einer Aufzählung für den Suchvektor und den Ergebnisvektor.
| Formel | Beschreibung | Ergebnis |
|---|---|---|
| =VERWEIS(5; 1, 2, 3, 4, 5, 6, 7, 8, 9, 10; {"Wasserstoff", "Helium", "Lithium", "Beryllium", "Bor", "Kohlenstoff", "Stickstoff", "Sauerstoff", "Flour", "Neon"}) | Hier gibt die Funktion den Namen des Elementes mit der Kernladungszahl 5 zurück. | Bor |
Ähnliche LibreOffice Funktionen:
ODF Standard:
Betroffene (oder ähnliche) EXCEL-Funktionen:
LOOKUP