Jump to content

Documentation/Calc Functions/NORMDIST

From The Document Foundation Wiki

Function name:

NORMDIST

Category:

Statistical Analysis

Summary:

Calculates normal distribution values from either the probability density function or the cumulative distribution function.

The normal distribution is also known as the Gaussian distribution. It is a family of continuous probability distributions used in many fields to represent independent, randomly generated variables. Each normal distribution has a curve with the same general bell shape that is symmetric about the mean (often denoted by the lowercase Greek letter mu (μ)), with a spread defined by the standard deviation (often denoted by the lowercase Greek letter sigma (σ)).

Syntax:

NORMDIST(Number; Mean; STDEV[; C])

Returns:

Returns a non-negative real number, which is the normal distribution value for the given arguments. For the probability density function, the value returned lies in the range [0, +∞). For the cumulative distribution function, the value returned lies in the range [0, 1].

Arguments:

Number is a real number, or a reference to a cell containing that number, which is the value at which the normal distribution is to be evaluated.

Mean is a real number, or a reference to a cell containing that number, which is the mean of the normal distribution.

STDEV is a positive real number, or a reference to a cell containing that number, which is the standard deviation of the normal distribution.

C is a logical value, or a reference to a cell containing that value, that determines whether the required probability is taken from the probability density function or the cumulative distribution function. If C is set to 0 or FALSE, a value from the probability density function is calculated. For any other values of C, or if it is omitted, a value from the cumulative distribution function is calculated.

  • If any of Number, Mean, or STDEV is non-numeric, then NORMDIST reports a #VALUE! error.
  • If STDEV is less than or equal to 0.0, then NORMDIST reports an invalid argument error (Err:502).

Additional details:

  • Calc's NORMDIST and NORM.DIST functions perform similar calculations. However, there are minor differences between the two functions with respect to their arguments – for NORMDIST the C argument may be omitted. The requirements for NORMDIST are specified in ODF 1.2; NORM.DIST is provided for interoperability with Microsoft Excel.
  • The normal distribution with a mean of 0 and standard deviation of 1 is known as the standard normal distribution. This gives rise to the following relationship between relevant Calc functions:
[math]\displaystyle{ \text{NORMDIST}(x;\:0;\:1;\:1)\:=\:\text{NORMSDIST}(x) }[/math]
  • The formula for the probability density function of the normal distribution is:
[math]\displaystyle{ PDF_{normal}(x; \mu; \sigma)~=~\frac{1}{\sigma\sqrt{2\pi}}~\text{EXP} \left(-\frac{1}{2}\left( \frac{x-\mu}{\sigma} \right)^2 \right) }[/math]
  • The formula for the cumulative distribution function of the normal distribution is:
[math]\displaystyle{ CDF_{normal}(x; \mu; \sigma)~=~\int_{-\infty }^{x}\frac{1}{\sigma\sqrt{2\pi}}~\text{EXP} \left(-\frac{1}{2}\left( \frac{t-\mu}{\sigma} \right)^2 \right) \:dt }[/math]
  • The following figure shows probability density function plots for five sample normal distributions.
  • The following figure shows cumulative distribution function plots for five sample normal distributions.

Examples:

Formula Description Returns
=NORMDIST(A1; A2; A3; A4) where cells A1:A4 contain the numbers 7.14, 1.5, 3.2, and 1 respectively. Here the function calculates a value from the cumulative distribution function of the normal distribution for the given argument values. Note that the formula =NORMDIST(A1; A2; A3) returns the same value, with the omitted C argument assuming its default value of TRUE (1). 0.961007571808867
=NORMDIST(7.14; 1.5; 3.2; FALSE()) Here the function calculates a value from the probability density function of the normal distribution for the given argument values. 0.026376219058927
=NORMDIST(2; 0; 0.5; 0) Here the function calculates a value from the probability density function of the normal distribution for the given argument values. Note that the normal distribution is symmetric and so the formula =NORMDIST(-2; 0; 0.5; 0) returns the same value. 0.000267660451529771
=NORMDIST(1; 0; 1.2; 1) Here the function calculates a value from the cumulative distribution function of the normal distribution for the given argument values. Note that the normal distribution is symmetric and so the formula =1-NORMDIST(-1; 0; 1.2; 1) returns the same value. 0.797671619036357
=NORMDIST(0.5; 0; 1; 1) Here the function calculates a value from the cumulative distribution function of the standard normal distribution. Note that the formula =NORMSDIST(0.5) returns the same value. 0.691462461274013

Related LibreOffice functions:

NORM.DIST

NORM.INV

NORM.S.DIST

NORM.S.INV

NORMINV

NORMSDIST

NORMSINV

PHI

ODF standard:

Section 6.18.52, part 2

Related (or similar) Excel functions:

NORMDIST