Jump to content

Documentation/Calc 関数/STYLE

From The Document Foundation Wiki
This page is a translated version of the page Documentation/Calc Functions/STYLE and the translation is 100% complete.


Function name:

STYLE

Category:

Spreadsheet

Summary:

関数呼び出しを含むセルにスタイルを適用し、オプションで、時間遅延後にそのセルに 2 番目のスタイルを適用します。 STYLE は、数式を使用してセルに適用された書式を動的に変更する必要がある場合に役立ちます。

STYLE 関数は、やむを得ない理由がない限り使用しないでください。 その目的は、非同期の Add-In 関数を使用して、結果が利用可能であることを視覚的に通知することです。 それ以外のほとんどの場合、条件付き書式を使用することをお勧めします。

Syntax:

STYLE(スタイル[; 時間[; スタイル 2]])

Returns:

値 0 (ゼロ)を返します。これにより、数式から出力される全体的な値を変更することなく、数式の他のコンポーネントに STYLE 関数の呼び出しを追加できます。

Arguments:

スタイルは、引用符で囲まれた文字列、またはその文字列を含むセルへの参照であり、セルに(最初に)割り当てられるセルスタイルの名前です。 文字列が定義されたセルスタイルの名前と一致しない場合は、代わりに 標準 のセルスタイルが適用されます。

時間 は、正の実数、またはその数値を含むセルへの参照であり、スタイル 2 のセルスタイルを適用するまでの遅延時間 ( 秒 ) です。 この引数を省略すると、既定値の 0 (ゼロ)が使われます。

スタイル 2 は、引用符で囲まれた文字列、またはその文字列を含むセルへの参照です。これは、指定された遅延 時間 が経過した後にセルに適用されるセルスタイルの名前です。 遅延 時間 を指定し、引数 スタイル 2 を省略すると、遅延時間の経過後、セルは 標準 のセルスタイルに戻ります。

  • 時間 が負の値の場合、 STYLE は値を 0 にリセットします。この場合、エラーは報告されません。
  • 時間 が 0 に設定またはリセットされた場合、最初に適用されたスタイルは変更されず、スタイル 2 は適用されません。

Additional details:

  • STYLE 関数によるスタイルの切り替えは、次の場合に行われます:
  • 関数呼び出しは、最初にセルに入力されます。
  • データ ▸ 計算 ▸ 無条件の再計算 を選択すると、すべての STYLE 関数の呼び出しがリセットされます。
  • データ ▸ 計算 ▸ 再計算を選択すると、選択したセルの{STYLE 関数の呼び出しがリセットされます。
  • STYLE は、 CURRENT 関数と組み合わせて使用すると、セルの値に応じて色、フォント、またはその他の書式をセルに適用する場合に特に便利です。たとえば、数式 =(($A$1*$A$2)/$A$3) + STYLE(IF(CURRENT()>3; "良い"; "悪い")) を考えてみましょう。この数式は、($A$1*$A$2)/$A$3 の値を計算します。この計算の結果が 3 を超える場合、その結果は 良い セルスタイルを使用して数式セルに表示されます。それ以外の場合、結果は 悪い セルスタイルを使用して数式セルに表示されます。
  • 数式では、セルに適用されている書式を直接判断する方法はありません。

Examples:

例のデータ
A B C
1 4 警告
2 3 6 60.0
3 2 7 標準
Formula Description Returns
=STYLE("脚注") 0 (ゼロ)を返し、数式セルを 脚注 のセルスタイルで書式設定します。 0
=STYLE(C1; C2; C3)

0 (ゼロ)を返し、警告 のセルスタイルを使用して数式セルを 60 秒間書式設定します。 60 秒後、標準 のセルスタイルがセルに適用されます。

0
=SQRT(49) + STYLE("どちらでもない") 49 の平方根を どちらでもない のセルスタイルで表示します。 7
=PI()*POWER(3; 2) + STYLE("結果"; 5; "標準") π×32 (28.2743338823081)結果 のセルスタイルで 5 秒間表示し、その後は 標準 のセルスタイルで表示します。 28.2743...
="Text"&T(STYLE("エラー"))

STYLE("エラー") は、数式セルに エラー のセルスタイルを適用し、0 (ゼロ)を返します。 T(0)は、値 0 を空の文字列に変換します ( 0 が表示されないようにします )。 これは、文字列 "Text" に ( 概念的に ) 追加されます。

Text
=B2+B3 + STYLE( IF( CURRENT()>10; "悪い"; "良い"))

STYLE 関数は常に値 0 (ゼロ)を返すため、B2+B3 の結果を返します。 ただし、戻り値は、10 より大きい場合は 悪いという名前のセルスタイルを使用して表示され、それ以外の場合は 良い という名前のセルスタイルを使用して表示されます。

13

Related LibreOffice functions:

CELL

CURRENT

IF

INFO

N

T

TEXT

VALUE

ODF standard:

なし。代わりに次を参照してください。 ORG.OPENOFFICE.STYLE

Related (or similar) Excel functions:

なし。