Documentation/Calc 関数/OFFSET

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/OFFSET and the translation is 100% complete.
    Other languages:


    Function name:

    OFFSET

    Category:

    Spreadsheet

    Summary:

    基準位置から 指定の 行数 と 列数 を移動した位置、および 高さ と 幅 で大きさを指定して、修正された参照を決定します。

    Syntax:

    OFFSET(参照; 行数; 列数[; 高さ[; ]])

    Returns:

    指定された引数で構成される、セルまたはセル範囲への変更された参照を返します。

    Arguments:

    参照 は、セル参照、セル範囲への参照、または名前付き範囲またはデータベース範囲の名前です。 これにより、 OFFSET の開始点が提供され、他の引数の値に基づいて変更された参照が構築されます。

    行数 は、開始する参照からオフセットされる行数を指定する整数値、または整数値を含むセルへの参照です。 負の値を指定すると上にオフセットし、正の値は下にオフセットし、0 を指定すると同じ列が使用されます。

    列数 は、開始する参照からオフセットされる列数を指定する整数値、または整数値を含むセルへの参照です。 負の値を指定すると左にオフセットし、正の値を指定すると右にオフセットされます。0 を指定すると同じ列が使用されます。

    高さ は、変更された参照で必要な行の総数を指定する正の整数値、またはそのような値を含むセルへの参照です。 省略すると、既定値の 1 が適用されます。

    は、変更された参照で必要な列の総数を指定する正の整数値、またはそのような値を含むセルへの参照です。 省略すると、既定値の 1 が適用されます。

    • 参照 が複数のセル範囲 (領域) で構成されている場合、 OFFSET パラメータ・リスト・エラー (エラー:504) を返します。
    • 行数列数高さ のいずれかが数値でない場合、OFFSET は #VALUE! エラーを返します。
    • 行数列数高さ の整数以外の値は、整数に切り捨てられます。
    • 切り捨て後、高さ または のいずれかが 1 未満の場合、OFFSET は無効な引数エラー (エラー:502) を返します。
    • 変更された参照にシートの最大寸法の範囲外にある 1 つまたは複数のセルが含まれている場合、 OFFSET は 無効な引数 エラー(エラー:502) を返します。
    • の参照 が単一のセルへの参照で、高さの幅 の両方が省略されているか 1 に設定されている場合、 OFFSET は単一のセル参照を返します。それ以外の場合、OFFSET はセル範囲への参照を返します。

    Additional details:

    • OFFSET は 揮発性関数 です。これは、データ ▸ 計算 ▸ 再計算 を選択するか F9 を押すか、または任意の入力イベントでセルが更新されると、 OFFSET によって返された参照が更新されることを意味します。
    • Calc とは異なり、Microsoft Excel では、their documentation および OOXML specification (ECMA-376-1:2016 section 18.17.7.245 を参照) に反している場合でも、高さ および の引数に負の値を使用できます。これは、両方のアプリケーションで同じファイルを開いた場合に、異なる結果が得られる可能性があることを意味します。tdf#157948 を参照してください。

    Examples:

    例題用のデータ
    A B C D E F G H
    1
    2 123.4 2.7 3.6 4.8 2.9
    3 1 3 LibreOffice 1 1 1 1 1
    4 2 4 1 1 1 1 1
    5 1 1 1 1 1
    6 1 1 1 1 1
    Formula Description Returns
    =OFFSET(A1; 2; 2)

    セル A1 の 2 行下、2 列右にあるセルを特定します。 高さ の引数は省略されるため、どちらも既定値の 1 を使用します。 したがって、 OFFSET 関数はセル C3 への参照を返し、数式はそのセルの内容を返します。

    LibreOffice
    =OFFSET(B1; D2; E2; F2; G2)

    OFFSET は、引数として入力された小数値を整数値 (B1; 2; 3; 4; 2) に切り捨てます。 この関数は、セル B1 の 2 行下で 3 列右にあるセル (セル E3) を特定します。 さらに、これが高さ 4 行、幅 2 列の領域の左上のセルであることを判断します。 したがって、OFFSET 関数は、セル range E3:F6 への参照を返します。 (↵ Enterキーを使用して作成されるような) 配列以外の数式を使用すると、#VALUE! エラーが発生します。

    #VALUE!
    =SUM(OFFSET(B1; D2; E2; F2; G2))

    前の例題と同様です。 SUM 関数は、OFFSET 関数の結果のセル範囲 (E3:F6) を引数として受け取り、その数値に対して合計を実行します。

    8
    =OFFSET(B1; 2; 3; 4; 2) }

    Control + ⇧ Shift + ↵ Enter キーの組み合わせを使って結果を得られます。

    配列数式として、結果のセル range (E3:F6) は、配列 (4 行×2 列) を占めるセルの領域を決定します。 結果の配列の各セルには、OFFSET 関数によって返されるセル範囲の対応する値が表示されます。 配列数式を含む "ホーム" セルにはセル E3 の値が表示され、(配列内で)右側に隣接するセルにはセル F3 の値が表示され、数式セルの下に隣接するセル (配列内で 1 行下) にはセル E4 の値が表示されます。

    1 1
    1 1
    1 1
    1 1
    =SUM(OFFSET(B2:C3; 1; -1))

    OFFSET 関数はセル範囲 A3:B4 への参照を返し、数式はその範囲のセルの値の合計を返します。

    10
    =OFFSET(D4; -2; -3)

    セル D4 から開始して、上に 2 行、左に 3 列移動し(セル A2 を参照)、その値を入力します。

    123.4
    =OFFSET(B2:C3; 0; 0; 3; 4) }

    配列数式とします。

    行数列数 の引数は両方とも 0 に設定されているため、 OFFSET 関数は範囲の左上のセルを変更しません。 ただし、元の範囲は高さ 2 行、幅 2 列であったのに対し、更新された範囲は高さ 3 行、幅 4 列です。 セル B2 の内容は数式セルに表示され、セル B3 の内容は数式セルの下のセルに表示され、セル B4 の内容はその下の次のセルに表示されます。

    2.7 3.6
    3 LibreOffice 1 1
    4 1 1
    =SUM(OFFSET(B1; 2; 2; 4; 5))

    OFFSET 関数は、セル範囲 D3:H6 への参照を返します。 この数式は、その範囲内のセルの値の合計を返します。

    20
    =OFFSET(A1; 0; 0; ; 6) }

    配列数式とします。

    高さ 引数は省略できますが (既定値は 1 )、 引数には値が指定されます。 セル範囲 A1:F1 への参照を返します。 数式の結果として、セル A1 の内容が数式セルに表示され、セル B1 の内容が数式セルの右側のセルに表示され、セル C1 の内容がその次の右側のセルに表示されます。

    Description 列をご覧ください。

    Related LibreOffice functions:

    COLUMN

    COLUMNS

    INDEX

    MATCH

    ROW

    ROWS

    ODF standard:

    Section 6.14.11, part 2

    Related (or similar) Excel functions:

    OFFSET