Documentazione/Funzioni di Calc/ESPR.REG
TDF LibreOffice Document Liberation Project Blog comunitari Weblate Nextcloud Redmine Ask LibreOffice Donazione
Nome funzione:
ESPR.REG
Categoria:
Testo
Riepilogo:
Confronta una stringa di testo con un'espressione regolare ed estrae o sostituisce il testo corrispondente, a seconda delle impostazioni dell'argomento.
Sintassi:
ESPR.REG(Testo; Espressione[; [Sostituzione][; Contrassegno od occorrenza]])
Restituisce:
Restituisce uno dei seguenti a seconda dei valori degli argomenti. Per ulteriori informazioni sulla occorrenza di ciascun tipo restituito (con esempi), vedere la sezione #Additional details: di seguito.
- Una copia di una sottostringa estratta dal testo originale.
- Una copia del testo originale, modificata sostituendo una o più corrispondenze.
- Una copia del testo originale, senza modifiche.
- Errore relativo a un valore non disponibile (#N/D).
Argomenti:
Testo è una stringa di testo (tra virgolette), oppure un riferimento ad una cella contenente una stringa di testo, ovvero il testo originale a cui applicare Espressione.
Espressione è una stringa di testo (tra virgolette), oppure un riferimento ad una cella contenente una stringa di testo, ovvero l'espressione regolare da applicare a Testo.
Sostituzione è una stringa di testo (tra virgolette), oppure un riferimento ad una cella contenente una stringa di testo, ovvero il testo sostitutivo da utilizzare. L'impostazione di Sostituzione su una stringa vuota può essere utilizzata come meccanismo per eliminare i caratteri corrispondenti.
Contrassegno od occorrenza è una delle seguenti opzioni:
- Una stringa comprendente un singolo carattere "g" minuscolo o un riferimento a una cella contenente tale stringa di testo. Il carattere "g" viene utilizzato per selezionare la sostituzione globale, in modo che qualsiasi sostituzione venga applicata a tutte le corrispondenze.
- Un numero intero non negativo o un riferimento a una cella contenente tale numero intero, che indica quale corrispondenza specifica deve essere utilizzata.
- Se Espressione non è un'espressione regolare valida, allora ESPR.REG segnala un errore di argomento non valido (Err:502 ).
- Se Contrassegno od occorrenza è una stringa di testo non numerica che contiene qualsiasi carattere diverso da una singola "g" minuscola, allora ESPR.REG segnala un errore di argomento non valido ( Err:502).
- Se Contrassegno od occorrenza è un valore numerico negativo, allora ESPR.REG segnala un errore di argomento non valido (Err: 502).
- Se Contrassegno od occorrenza è un valore numerico non negativo e non intero, allora ESPR.REG utilizza il suo valore minimo.
- Se Sostituzione' viene omesso e Contrassegno od occorrenza è impostato su "g", allora ESPR.REG si comporta come se entrambi Sostituzione' e Contrassegno od occorrenza sono stati omessi.
Dettagli aggiuntivi:
Dettagli specifici della funzione ESPR.REG
- Il funzionamento della funzione ESPR.REG non dipende dall'opzione attualmente selezionata nell'area Caratteri jolly formule di ▸ ▸ ▸ (o ▸ ▸ ▸ su macOS).
- L'impostazione predefinita iniziale prevede che ESPR.REG utilizzi la corrispondenza con distinzione tra maiuscole e minuscole, ma questo può essere modificato utilizzando i flag all'interno dell'espressione regolare ICU. Ad esempio, includi "(?i)" all'interno dell'espressione regolare per passare a una corrispondenza senza distinzione tra maiuscole e minuscole, come in
=ESPR.REG("test","(? i)"& "TEST")
. - La stringa originale passata nell'argomento Testo non è influenzata da eventuali sostituzioni effettuate da ESPR.REG – le modifiche si riflettono solo nella stringa restituita.
- Potrebbe essere utile considerare ESPR.REG come operante in una delle cinque "modalità" distinte a seconda degli argomenti passati alla funzione. Queste modalità sono le seguenti:
- ESPR.REG(Testo; Espressione) estrae la prima corrispondenza di Espressione in Testo . Questo semplice modulo può essere utile per verificare che una stringa sia conforme ad alcuni modelli predefiniti (come numeri di telefono, indirizzi email, codici postali, ecc.).
- La formula
=ESPR.REG("LibreOffice Calc"; ".c")
estrae la prima occorrenza di una "c" minuscola preceduta da qualsiasi altro carattere e restituisce la stringa "ic". - La formula
=ESPR.REG("LibreOffice Calc"; "Z")
non trova corrispondenza e restituisce #N/D.
- La formula
- ESPR.REG(Testo; Espressione; Sostituzione) sostituisce la prima corrispondenza di Espressione in Testo con Sostituzione. Se c'è una corrispondenza, ESPR.REG restituisce la versione modificata di Testo; se non c'è corrispondenza, Testo viene restituito senza modifiche.
- La formula
=ESPR.REG("Inizializza nuove variabili e ottimizza il vostro codice."; "ise"; "ize")
restituisce "Inizializza nuove variabili e ottimizza il vostro codice.". - La formula
=ESPR.REG("LibreOffice Calc"; "Z"; "?")
non trova corrispondenza e restituisce la stringa "LibreOffice Calc" senza modifiche.
- La formula
- ESPR.REG(Testo; Espressione; Sostituzione;"g") sostituisce la prima corrispondenza di Espressione in Testo con Sostituzione. Se c'è una corrispondenza, ESPR.REG restituisce la versione modificata di Testo; se non c'è corrispondenza, Testo viene restituito senza modifiche.
- La formula
=ESPR.REG("Inizializza nuove variabili e ottimizza il vostro codice."; "ise"; "ize"; "g")
restituisce "Inizializza nuove variabili e ottimizza il vostro codice.". - La formula
=ESPR.REG("LibreOffice Calc"; "Z"; "?"; "g")
non trova corrispondenza e restituisce la stringa "LibreOffice Calc" senza modifiche.
- La formula
- ESPR.REG(Testo; Espressione; ; Corrispondenza) estrae la nesima corrispondenza di Espressione in Testo (dove n è data dal valore dell'argomento Corrispondenza).
- La formula
=ESPR.REG("LibreOffice Calc"; ".c"; ; 1)
estrae la prima occorrenza di una "c" minuscola preceduta da qualsiasi altro carattere e restituisce la stringa "ic". - La formula
=ESPR.REG("LibreOffice Calc"; ".c"; ; 2)
estrae la seconda occorrenza di una "c" minuscola preceduta da qualsiasi altro carattere e restituisce la stringa "ic". - La formula
=ESPR.REG("LibreOffice Calc"; ".c"; ; 3)
non trova corrispondenza e restituisce #N/D. - Il valore 0 per Occorrenza è un caso speciale, per il quale ESPR.REG restituisce Testo non modificato.
- La formula
- ESPR.REG(Testo; Espressione; Sostituzione; Corrispondenza) sostituisce la nesima corrispondenza di Espressione in Testo con Sostituzione (dove n è dato dal valore di argomento Corrispondenza). Se c'è una corrispondenza, ESPR.REG restituisce la versione modificata di Testo; se non c'è corrispondenza, Testo viene restituito senza modifiche.
- La formula
=ESPR.REG("Inizializza nuove variabili e ottimizza il vostro codice."; "ise"; "ize"; 1)
restituisce "Inizializza nuove variabili e ottimizza il vostro codice.". - La formula
=ESPR.REG("Inizializza nuove variabili e ottimizza il vostro codice."; "ise"; "ize"; 2)
restituisce "Inizializza nuove variabili e ottimizza il vostro codice.". - La formula
=ESPR.REG("Inizializza nuove variabili e ottimizza il vostro codice."; "ise"; "ize"; 3)
restituiscela stringa non modificata "Inizializza nuove variabili e ottimizza il vostro codice.". - Il valore 0 per Occorrenza è un caso speciale, per il quale ESPR.REG restituisce Testo non modificato.
- La formula
Informazioni generali sulle espressioni regolari in Calc
- Un'espressione regolare è una stringa di caratteri che definisce una sequenza di testo da ricercare. Potete trovare maggiori e più dettagliate informazioni sulla pagina di Wikipedia relativa alle Espressioni regolari.
- Le espressioni regolari sono ampiamente usate in molti campi e sono disponibili molteplici processori di espressioni regolari. Calc utilizza il pacchetto open source Regular Expressions della International Components for Unicode (ICU). Vedere la loro documentazione sulle Espressioni regolari per maggiori dettagli, che comprendono la definizione integrale della sintassi delle Espressioni regolari ICU.
- In aggiunta a ciò, la guida in linea di LibreOffice fornisce un elenco delle espressioni regolari di alto livello.
- Il motore per le espressioni regolari di Calc supporta il rilevamento di gruppi numerati, che consentono di identificare dei sotto intervalli all'interno di una corrispondenza e di usarli all'interno di un testo sostitutivo. Le parentesi sono usate per raggruppare i componenti di un'espressione regolare e creare un gruppo numerato. Per inserire un gruppo rilevato all'interno di un testo sostitutivo, usate il formato "$n", nel quale n è il numero del gruppo rilevato.
Esempi:
Formula | Descrizione | Restituisce |
---|---|---|
=ESPR.REG("123456ABCDEF"; "[:digit:]"; "Z") | Qui la funzione restituisce "Z23456ABCDEF", dove la prima corrispondenza di una cifra viene sostituita da "Z". | Z23456ABCDEF |
=ESPR.REG(D1; D2; D3; D4) dove le celle da D1 a D4 contengono rispettivamente le stringhe "123456ABCDEF", "[:digit:]", "Z" e "g". | Qui la funzione restituisce "ZZZZZZABCDEF", dove tutte le cifre vengono sostituite da "Z". | ZZZZZZABCDEF |
=ESPR.REG("123456ABCDEF"; "[126]"; ""; "g") | Qui la funzione restituisce "345ABCDEF", dove qualsiasi occorrenza di "1", "2" o "6" viene sostituita dalla stringa vuota e quindi eliminata. | 345ABCDEF |
=ESPR.REG("axbxcxd"; ".x"; ; 2) | Qui la funzione restituisce "bx", la seconda corrispondenza di ".x". | bx |
=ESPR.REG("axbxcxd"; "(.)x"; "$1y"; 2) | Qui la funzione restituisce "axbycxd", la seconda corrispondenza di "(.)x" (ad esempio "bx") viene sostituita con il gruppo catturato di un carattere (ad esempio "b") seguito da "y". | axbycxd |
=ESPR.REG("LibreOffice Calc"; "libreoffice") | Qui la funzione restituisce #N/D perché per impostazione predefinita la corrispondenza è sensibile alle maiuscole e alle minuscole. | #N/D |
=ESPR.REG("LibreOffice Calc"; "(?i)libreoffice") | Qui la funzione trova una corrispondenza e restituisce "LibreOffice", perché il flag di ricerca (?i) passa a una corrispondenza senza distinzione tra maiuscole e minuscole. | LibreOffice |
Funzioni di LibreOffice correlate:
Nessuno.
Standard ODF:
Nessuno
Funzioni equivalenti (o simili) di Excel:
Nessuno