Documentatie/Calc-functies/OF

This page is a translated version of the page Documentation/Calc Functions/OR and the translation is 100% complete.

TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren

Other languages:

Deutsch
English
Nederlands
čeština

Startpagina Calc-functies | Lijst met functies | Afkortingen

Functienaam:

OF

Categorie:

Logisch

Samenvatting:

Test meerdere voorwaarden om te bepalen of aan ten minste één is voldaan. WAAR wordt geretourneerd als aan ten minste één voorwaarde is voldaan en anders ONWAAR.

Syntaxis:

OF(Logische waarde 1 [; Logische waarde 2 [; … [; Logische waarde 255]]])

Retourneert:

Retourneert de logische waarde WAAR als aan ten minste één van de opgegeven voorwaarden wordt voldaan. Retourneert de logische waarde ONWAAR als aan geen van de opgegeven voorwaarden wordt voldaan.

Argumenten:

Logische Waarde 1, Logische Waarde 2, … , Logische Waarde 255 geven de reeks voorwaarden die gecontroleerd moeten worden. Elke voorwaarde moet een uitdrukking bevatten die een logische waarde oplevert die WAAR of ONWAAR is. Als een uitdrukking resulteert in een getal in plaats van een logische waarde, wordt de waarde 0 (nul) behandeld als ONWAAR en worden alle niet-nulwaarden behandeld als WAAR. Elk argument kan één van de volgende vormen aannemen:

Een logische waarde of een uitdrukking die kan worden geëvalueerd tot een logische waarde. Voorbeelden zijn WAAR, 3, 1<5, 2+3=7, A2*A3 en B8<10.
Een verwijzing naar een enkele cel die een logische waarde of uitdrukking bevat.
Een verwijzing naar een celbereik dat logische waarden of uitdrukkingen bevat (bijvoorbeeld D6:E12 of A1:B9~E12:E14).
De naam van een benoemd bereik, bestaande uit cellen die logische waarden of uitdrukkingen bevatten.
De naam van een databasebereik, bestaande uit cellen die logische waarden of uitdrukkingen bevatten.
Een matrix van logische waarden of getallen (bijvoorbeeld {WAAR; ONWAAR; 0; 123,456}).

Merk op dat hoewel OF tot 255 argumenten kan accepteren, elk argument een celbereik kan specificeren. Dit betekent dat het aantal verwerkte positieve gehele getallen veel meer dan 255 kan zijn.

Als de argumenten niet ten minste één logische waarde geven, rapporteert OF de fout #WAARDE!
Als de argumenten precies één waarde opleveren, geeft OF die logische waarde als resultaat.
Als een argument een string tussen aanhalingstekens is, dan rapporteert OF de fout #WAARDE! Dit geldt niet voor verwijzingen naar cellen die strings bevatten.
Lege cellen en cellen die tekst bevatten, worden genegeerd door OF.
Als een cel een fout bevat, verspreidt OF die fout ongeacht de inhoud van andere cellen.

Aanvullende details:

Details specifiek voor de functie OF

In zijn eenvoudigste vorm is de logische OF (ook wel logische disjunctie genoemd) van twee logische waarden een bewerking die de waarde waar produceert als één van de opdrachtelementen waar is en anders onwaar. Het kan als volgt worden uitgedrukt als een waarheidstabel:

Waarheidstabel voor logische bewerking OF
Opdrachtelement 1	Opdrachtelement 2	Opdrachtelement 1 OF Opdrachtelement 2
waar	waar	waar
waar	onwaar	waar
onwaar	waar	waar
onwaar	onwaar	onwaar

OFnegeert tekst in cellen of lege cellen. Als u verkeerde resultaten vermoedt, zoek dan naar tekst binnen het (de) opgegeven gegevensbereik(en). Om tekstinhoud binnen een gegevensbereik te markeren, gebruikt u de functie Beeld ▸ Waardemarkering van Calc.
Hoewel u OF op zichzelf kunt gebruiken, is het vaak veel handiger in combinatie met andere functies. Denk bijvoorbeeld aan een waarde in cel A1 waarvan u verwacht dat deze positief is en een waarde in cel B1 waarvan u verwacht dat deze negatief is. U kunt een formule zoals =ALS(OF(A1<=0; B1>=0); "Buiten bereik"; "Binnen bereik") in een andere cel plaatsen om te controleren of beide waarden binnen het verwachte bereik liggen.

Algemene informatie over de logische functies van Calc

NB:
Voor het gemak wordt de informatie in deze subsectie herhaald op alle pagina's die de logische functies van Calc beschrijven.

Calc gebruikt de getallen 0 (ONWAAR) en 1 (WAAR) om logische waarden weer te geven. Voer bijvoorbeeld 1 in in een cel met de standaard algemene getalopmaak. Selecteer vervolgens Opmaak ▸ Cellen op de Menubalk om het dialoogvenster Cellen opmaken weer te geven, selecteer de optie Booleaanse waarde in het gedeelteCategorie van het tabblad Getallen en klik op de knop OK. Merk op dat het getal 1 nu wordt weergegeven als WAAR. Om terug te keren naar het weergeven van het getal 1, herhaalt u het proces maar selecteert u Getal in plaats van Booleaanse waarde.

Om een logische waarde in een cel in te voeren, typt u gewoon WAAR of ONWAAR (hoofdletterongevoelig) in de cel. Calc zal de logische waarde herkennen, deze in hoofdletters weergeven en de opmaak van de cel wijzigen in de opmaak die past bij Booleaanse waarden.

Calc-functies die een logisch resultaat produceren, geven een getal terug, of 0 of 1. In het geval van een formule die zo'n logische functie eenvoudig aanroept en zich in een cel bevindt die de standaard algemene getalopmaak heeft, wordt de cel overgeschakeld naar de opmaak van de Booleaanse waarde en de geretourneerde waarde wordt weergegeven als ONWAAR of WAAR. Bijvoorbeeld =WAAR() retourneert de waarde 1, die wordt weergegeven als WAAR; als u de opmaak vervolgens wijzigt in een numerieke opmaak, wordt het weergegeven als het getal 1.

Calc-functies die op een logisch resultaat testen, evalueren altijd de te testen uitdrukking en controleren of deze gelijk is aan 0. De waarde 0 wordt als ONWAAR beschouwd en elke andere waarde wordt als WAAR genomen. Bijvoorbeeld, =NIET(0) geeft WAAR terug en =NIET(57,89) geeft ONWAAR terug.

In tegenstelling tot Calc heeft Microsoft Excel een apart type voor logische waarden - het zijn geen getallen maar worden soms geconverteerd naar getallen. Wees daarom voorzichtig als u compatibiliteit nodig heeft.

Voorbeelden:

Gegevens voor voorbeelden
	A	C	D
1	=ONWAAR()	45	2,2
2	=NIET(WAAR())		3
3	1		-5,4
4	2
5	3	"Voorwaarden": `A1:A5`	⇐ `genoemd bereik`

Formule	Beschrijving	Retourneert
=OF(ONWAAR(); WAAR())	Een van de argumenten id waar.	WAAR
=OF(ONWAAR(); 3>5)	Geen van de argumenten is waar.	ONWAAR
=OF(WAAR(); C1>10; ONWAAR())	Twee van de argumenten zijn waar.	WAAR
=OF(D1:D3)	Alle drie opgegeven numerieke waarden niet gelijk zijn aan 0.	WAAR
=OF({2; 4; 6; 8})	Alle vier opgegeven numerieke waarden niet gelijk zijn aan 0.	WAAR
=OF(12<13; 14>12; 7<6)	De voorwaarde in het derde argument is onwaar, terwijl de eerste twee waar zijn.	WAAR
=OF(Voorwaarden)	Drie cellen zijn waar.	WAAR

Gerelateerde LibreOffice-functies:

ODF standaard:

Section 6.15.8, part 2

Gerelateerde (of gelijkwaardige) Excel-functies:

OR