Dokumentation/Calc Funktionen/TEILB

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/MIDB and the translation is 100% complete.
    Other languages:


    Funktionsname:

    TEILB

    Kategorie:

    Text

    Zusammenfassung:

    Entnimmt aus dem angegebenen Text einen Teil ab der Startposition mit der angegebenen Länge in Bytes.

    Syntax:

    TEILB(Text; Start; Anzahl Bytes)

    Rückgabewerte:

    Gibt einen Text mit der angegebenen Anzahl Bytes ab der Startposition aus dem angegebenen Text zurück.

    Argumente:

    Text ist ein Text (in Anführungszeichen), eine Zahl oder eine Referenz auf eine Zelle mit einem dieser Typen. Das ist dann der Text, aus dem das Teilstück entnommen wird.

    Start ist eine positive Ganzzahl oder eine Referenz auf eine Zelle mit dieser Ganzzahl. Diese Ganzzahl ist die Position des ersten Bytes, das aus dem Text entnommen wird.

    Anzahl Bytes ist eine nicht-negative Ganzzahl oder eine Referenz auf eine Zelle mit dieser Ganzzahl. Das ist die Anzahl der aus dem Text zu entnehmenden Bytes.

    • Falls entweder der Start oder die Anzahl Bytes nicht numerisch sind, dann meldet TEILB einen #WERT!-Fehler.
    • Falls entweder der Start oder die Anzahl Bytes nicht ganzzahlig sind, dann verkürzt sie TEILB auf eine Ganzzahl.
    • Falls nach einer eventuellen Verkürzung der Start kleiner als 1 ist, dann meldet TEILB einen invalid argument error (Fehler:502).
    • Falls nach einer eventuellen Verkürzung der Start größer als der Text (in Bytes) ist, dann gibt TEILB einen leeren Text zurück.
    • Falls die Anzahl Bytes kleiner als 0 ist, dann meldet TEILB einen invalid argument error (Fehler:502).
    • Falls nach einer eventuellen Verkürzung die Anzahl Bytes gleich 0 ist, dann gibt TEILB einen leeren Text zurück.
    • Falls (Start + Anzahl Bytes – 1) größer als die Länge des Textes (in Bytes) ist, dann gibt TEILB einen Text vom Start bis zum Ende des Textes zurück.

    Zusätzliche Informationen:

    Spezifische Eigenheiten der Funktion TEILB

    Falls die angegebene Anzahl Bytes dazu führen würde, nur ein Byte eines zwei-Byte Zeichens zu entnehmen, fügt TEILB stattdessen ein Leerzeichen (Unicode U+0020) am Ende des zurückzugebenden Textes ein.

    =TEILB(Text; 1; Länge) entspricht =LINKSB(Text; Länge)


    Allgemeine Informationen über die Byte-Position Funktionen in Calc

    Note pin.svg

    Anmerkung:
    Der Einfachheit halber werden die Informationen dieses Unterabschnittes auf allen Seiten der Byte-Position Funktionen in Calc wiederholt.

    Calc bietet einige Byte-Position Text Funktionen, die mit Zwei-Byte Zeichensätzen (Double Byte Character Set (DBCS)) arbeiten. Diese Funktionen sind FINDENB, LINKSB, LÄNGEB,TEILB, ERSETZENB, RECHTSB und SUCHENB. Jede davon hat einen äquivalenten "normalen" Namen mit einem "B" am Ende.

    Calc bezeichnet als zwei-Byte Zeichen die Zeichen, die in folgenden Unicode-Abschnitten liegen:

    • Bopomofo Erweitert (U+31A0 ... U+31BF)
    • Bopomofo (U+3100 ... U+312F)
    • CJK Kompatibilitätsformen (U+FE30 ... U+FE4F)
    • CJK-Ideogramme, Kompatibilität, Ergänzung (U+2F800 ... U+2FA1F)
    • CJK-Ideogramme, Kompatibilität (U+F900 ... U+FAFF)
    • CJK Kompatibilität (U+3300 ... U+33FF)
    • CJK-Radikale, Ergänzung (U+2E80 ... U+2EFF)
    • CJK-Striche (U+31C0 ... U+31EF)
    • CJK-Symbole und -Interpunktion (U+3000 ... U+303F)
    • Vereinheitlichte CJK-Ideogramme, Erweiterung A (U+3400 ... U+4DBF)
    • Vereinheitlichte CJK-Ideogramme, Erweiterung B (U+20000 ... U+2A6DF)
    • Vereinheitlichte CJK-Ideogramme (U+4E00 ... U+9FFF)
    • Umschlossene CJK-Zeichen und -Monate (U+3200 ... U+32FF)
    • Halbbreite und vollbreite Formen (U+FF00 ... U+FFEF)
    • Hangeul-Jamo, Kompatibilität (U+3130 ... U+318F)
    • Hangeul-Jamo (U+1100 ... U+11FF)
    • Hangeul-Silbenzeichen (U+AC00 ... U+D7AF)
    • High Private Use Surrogates (U+DB80 ... U+DBFF)
    • High Surrogates (U+D800 ... U+DB7F)
    • Hiragana (U+3040 ... U+309F)
    • Ideographische Beschreibungszeichen (U+2FF0 ... U+2FFF)
    • Kanbun (U+3190 ... U+319F)
    • Kangxi-Radikale (U+2F00 ... U+2FDF)
    • Katakana (U+30A0 ... U+30FF)
    • Low Surrogates (U+DC00 ... U+DFFF)
    • Private Use Area (U+E000 ... U+F8FF)
    • Yi-Radikale (U+A490 ... U+A4CF)
    • Yi-Silbenzeichen (U+A000 ... U+A48F)

    siehe Wikipedia unter Liste der Unicodeblöcke für weitergehende Informationen zu diesen Abschnitten

    Zusätzlich werden die Zeichencodes U+005C und U+20AC für zwei-Byte Zeichen verwendet, wenn die Systemsprache auf Japanisch gestellt ist.

    Wie im ODF 1.2 beschrieben, sind Byte-Positionen implementationsabhängig und daher reduziert diese Abhängigkeit die Kompatibilität.

    Beispiele:

    Die folgenden Beispiele sind ähnlich zu denen für die Funktion TEIL und zeigen das konsistente Verhalten der zwei Funktionen für ein-Byte Zeichenketten.

    Formel Beschreibung Ergebnis
    =TEILB("Eingabetext"; 2; 3) Hier gibt die Funktion drei Bytes aus dem Eingabetext zurück, beginnend mit dem zweiten Byte. "ing"
    =TEILB(12.345,6789; 5; 4) Hier gibt die Funktion vier Bytesw aus dem Eingabetext zurück, beginnend mit dem fünften Byte. Das Ergebnis wird als Text formatiert. "5,67"
    =TEILB(D1; D2; D3), wobei die Zelle D1 den Text "Eingabetext" enthält, die Zelle D2 die Zahl 2 enthält und Zelle D3 die Zahl 3. Hier gibt die Funktion drei Bytes aus dem Eingabetext zurück, beginnend mit dem zweiten Byte. "ing"
    =TEILB("Eingabetext"; 6; 0) Hier gibt die Funktion einen leeren Text zurück. ""

    Die verbleibenden Beispiele zeigen das Verhalten von TEILB für Texte, die zwei-Byte Zeichen beinhalten. Diese Beispiele verwenden die zwei-Byte Zeichen "中" (Unicode Vereinheitlichte CJK-Ideogramme - 4E2D) und "国" (Vereinheitlichte CJK-Ideogramme - 56FD).

    Formel Beschreibung Ergebnis
    =TEILB("中国"; 1; 0) Hier gibt die Funktion einen leeren Text zurück, weil die Anzahl Bytes auf 0 steht. ""
    =TEILB("中国"; 1; 1) Hier gibt die Funktion ein Leerzeichen zurück, weil ein Byte nur die Hälfte eines DBCS-Zeichens ist. " "
    =TEILB("中国"; 1; 2) Hier gibt die Funktion "中" zurück, weil zwei Bytes ein vollständiges DBCS-Zeichen bilden. "中"
    =TEILB("中国"; 1; 3) Hier gibt die Funktion "中 " zurück, weil drei Bytes ein und ein halbes DBCS-Zeichen bilden; das letzte Byte wird als Leerzeichen zurückgegeben. "中 "
    =TEILB("中国"; 1; 4) Hier gibt die Funktion "中国" zurück, weil vier Byte zwei vollständige DBCS-Zeichen bilden. "中国"
    =TEILB("中国"; 2; 1) Hier gibt die Funktion ein Leerzeichen zurück, weil Position 2 nicht der Beginn eines Zeichens in diesem DBCS-Text ist. " "
    =TEILB("中国"; 2; 2) Hier gibt die Funktion zwei Leerzechen zurück, weil die zwei angeforderten Bytes die letzte Hälfte des ersten Zeichens und die erste Hälfte des zweiten Zeichens im DBCS-Text ist. " "
    =TEILB("中国"; 2; 3) Hier gibt die Funktion " 国" zurück, weil Byte-Position 2 nicht de Beginn eines Zeichens im DBCS-Text ist un daher ein Leerzeichen für Byte-Position 2 zurückgegeben wird. " 国"
    =TEILB("中国"; 3; 1) Hier gibt die Funktion ein Leerzeichen zurück, weil Byte-Position am Beginn eines Zeichens im DBCS-Text ist, aber ein Byte nur die Hälfte eines DBCS-Zeichens ist. " "
    =TEILB("中国"; 3; 2) Hier gibt die Funktion "国" zurück, weil Byte-Position 3 am Beginn eines Zeichens im DBCS-Text steht und zwei Byte ein DBCS-Zeichen bilden. "国"

    Ähnliche LibreOffice Funktionen:

    FINDENB

    LINKSB

    LÄNGEB

    TEIL

    ERSETZENB

    RECHTSB

    SUCHENB

    ODF Standard:

    Kapitel 6.7.5, Teil 2

    Betroffene (oder ähnliche) EXCEL-Funktionen:

    MIDB