Documentation/Calc-functies/GETALWAARDE

From The Document Foundation Wiki
Jump to navigation Jump to search
This page is a translated version of the page Documentation/Calc Functions/NUMBERVALUE and the translation is 100% complete.
Other languages:
English • ‎Nederlands



Functienaam:

GETALWAARDE

Categorie:

Tekst

Samenvatting:

Converteert de tekenreeksweergave van een getal naar een locale-onafhankelijke getalopmaak. De invoer kan een landinstelling of een ander op maat gemaakte opmaak hebben. De uitvoer is standaard opgemaakt als een geldig IEEE (Institute of Electrical and Electronics Engineers) drijvende-kommatype, dat het volledige stopteken (Unicode U+002E) gebruikt als hetdecimaalteken en bevat geen groepsscheidingstekens.

Syntaxis:

GETALWAARDE(Tekst[; Decimaal scheidingsteken[; Groepsscheidingsteken]])

Retourneert:

Retourneert een reëel getal dat overeenkomt met het getal dat als tekenreeks is opgegeven. De standaardwaarde is dat het geretourneerde getal wordt opgemaakt als een geldig IEEE-drijvend-kommatype, maar dit kan worden overschreven door de opmaak die op de formulecel is toegepast te wijzigen.

Argumenten:

Tekst is een tekenreeks (tussen aanhalingstekens) of een verwijzing naar een cel die een tekenreeks bevat, die het te converteren getal bevat.

Decimaal scheidingsteken is een enkel teken, of een verwijzing naar een cel met een enkel teken, dat het teken specificeert dat wordt gebruikt als decimaal scheidingsteken in Tekst. Dit argument kan worden weggelaten als Tekst geen scheidingstekens voor decimalen of groepen bevat.

Groepsscheidingsteken is een tekenreeks of een verwijzing naar een cel die een tekenreeks bevat, die het teken of de tekens specificeert die worden gebruikt als het groepsscheidingsteken in Tekst. Dit argument kan worden weggelaten als Tekst geen groepsscheidingstekens bevat.

  • Als Tekst geen geldig getalbevat, retourneert GETALWAARDE als fout #WAARDE!.
  • Als Decimaal scheidingsteken geen enkel teken specificeert, dan retourneert GETALWAARDE als fout Ongeldig argument (Fout:502).
  • Als het teken gespecificeerd door Decimaal scheidingsteken is opgenomen in Groepsscheidingsteken, dan retourneert GETALWAARDE als fout Ongeldig argument(Fout:502).

Aanvullende details:

ODF 1.2 stelt dat de aangeleverde string getransformeerd moet worden volgens vijf regels:

  1. Verwijder eerst alle exemplaren van het groepsscheidingsteken vóór een decimaalteken. De formule =GETALWAARDE("1.234.567,89"; ","; ".") geeft bijvoorbeeld 1234567,89 als resultaat. De formule =GETALWAARDE("1,234.567,89"; "."; ",") rapporteert echter een fout #WAARDE! omdat het een groepsscheidingsteken bevat na het decimaalteken.
  2. Vervang eerst in de tekst het decimale scheidingsteken door het PUNT-teken (U+002E). De formule =GETALWAARDE("1#234"; "#") geeft bijvoorbeeld 1,234 terug. De formule =GETALWAARDE("1#23#4"; "#") retourneert echter een fout #WAARDE! omdat het een tweede decimaalteken bevat.
  3. Verwijder alle witruimtetekens. Voeg bijvoorbeeld de formule ="1" & UNITEKEN(32) & "2" & UNITEKEN (9) & "3" & UNITEKEN (10) & "4" & UNITEKEN(13) in cel A1. Deze tekenreeks bevat de cijfers 1, 2, 3 en 4 afgewisseld met verschillende Unicode-tekens voor witruimten (dat wil zeggen, spatie (U+0020), tab (U+0009), regelinvoer (U+000A) en regelterugloop (U +000D)). Dan retourneert de formule =GETALWAARDE($A$1) 1234, waarbij de tekens voor de witruimte zijn verwijderd.
  4. Als het eerste teken van de resulterende string een PUNT-teken (U+002E) is, voeg dan een nul toe. De formule =GETALWAARDE(".6", ".") retourneert bijvoorbeeld 0,6.
  5. Als de string eindigt op één of meer exemplaren van PROCENTTEKEN (U+0025), verwijder dan het (de) procentteken(s). Als procenttekens op deze manier worden verwijderd, wordt de waarde van het geretourneerde getal gedeeld door 100 voor elk verwijderd procentteken. De formule =GETALWAARDE("34%") geeft bijvoorbeeld 0,34 terug en de formule =GETALWAARDE("34%%") geeft 0,0034 terug.

Voorbeelden:

Formule Beschrijving Retourneert
=GETALWAARDE("1.234.567,89"; ","; ".") Hier verwijdert de functie de twee groepsscheidingstekens. 1234567.89
=GETALWAARDE(D1; D2; D3) waarbij de cellen D1, D2 en D3 respectievelijk de tekenreeksen "1.234.567,89", "," en ".". Hier verwijdert de functie opnieuw de twee groepsscheidingstekens. 1234567.89
=GETALWAARDE("123·4"; "·") Hier verandert de functie het decimaalteken van een "·" in een komma. Er wordt geen groepsscheidingsteken gebruikt in het opgegeven nummer en dus wordt het Groepsscheidingsteken argument weggelaten. 123.4
=GETALWAARDE("123e12") Hier retourneert de functie 1.23E+14. Er worden geen decimale of groepsscheidingstekens gebruikt in het opgegeven getal en dus worden de argumenten Decimaal scheidingsteken en Groepsscheidingsteken weggelaten. 1.23E+14
=GETALWAARDE("1#!234#!567"; "."; "#!") Hier retourneert de functie 1234567. Merk op dat in dit geval het groepsscheidingsteken wordt gespecificeerd als een tekenreeks van twee tekens. 1234567

Gerelateerde LibreOffice-functies:

WAARDE

ODF standaard:

Section 6.13.28, part 2

Gelijkwaardige Excel-functies:

NUMERIEKE.WAARDE