Dokumentation/Calc Funktionen/REGAUS

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/REGEX and the translation is 98% complete.
    Outdated translations are marked like this.

    TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende

    Other languages:


    Funktionsname:

    REGAUS

    Kategorie:

    Text

    Zusammenfassung:

    Vergleicht einen Text gegen einen regulären Ausdruck und entnimmt entweder den übereinstimmenden Text oder ersetzt ihn, je nach den Argumenten.

    Syntax:

    REGAUS(Text; Ausdruck[; [Ersatz][; Marker oder Auftreten]])

    Rückgabewerte:

    Gibt eine der folgenden, von den Argumenten abhängigen Werten zurück. Für weitergehende Informationen über das Auftreten jedes Rückgabewertes (mit Beispielen) siehe #Zusätzliche Informationen: weiter unten.

    1. Den aus dem Originaltext entnommenen Text.
    2. Den Originaltext, wobei eine oder mehrere der Übereinstimmungen ersetzt wurden.
    3. Den Originaltext, unverändert.
    4. Einen value not available error (#NV).

    Argumente:

    Text ist eine Zeichenkette (in Anführungszeichen) oder eine Referenz auf eine Zelle mit der Zeichenkette. Diese Zeichenkette ist der Originaltext, auf den der Ausdruck angewendet werden soll.

    Ausdruck ist ein Text (in Anführungszeichen) oder eine Referenz auf eine Zelle mit dem Text. Dies ist der reguläre Ausdruck, der auf den Text angewendet werden soll.

    Ersatz ist ein Text (in Anführungszeichen) oder eine Referenz auf eine Zelle mit dem Text. Das ist der zu verwendende Ersatztext. Den Ersatz in einen leeren Text einzusetzen kann als Mechanismus gesehen werden, um übereinstimmende Zeichen zu löschen.

    Marker oder Auftreten ist eine der folgenden Optionen:

    1. Ein einzelnes kleines "g" oder eine Referenz auf eine Zelle mit dem "g". Dieses "g" bedeutet globales Ersetzen, also werden alle Übereinstimmungen ersetzt.
    2. Eine nicht-negative Ganzzahl oder eine Referenz auf eine Zelle mit dieser Ganzzahl. diese Zahl gibt an, die wievielte Übereinstimmung betroffen ist.
    • Falls der Ausdruck kein gültiger regulärer Ausdruck ist, dann meldet REGAUS einen invalid argument error (Fehler:502).
    • Falls Marker oder Auftreten ein nicht-numerischer Text ist, der etwas anderes als ein kleines "g" enthält, dann meldet REGAUS einen invalid argument error (Fehler:502).
    • Falls Marker oder Auftreten eine negative Zahl ist, dann meldet REGAUS einen invalid argument error (Fehler:502).
    • Falls Marker oder Auftreten eine nicht negative Dezimalzahl ist, rundet sie REGAUS ab.
    • Falls Ersatz fehlt und Marker oder Auftreten mit "g" angegeben ist, dann verhält sich REGAUS, als würden sowohl Ersatz als auch Marker oder Auftreten fehlen würden.

    Zusätzliche Informationen:

    Spezifische Eigenheiten der Funktion REGAUS

    • Die Ausführung der Funktion REGAUS ist unabhängiug von der Einstellung im Bereich Platzhalter in Formelndes Dialogs Extras ▸ Optionen ▸ LibreOffice Calc ▸ Berechnen (oder LibreOffice ▸ Preferences ▸ LibreOffice Calc ▸ Berechnen unter macOS).
    • Der ursprüngliche Standard von REGAUS ist, case-sensitive Übereinstimmungen zu verwenden, aber das kann durch Setzen von Markern im ICU regulären Ausdruck geändert werden.
    • Der ursprüngliche Text wird von Ersetzungen durch REGAUS nicht beeinflusst - Änderungen werden nur im Ausgabetext vorgenommen.
    • Es kann hifreich sein, REGAUS als Ausführung in fünf bestimmten "Modi" abhängig von den Argumenten der Funktion zu sehen. Diese Modi sind wie folgt:
    1. REGAUS(Text; Ausdruck) entnimmt den ersten Treffer des Ausdruckes im Text. Diese einfache Form ist hilfreich bei der Überprüfung vordefinierter Muster (wie z. Bsp. Telefonnummern, eMail-Adressen, Postleitzahlen usw.).
      • Die Formel =REGAUS("LibreOffice Calc"; ".c") entnimmt das erste Auftreten des kleinen "c" nach einem anderen Zeichen und gibt "ic" zurück.
      • Die Formel =REGAUS("LibreOffice Calc"; "Z") findet keine Übereinstimmung und gibt #NV zurück.
    2. REGAUS(Text; Ausdruck; Ersatz) ersetzt die erste Übereinstimmung des Ausdruckes im Text mit dem Ersatz. Falls es einen Treffer gibt, gibt REGAUS die geänderte Version des Testes zurück. Andernfalls wird der unveränderte Text zurückgegeben.
      • Die Formel =REGAUS("Initialisire neue Variablen und optimire deinen Code."; "ire"; "iere") gibt "Initialisiere neue Variablen und optimiere deinen Code." zurück.
      • Die Formel =REGAUS("LibreOffice Calc"; "Z"; "?") findet keine Übereinstimmung und gibt den Text "LibreOffice Calc" unverändert zurück.
    3. REGAUS(Text; Ausdruck; Ersatz; "g") ersetzt jedes Vorkommen von Ausdruck im Text mit Ersatz. Falls es einen Treffer gibt, gibt REGAUS die veränderte Version des Textes zurück, ansonsten wird der Text unverändert zurückgegeben.
      • Die Formel =REGAUS("Initialisire neue Variablen und optimire deinen Code."; "ire"; "iere") gibt "Initialisiere neue Variablen und optimiere deinen Code." zurück.
      • Die Formel =REGAUS("LibreOffice Calc"; "Z"; "?"; "g") findet keine Übereinstimmung und gibt den Text "LibreOffice Calc" unverändert zurück.
    4. REGAUS(Text; Ausdruck; ; Auftreten) entnimmt die n-te Übereinstimmung des Ausdruckes im Text (wobei n im Argument Auftreten angegeben wird).
      • Die Formel =REGAUS("LibreOffice Calc"; ".c"; ; 1) entnimmt das erste Auftreten des Kleinbuchstabens "c" nach einem anderen Zeichen und gibt den Text "ic" zurück.
      • Die Formel =REGAUS("LibreOffice Calc"; ".c"; ; 2) entnimmt das zweite Auftreten des Kleinbuchstabens "c" nach einem anderen Zeichen und gibt den Text "lc" zurück.
      • Die Formel =REGAUS("LibreOffice Calc"; ".c"; ; 3) findet keine Übereinstimmung und gibt #NV zurück.
      • Der Wert 0 im Auftreten ist ein Sonderfall. Dabei gibt REGAUS den unveränderten Text zurück.
    5. REGAUS(Text; Ausdruck; Ersatz; Auftreten) ersetzt die n-te Übereinstimmung des Ausdruckes im Text mit dem Ersatz (wobei n im Auftreten angegeben wird). Falls es einen Treffer gibt, gibt REGAUS die veränderte Version des Textes zurück, ansonsten wird der Text unverändert zurückgegeben.
      • Die Formel =REGAUS("Initialisire neue Variablen und optimire deinen Code."; "ire"; "iere"; 1) gibt "Initialisiere neue Variablen und optimire deinen Code." zurück.
      • Die Formel =REGAUS("Initialisire neue Variablen und optimire deinen Code."; "ire"; "iere") gibt "Initialisire neue Variablen und optimiere deinen Code." zurück.
      • Die Formel =REGAUS("Initialisire neue Variablen und optimire deinen Code."; "ire"; "iere"; 3) gibt den Text "Initialisire neue Variablen und optimire deinen Code." unverändert zurück.
      • Der Wert 0 im Auftreten ist ein Sonderfall. Dabei gibt REGAUS den unveränderten Text zurück.


    Allgemeine Informationen über die regulären Ausdrücke in Calc

    Note pin.svg

    Anmerkung:
    Der Einfachheit halber werden die Informationen dieses Unterabschnittes auf allen Seiten der Funktionen in Calc wiederholt, die reguläre Ausdrücke bearbeiten.
    • Ein regulärer Ausdruck ist eine Zeichenkette die ein Textmuster beschreibt. Genauere allgemeine Hintergrundinformationen finden sich in der Wiki Regulärer Ausdruck
    • Reguläre Ausdrücke sind weit verbreitet. Dabei gibt es viele Prozessoren für reguläre Ausdrücke. Calc nutzt den open source Regular Expressions package from the International Components for Unicode (ICU). Siehe bitte unter deren Dokumentation zu den regulären Ausdrücken für weitergehende Informationen inklusive der volständigen Beschreibung zur Syntax der ICU Regular Expressions.
    • Zusätzlich stellt die LibreOffice Hilfe eine umfangreiche Liste der regulären Ausdrücke zur Verfügung.
    • Calcs Generator für reguläre Ausdrücke unterstützt zahlreiche Erfassungs Möglichkeiten, welche es Untergruppen in einem Bereich erlauben innerhalb eines Treffers identifiziert zu werden und in einem Text ersetzt werden können. Runde Klammern werden genutzt um Komponenten eines regulären Ausdruckes zu gruppieren und eine nummerierte Treffer-Liste zu erzeugen. Um eine solche Treffer-Liste in einen Text einzufügen, verwenden Sie bitte das Kürzel "$n", wobei n die Zahl der Treffer-Liste ist.

    Beispiele:

    Formel Beschreibung Ergebnis
    =REGAUS("123456ABCDEF"; "[:digit:]"; "Z") Hier gibt die Funtion "Z23456ABCDEF" zurück, wobei das erste Vorkommen einer Ziffer durch "Z" ersetzt wird. Z23456ABCDEF
    =REGAUS(D1; D2; D3; D4), wobei die Zellen D1 bis D4 die Texte "123456ABCDEF", "[:digit:]", "Z" und "g" enthält. Hier gibt die Funktion "ZZZZZABCDEF" zurück, wobei alle Vorkommen einer Ziffer durch "Z" ersetzt werden. ZZZZZZABCDEF
    =REGAUS("123456ABCDEF"; "[126]"; ""; "g") Hier gibt die Funktion "345ABCDEF" zurück, wobei jedes Auftreten von "1", "2" oder "6" durch einen leeren Text und damit entfernt wird. 345ABCDEF
    =REGAUS("axbxcxd"; ".x"; ; 2) Hier gibt die Funktion "bx" zurück, das zweite Auftreten von ".x". bx
    =REGAUS("axbxcxd"; "(.)x"; "$1y"; 2) Hier gibt die Funktion "axbycxd" zurück, der zweite Treffer von "(.)x" (also "bx") wird durch die gefundene Zeichengruppe eines Buchstabens (also "b") ersetzt, gefolgt von einem "y". axbycxd
    =REGAUS("LibreOffice Calc"; "libreoffice") Hier gibt die Funktion #NV zurück, weil die Suche standardmäßig case-sensitiv ist. #NV
    =REGAUS("LibreOffice Calc"; "(?i)libreoffice") Hier findet die Funktion einen Treffer und gibt "LibreOffice" zurück, weil die Suche nach (?i) in eine nicht case-sensitive Suche umschaltet. LibreOffice

    Ähnliche LibreOffice Funktionen:

    Nichts.

    ODF Standard:

    Nichts

    Betroffene (oder ähnliche) EXCEL-Funktionen:

    Nichts


    Retrieved from "https://wiki.documentfoundation.org/index.php?title=Documentation/Calc_Functions/REGEX/de&oldid=775349"