Documentatie/Calc-functies/VERSCHUIVING
TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren
Functienaam:
VERSCHUIVING
Categorie:
Werkblad
Samenvatting:
Bepaalt een gewijzigde verwijzingen, gegeven een initieel startpunt, gespecificeerde rij-/kolomverschuivingen en gespecificeerde hoogte-/breedte-afmetingen.
Syntaxis:
VERSCHUIVING(Verwijzing; Rijen; Kolommen[; Hoogte[; Breedte]])
Retourneert:
Retourneert een gewijzigde verwijzing naar een cel of celbereik, opgebouwd uit de opgegeven argumenten.
Argumenten:
Verwijzing is een celverwijzing, een verwijzing naar een celbereik of de naam van een benoemd bereik of databasebereik. Het biedt het startpunt voor VERSCHUIVING om een gewijzigde verwijzing te construeren op basis van de waarden van andere argumenten.
Rijen is een geheel getal of een verwijzing naar een cel die een geheel getal bevat, dat het aantal rijen aangeeft dat moet worden verschoven ten opzichte van de beginverwijzing. Een negatieve waarde verschuift naar boven, een positieve waarde verschuift naar beneden en 0 gebruikt dezelfde rij.
Kolommen is een geheel getal of een verwijzing naar een cel die een geheel getal bevat, waarmee het aantal kolommen wordt gespecificeerd dat moet worden verschoven ten opzichte van de beginverwijzing. Een negatieve waarde verschuift naar links, een positieve waarde verschuift naar rechts en 0 gebruikt dezelfde kolom.
Hoogte is een positief geheel getal of een verwijzing naar een cel die een dergelijke waarde bevat, die het totale aantal vereiste rijen in de gewijzigde verwijzing aangeeft. Indien weggelaten, wordt een standaardwaarde van 1 toegepast.
Breedte is een positief geheel getal of een verwijzing naar een cel die een dergelijke waarde bevat, die het totale aantal kolommen specificeert dat vereist is in de gewijzigde verwijzing. Indien weggelaten, wordt een standaardwaarde van 1 toegepast.
- Als Verwijzing meerdere celbereiken (gebieden) omvat, dan retourneert VERSCHUIVING fout in de lijst met parameters (Fout:504).
- Als één van de Rijen, Kolommen, Hoogte of Breedte niet-numeriek is, retourneert VERSCHUIVING als fout #WAARDE!.
- Niet-gehele waarden van Rijen, Kolommen, Hoogte of Breedte worden afgekapt tot gehele getallen.
- Als, na afkapping ofwel Hoogte of Breedte kleiner is dan 1, dan retourneert VERSCHUIVING als fout Ongeldig argument (Fout:502).
- Als de gewijzigde verwijzing één of meer cellen zou bevatten die buiten de maximale bladafmetingen liggen, dan retourneert VERSCHUIVING Ongeldig argument (Fout:502).
- Als Referentie een verwijzing is naar een enkele cel met zowel Hoogte als Breedte weggelaten of ingesteld op 1, dan retourneert VERSCHUIVING een enkele celverwijzing. Anders retourneert VERSCHUIVING een verwijzing naar een celbereik.
Aanvullende details:
- VERSCHUIVING is een vluchtige functie. Dit betekent dat Calc de verwijzing die wordt geretourneerd door VERSCHUIVING zal bijwerken wanneer een cel wordt bijgewerkt door ▸ ▸ te selecteren of op F9 te drukken of op een invoergebeurtenis.
- In tegenstelling tot Calc accepteert Microsoft Excel negatieve waarden voor de argumenten Hoogte en Breedte, ook al is dit in strijd met hun documentatie en de OOXML-specificatie (zie ECMA-376-1:2016 sectie 18.17.7.245). Dit betekent mogelijk verschillende resultaten wanneer hetzelfde bestand in beide toepassingen wordt geopend. Zie tdf#157948.
Voorbeelden:
| A | B | C | D | E | F | G | H | |
|---|---|---|---|---|---|---|---|---|
| 1 | ||||||||
| 2 | 123,4 | 2,7 | 3,6 | 4,8 | 2,9 | |||
| 3 | 1 | 3 | LibreOffice | 1 | 1 | 1 | 1 | 1 |
| 4 | 2 | 4 | 1 | 1 | 1 | 1 | 1 | |
| 5 | 1 | 1 | 1 | 1 | 1 | |||
| 6 | 1 | 1 | 1 | 1 | 1 |
| Formule | Beschrijving | Retourneert | ||||||||||||
|---|---|---|---|---|---|---|---|---|---|---|---|---|---|---|
| =VERSCHUIVING(A1; 2; 2) |
Bepaalt de cel die zich 2 rijen onder en 2 kolommen rechts van cel A1 bevindt. De argumenten Hoogte en Breedte worden weggelaten en nemen beide de standaardwaarde 1 aan. De functie VERSCHUIVING retourneert daarom een verwijzing naar cel C3 en de formule retourneert de inhoud van die cel. |
LibreOffice | ||||||||||||
| =VERSCHUIVING(B1; D2; E2; F2; G2) |
VERSCHUIVING kapt de decimale getallen af die als argumenten voor gehele waarden zijn opgegeven (B1; 2; 3; 4; 2). De functie bepaalt de cel die 2 rijen lager is en 3 kolommen rechts van cel B1 (dat wil zeggen cel, E3). Het bepaalt verder dat dit de cel linksboven is van een gebied van 4 rijen hoog en 2 kolommen breed. De functie VERSCHUIVING retourneert daarom een verwijzing naar het celbereik E3:F6. Uitgaande van een niet-matrixformule (gemaakt met de ↵ Enter-toets), dan resulteert dit in een #WAARDE! fout. |
#WAARDE! | ||||||||||||
| =SOM(VERSCHUIVING(B1; D2; E2; F2; G2)) |
Vergelijkbaar met het vorige voorbeeld. De functie SOM neemt het resulterende celbereik van de VERSCHUIVING functie (E3:F6) als argument, waarbij een som wordt uitgevoerd op basis van de numerieke waarden. |
8 | ||||||||||||
{ =VERSCHUIVING(B1; 2; 3; 4; 2) }
Introductie met de combinatie van Control + ⇧ Shift + ↵ Enter. |
Als matrixformule bepaalt het resulterende celbereik (E3:F6) het gebied van cellen dat de matrix zal beslaan (4 rijen bij 2 kolommen). Elke cel van de resulterende matrix geeft de corresponderende waarde weer van het celbereik dat wordt geleverd door de VERSCHUIVING functie. De "home"-cel die de matrixformule bevat, geeft de waarde van cel E3 weer; de aangrenzende cel aan de rechterkant (binnen de array) geeft de waarde van cel F3 weer; de aangrenzende cel onder de formulecel (één rij lager, binnen de matrix) geeft de waarde van cel E4 weer. en ga zo maar door. |
| ||||||||||||
| =SOM(VERSCHUIVING(B2:C3; 1; -1)) |
de functie VERSCHUIVING retourneert een verwijzing naar het celbereik A3:B4 en de formule retourneert de som van de waarden in de cellen van dat bereik. |
10 | ||||||||||||
| =VERSCHUIVING(D4; -2; -3) |
Vanaf cel D4, 2 rijen omhoog en 3 kolommen naar links (om naar cel A2 te verwijzen); Geef dan de waarde ervan. |
123,4 | ||||||||||||
{ =VERSCHUIVING(B2:C3; 0; 0; 3; 4) }
als matrixformule. |
Aangezien de argumenten Rijen en Kolommen beide zijn ingesteld op nul, brengt de functie VERSCHUIVING geen wijzigingen aan in de cel linksboven in het bereik. Het oorspronkelijke bereik was echter twee rijen diep en twee kolommen breed, terwijl het bijgewerkte bereik drie rijen diep en vier kolommen breed is. De inhoud van cel B2 komt in de formulecel. De inhoud van cel B3 verschijnt in de cel onder de formulecel, de inhoud van cel B4 in de volgende cel eronder, enzovoort. |
| ||||||||||||
| =SOM(VERSCHUIVING(B1; 2; 2; 4; 5)) |
De functie VERSCHUIVING retourneert een verwijzing naar het celbereik D3:H6. De formule retourneert de som van de waarden in de cellen binnen dat bereik. |
20 | ||||||||||||
{ =VERSCHUIVING(A1; 0; 0; ; 6) }
als matrixformule. |
Het argument Hoogte mag worden weggelaten (standaard 1) terwijl het argument Breedte een waarde krijgt. Retourneert een verwijzing naar het celbereik A1:F1. De formule resulteert erin dat de inhoud van cel A1 in de formulecel verschijnt, de inhoud van cel B1 in de cel rechts van de formulecel, de inhoud van cel C1 in de volgende cel rechts, enzovoort. |
Zie kolom Beschrijving |
Gerelateerde LibreOffice-functies:
ODF standaard:
Gerelateerde (of gelijkwaardige) Excel-functies:
OFFSET