Documentation/Calc Functions/OR/cs
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Donate
Název funkce:
OR
Kategorie:
Logické
Shrnutí:
Tests multiple conditions to determine whether at least one is met. Returns TRUE if at least one condition is met. Returns FALSE if no condition is met.
Syntaxe:
OR(Logical Value 1[; Logical Value 2[; … [; Logical Value 255]]])
Vrátí:
Returns the logical value TRUE if at least one of the supplied conditions is met. Returns the logical value FALSE when none of the supplied conditions are met.
Argumenty:
Logical Value 1, Logical Value 2, … , Logical Value 255 give the set of conditions to be checked. Each condition should comprise an expression that evaluates to give a logical value that is either TRUE or FALSE. If an expression evaluates to a number instead of a logical value, then the value 0 (zero) is treated as FALSE and all non-zero numeric values are treated as TRUE. Each argument may take one of the following forms:
- A logical value, or an expression that can be evaluated to a logical value. Examples include TRUE, 3, 1<5, 2+3=7, A2*A3, and B8<10.
- A reference to a single cell containing a logical value or expression.
- A reference to a cell range containing logical values or expressions (for example, D6:E12 or A1:B9~E12:E14).
- The name of a named range, comprising cells containing logical values or expressions.
- The name of a database range, comprising cells containing logical values or expressions.
- An inline array of logical values or numbers (for example {TRUE, FALSE, 0, 123,456}).
Note that although OR can accept up to 255 arguments, each argument could specify a range of cells. This means that the number of conditions processed could be many more than 255.
- If the arguments do not give at least one logical value, then OR reports a #VALUE! error.
- If the arguments give exactly one value, then OR returns that logical value.
- If any argument is a string in quotation marks, then OR reports a #VALUE! error. This does not apply to references to cells containing strings.
- Empty cells and cells that contain text are ignored by OR.
- If a cell contains an error value, then OR propagates that error irrespective of the content of other cells.
Další detaily:
Details specific to OR function
- In its simplest form, the logical OR (sometimes known as logical disjunction) of two logical values is an operation that produces a value of true if either of its operands is/are true; otherwise the result is false. It can be expressed as a truth table as follows:
| Operand 1 | Operand 2 | Operand 1 OR Operand 2 |
|---|---|---|
| true | true | true |
| true | false | true |
| false | true | true |
| false | false | false |
- OR ignores any text in cells or empty cells. If you suspect wrong results, look for text within the supplied data range(s). To highlight text content within a data range, use Calc's ▸ feature.
- Although you can use OR on its own, it is often much more useful when combined with other functions. For example, consider a value in cell A1 that you expect to be positive and a value in cell B1 that you expect to be negative. You might place a formula such as
=IF(OR(A1<=0; B1>=0); "Out of range"; "In range")in some other cell to check whether both values are within their expected ranges.
Obecné informace o logických funkcích v Calcu
 |
Poznámka:
|
Calc používá čísla 0 (FALSE) a 1 (TRUE) pro vyjádření logických hodnot. Například zadejte 1 do buňky, která má výchozí obecný formát čísla. Poté zvolte na panelu nabídek ▸ , čímž zobrazíte dialogové okno Formátovat buňky, v oblasti Kategorie na kartě Čísla vyberte možnost Booleovská hodnota a klepněte na tlačítko . Všimněte si, že číslo 1 je nyní zobrazeno jako TRUE. Chcete-li se vrátit k zobrazení čísla 1, zopakujte postup, ale místo možnosti Booleovská hodnota vyberte možnost Číslo'.
Chcete-li do buňky zadat logickou hodnotu, jednoduše do ní napište buď TRUE, nebo FALSE (bez ohledu na velikost písmen). Calc logickou hodnotu rozpozná, zobrazí ji velkými písmeny a změní formát buňky na formát vhodný pro logické hodnoty.
Funkce Calc, které vytvářejí logický výsledek, vracejí číslo, buď 0 nebo 1. V případě vzorce, který jednoduše volá takovou logickou funkci a je v buňce, která má výchozí obecný formát čísla, se buňka přepne na formát booleovské hodnoty a vrácená hodnota se zobrazí jako FALSE nebo TRUE. Například =TRUE() vrátí hodnotu 1, která se zobrazí jako TRUE; pokud potom změníte formát na číselný formát, zobrazí se jako číslo 1.
Funkce Calcu, které testují logický výsledek, vždy vyhodnotí testovaný výraz a zkontrolují, zda se rovná 0. Hodnota 0 je brána jako FALSE a jakákoli jiná hodnota je brána jako TRUE. Například =NOT(0) vrátí hodnotu TRUE a =NOT(57,89) vrátí hodnotu FALSE.
Na rozdíl od Calcu má Microsoft Excel samostatný typ pro logické hodnoty - nejsou to čísla, ale někdy se na čísla převádějí. Dejte si proto pozor, pokud potřebujete kompatibilitu.
Příklady:
| A | B | C | D | |
|---|---|---|---|---|
| 1 | =FALSE() | 45 | 2,2 | |
| 2 | =NOT(TRUE()) | 3 | ||
| 3 | 1 | -5,4 | ||
| 4 | 2 | |||
| 5 | 3 | "Conditions": A1:A5
|
⇐ named range
|
| Vzorec | Popis | Vrátí |
|---|---|---|
| =OR(FALSE(); TRUE()) | One of the arguments is true. | TRUE |
| =OR(FALSE(); 3>5) | Neither of the arguments is true. | FALSE |
| =OR(TRUE(); C1>10; FALSE()) | Two of the arguments are true. | TRUE |
| =OR(D1:D3) | All three supplied numeric values are not equal to 0. | TRUE |
| =OR({2; 4; 6; 8}) | All four supplied numeric values are not equal to 0. | TRUE |
| =OR(12<13; 14>12; 7<6) | The condition given in the third argument is false while the first two are true. | TRUE |
| =OR(Conditions) | Three cells are true. | TRUE |
Související funkce LibreOffice:
ODF standard:
Související (nebo podobné) funkce Excelu:
OR