Documentatie/Calc-functies/STIJL

This page is a translated version of the page Documentation/Calc Functions/STYLE and the translation is 100% complete.

TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren

Other languages:

Deutsch
English
Nederlands

Startpagina Calc-functies | Lijst met functies | Afkortingen

Functienaam:

STIJL

Categorie:

Werkblad

Samenvatting:

Past een opmaakprofiel toe op de cel die de functie-aanroep bevat en past optioneel een tweede opmaakprofiel toe op die cel na een vertraging. STIJL kan handig zijn wanneer u een formule moet gebruiken om de opmaak die op een cel is toegepast dynamisch te wijzigen.

De STIJL functie mag niet worden gebruikt zonder dwingende reden. Het doel is het gebruik met asynchrone Add-In functies om visueel te informeren over de beschikbaarheid van een resultaat. In bijna alle andere gevallen is het gebruik van voorwaardelijke opmaak een betere keuze.

Syntaxis:

STIJL(Opmaakprofiel[; Tijd[; Opmaakprofiel 2]])

Retourneert:

Retourneert de waarde 0 (nul), zodat u de functie-aanroep STIJL kunt toevoegen aan andere componenten van een formule zonder de algehele waarde-uitvoer van de formule te wijzigen.

Argumenten:

Opmaakprofiel is een tekenreeks tussen aanhalingstekens of een verwijzing naar een cel die die tekenreeks bevat, dat wil zeggen de naam van een celopmaakprofiel dat (aanvankelijk) aan de cel moet worden toegewezen. Als de tekenreeks niet overeenkomt met de naam van een gedefinieerde celopmaakprofiel, wordt in plaats daarvan het celopmaakprofiel Standaard toegepast.

Tijd is een positief reëel getal of een verwijzing naar een cel die dat getal bevat, dat wil zeggen de vertraging in seconden voordat het celopmaakprofiel Opmaakprofiel 2 wordt toegepast. Als dit argument wordt weggelaten, wordt de standaardwaarde 0 (nul) aangenomen.

Opmaakprofiel 2 is een tekenreeks tussen aanhalingstekens of een verwijzing naar een cel die die tekenreeks bevat, dat wil zeggen de naam van een celopmaakprofiel dat op de cel moet worden toegepast nadat de opgegeven vertragingstijd Tijd is verstreken. Als een vertragingstijd is opgegeven en het argument Opmaakprofiel 2 wordt weggelaten, zal de cel na de vertragingstijd Tijd terugkeren naar het celopmaakprofiel Standaard.

Als Tijd een negatieve waarde is, zet STIJL de waarde terug op 0. Er wordt in dit geval geen fout gerapporteerd.
Als Tijd is ingesteld of teruggezet op 0, wordt het oorspronkelijk toegepaste opmaakprofiel niet gewijzigd en wordt Opmaakprofiel 2 nooit toegepast.

Aanvullende details:

Wisseling van opmaakprofiel via de functie STIJL vindt plaats wanneer:

De functie-aanroep eerst wordt in een cel ingevoerd.
Na het selecteren van Gegevens ▸ Berekenen ▸ Werkblad opnieuw berekenen, worden alle functie-aanroepen van STIJL gereset.
Na het selecteren van Gegevens ▸ Berekenen ▸ Opnieuw berekenen, wordt de aanroep van STIJL in de geselecteerde cel gereset.

STIJL is vooral handig bij gebruik in combinatie met de HUIDIG om kleuren, lettertypen of andere opmaak toe te passen op een cel, afhankelijk van de waarde.

Beschouw bijvoorbeeld de formule =(($A$1*$A$2)/$A$3) + STIJL(ALS(HUIDIG()>3; "Goed"; "Slecht")). Deze formule berekent de waarde van ($A$1*$A$2)/$A$3. Als het resultaat van deze berekening groter is dan 3, wordt dat resultaat weergegeven in de formulecel met het celopmaakprofiel Goed. Anders wordt het resultaat weergegeven in de formulecel met het celopmaakprofiel Slecht.

Er is geen directe manier in een formule om te bepalen welke opmaak is toegepast op een cel.

Voorbeelden:

Gegevens voor voorbeelden
	A	B	C
1	4		Waarschuwing
2	3	6	60,0
3	2	7	Standaard

Formule	Beschrijving	Retourneert
=STIJL("Voetnoot")	Retourneert 0 en maakt de formulecel op met het celopmaakprofiel "Voetnoot".	0
=STIJL(C1; C2; C3)	Retourneert 0 en formatteert de formulecel gedurende 60 seconden met behulp van het celopmaakprofiel Waarschuwing. Na 60 seconden wordt het celopmaakprofiel Standaard toegepast op de cel.	0
=WORTEL(49) + STIJL("Neutraal")	Toont de vierkantswortel van 49 in het celopmaakprofiel Neutraal.	7
=PI()MACHT(3; 2) + STIJL("Resultaat"; 5; "Standaard*")	Toont π×3² (28,2743338823081) in het celopmaakprofiel Resultaat gedurende 5 seconden en daarna in het celopmaakprofiel Standaard.	28,2743...
="Tekst"&T(STIJL("Fout"))	`STIJL("Fout")` past het celopmaakprofiel Fout toe op de formulecel en retourneert 0 (nul). T(0) converteert de waarde 0 naar een lege tekenreeks (waardoor 0 niet wordt weergegeven). Dit wordt (fictief) toegevoegd aan de string "Tekst".	Tekst
=B2+B3 + STIJL( ALS( HUIDIG()>10; "Slecht"; "Goed"))	Retourneert het resultaat van `B2+B3`, aangezien de functie STIJL altijd de waarde 0 retourneert. De geretourneerde waarde wordt echter weergegeven met het celopmaakprofiel Slecht als deze groter is dan 10 en anders met het celopmaakprofiel Goed.	13

Gerelateerde LibreOffice-functies:

ODF standaard:

Geen. Zie in plaats daarvan ORG.OPENOFFICE.STYLE

Gerelateerde (of gelijkwaardige) Excel-functies:

Geen