Dokumentation/Calc Funktionen/SUCHEN
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende
Funktionsname:
SUCHEN
Kategorie:
Text
Zusammenfassung:
Ermittelt das erste Auftreten einer Zeichenkette innerhalb eines Textes.
SUCHEN verwendet entweder Platzhalter oder reguläre Ausdrücke. Standardmässig ist die Suche nicht case-sensitiv. Eine case-sensitive Suche kann unter Verwendung eines regulären Ausdruckes durchgeführt werden.
Syntax:
SUCHEN(Suchtext; Text[; Position])
Rückgabewerte:
Gibt die Position des ersten Zeichens des ersten Auftretens des zu suchenden Textes innerhalb des abzusuchenden Textes als Ganzzahl zurück. Der Rückgabewert kann nicht größer als die Länge des abzusuchenden Textes sein.
Argumente:
Suchtext ist ein Text (in Anführungszeichen), eine Zahl oder eine Referenz auf eine Zelle mit einem dieser Typen. Das ist dann der zu suchende Text.
Text ist ein Text (in Anführungszeichen), eine Zahl oder eine Referenz auf eine Zelle mit einem dieser Typen. Das ist dann der abzusuchende Text.
Position ist eine positive Ganzzahl oder eine Referenz auf eine Zelle mit dieser Ganzzahl. Das ist dann die Position des Zeichens mit dem die Suche startet. Falls die Position fehlt, verwendet SUCHEN die 1.
- Falls die Position keine Ganzahl ist, dann verkürzt sie SUCHEN auf eine Ganzzahl.
- Falls die Position kleiner als 1 ist, dann meldet SUCHEN einen invalid argument error (Fehler:502).
- Falls die Position nach einer eventuellen Verkürzung größer als die Länge des abzusuchenden Textes ist, dann meldet SUCHEN einen #WERT! Fehler.
- Falls keine Übereinstimmung gefunden wurde, dann meldet SUCHEN einen #WERT! error. Dies ist ein Fehler-Fall, der behandelt werden muss, bevor er als Argument einer anderen Funktion übergeben wird.
Zusätzliche Informationen:
Spezifische Eigenheiten der Funktion SUCHEN
Im Dialog ▸ ▸ ▸ (oder ▸ ▸ ▸ unter macOS) hat die Einstellung Suchkriterien = und <> müssen auf ganze Zellen angewendet werden keine Auswirkung auf das Verhalten von SUCHEN.
Vorschläge für die Behandlung von #WERT! Fehlern nachdem kein Treffer gefunden wurde:
=WENN(ISTFEHLER(SUCHEN("xyz"; "abcdef"; 1)); "ERR: Missing Substring"; "Substring Present")gibt "ERR: Missing Substring" anstatt des Fehlers aus der Funktion SUCHEN zurück.=WENN(ISTZAHL(SUCHEN("xyz"; "abcdef"; 1)); "Substring Present"; "ERR: Missing Substring")gibt "ERR: Missing Substring" zurück und meldet nicht den Fehler aus der Funktion SUCHEN weiter.
Allgemeine Informationen über die regulären Ausdrücke in Calc
 |
Anmerkung:
|
- Ein regulärer Ausdruck ist eine Zeichenkette die ein Textmuster beschreibt. Genauere allgemeine Hintergrundinformationen finden sich in der Wiki Regulärer Ausdruck
- Reguläre Ausdrücke sind weit verbreitet. Dabei gibt es viele Prozessoren für reguläre Ausdrücke. Calc nutzt den open source Regular Expressions package from the International Components for Unicode (ICU). Siehe bitte unter deren Dokumentation zu den regulären Ausdrücken für weitergehende Informationen inklusive der volständigen Beschreibung zur Syntax der ICU Regular Expressions.
- Zusätzlich stellt die LibreOffice Hilfe eine umfangreiche Liste der regulären Ausdrücke zur Verfügung.
- Calcs Generator für reguläre Ausdrücke unterstützt zahlreiche Erfassungs Möglichkeiten, welche es Untergruppen in einem Bereich erlauben innerhalb eines Treffers identifiziert zu werden und in einem Text ersetzt werden können. Runde Klammern werden genutzt um Komponenten eines regulären Ausdruckes zu gruppieren und eine nummerierte Treffer-Liste zu erzeugen. Um eine solche Treffer-Liste in einen Text einzufügen, verwenden Sie bitte das Kürzel "$n", wobei n die Zahl der Treffer-Liste ist.
Allgemeine Informationen über die Platzhalter in Calc
Platzhalter sind spezielle Zeichen für Suchtexte in Argumenten für einige Funktionen in Calc; sie können auch im Suchdialog verwendet werden. Der Gebrauch von Platzhaltern ermöglicht fortgeschrittenere Suchparamter bei einer einfachen Textsuche.
Calc unterstützt entweder Platzhalter oder reguläre Ausdrücke abhängig von den Einstellungen der aktuellen Applikation. Standardmäßig werden Platzhalter statt regulärer Ausdrücke unterstützt.
Um sicherzustellen, dass Platzhalter unterstützt werden, rufen Sie ▸ ▸ ▸ auf. Überprüfen Sie hier, ob die Einstellung Platzhalter in Formeln ermöglichen ausgewählt ist. Beachten Sie auch, dass reguläre Ausdrücke durch Auswählen von Reguläre Ausdrücke in Formeln ermöglichen unterstüzt werden können. Genauso können Sie weder Platzhalter noch reguläre Ausdrücke unterstützen lassen.
Die folgende Tabelle zeigt die Platzhalter, die Calc unterstützt.
| Platzhalter | Beschreibung |
|---|---|
| ? (Fragezeichen) | Vertritt ein einzelnes Zeichen. Zum Beispiel kann der Suchtext "b?g" "bag" oder "beg" heißen, aber nicht "boog" oder "mug". Beachte, dass es auch nicht "bg" heißen kann, da "?" genau ein Zeichen sein muss. Der Platzhalter "?" vertritt kein fehlendes Zeichen. |
| * (Asterisk) | Vertritt eine Reihe von Zeichen inklusive dem Leer-Text. Zum Beispiel vertritt der Text "*cast" "cast", "forecast" und "outcast", aber nicht "forecaster" unter Verwendung der Standardeinstellungen von Calc. Falls die Einstellung Suchkriterien = und <> müssen auf ganze Zellen zutreffen in ▸ ▸ ▸ ausgeblendet ist, dann wird "forecaster" auch durch *cast vertreten. |
| ~ (Tilde) | Unterdrückt die Sonderbehandlung des Fragezeichens Asterisken oder der Tilde, welche direkt nach der Tilde kommen. Zum Beispiel, stellt der Suchstring "why~?" nur "why?" und nicht "whys" oder "why~s" dar. |
Platzhalter sind nicht case sensitiv, also "A?" heißt sowohl "A1" also auch "a1".
Diese Platzhalter werden sowohl in Calc als auch in Microsoft EXCEL unterstützt. Wenn also Kompatibilität zwischen den beiden Anwendungen erforderlich ist, arbeiten Sie mit Platzhaltern anstatt mit regulären Ausdrücken. Wenn dagegen Kompatibilität nicht notwendig ist, arbeiten Sie stattdessen mit regulären Ausdrücken für mächtigere Möglichkeiten.
Beispiele:
Solange es nicht anders angegeben wird, funktionieren die Formeln wie beschrieben, unabhängig davon, ob Platzhalter oder reguläre Ausdrücke eingeschaltet sind oder nicht.
| Formel | Beschreibung | Ergebnis |
|---|---|---|
| =SUCHEN("fifty"; "Fifty-fifty") | Hier gibt die Funktion 1 zurück, weil der Treffer nicht case-sensitiv ist. | 1 |
| =SUCHEN(76; 998.877.667.654) | Hier gibt die Funktion 6 zurück, weil die Suche standardmässig beim ersten Zeichen des abzusuchenden Textes beginnt. | 6 |
| =SUCHEN(76; 998.877.667.654; 7) | Hier gibt die Funktion 9 zurück, weil die Suche beim siebten Zeichen des abzusuchenden Textes beginnt. | 9 |
| =SUCHEN(D1; D2; D3), wobei die Zellen D1 und D2 die Texte "Rook" und "Knight", während Zelle D3 1 enthält. | Hier gibt die Funktion den Fehler #WERT! zurück, weil kein Treffer gefunden wurde. | #WERT! |
| =SUCHEN("b??g"; "big bang theory") | Für diese Beispiel müssen Platzhalter akzeptiert werden. Hier gibt die Funktion 5 zurück, weil der "bang" aber nicht "big" übereinstimmt. | 5 |
| =SUCHEN("w*"; "What is the weather forecast?") | Für diese Beispiel müssen Platzhalter akzeptiert werden. Hier gibt die Funktion 1 zurück und zeigt damit, dass die Suche mit Platzhaltern ncht case-sensitiv ist. | 1 |
| =SUCHEN("t.n"; "often") | Für diese Beispiel müssen reguläre Ausdrücke akzeptiert werden. Hier gibt die Funktion 3 zurück, weil "ten" übereinstimmt. | 3 |
| =SUCHEN("(?-i)fifty"; "Fifty-fifty") | Für diese Beispiel müssen reguläre Ausdrücke akzeptiert werden. Hier gibt die Funktion 7 zurück, weil durch die Option "(?-i)" innerhalb des regulären Ausdruckes auf eine case-sensitive Suche umgeschaltet wurde. Dies zeigt den Gegensatz zum ersten Beispiel. | 7 |
Ähnliche LibreOffice Funktionen:
ODF Standard:
Betroffene (oder ähnliche) EXCEL-Funktionen:
SEARCH