Documentation/Calc 関数/SUMPRODUCT
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Donate
Function name:
SUMPRODUCT
Category:
Array
Summary:
指定された配列内の対応する要素を乗算し、それらの積の合計を返します。SUMPRODUCT を使用して、2 つのベクトルの dot or scalar product を計算できます。
SUMPRODUCT 関数の呼び出しは、配列数式として入力する必要はありません。
Syntax:
SUMPRODUCT(配列 1[; 配列 2;][...;[配列 255]])
Returns:
計算された積の合計である実数を返します。
Arguments:
配列 1には、乗算と合計に使用される最初の配列が含まれます。この引数には、明示的なセル範囲 (A1:C3 など)、名前付き範囲の名前、データベース範囲の名前、またはインライン定数配列の形式を使用できます。
配列 2 … 配列 255には、乗算と合計に使用される他の配列が含まれています。これらの引数は、配列 1 に対してリストされた形式のいずれかを取ることができます。配列 1 のエントリ数は、配列 2 … 配列 255 のそれぞれのエントリ数と同じである必要があります。
- 配列 1 のエントリ数が、他の配列引数 配列 2 … 配列 255 のエントリ数と等しくない場合、SUMPRODUCT は #VALUE! エラーを返します。
- 配列 1 ... 配列 255 内のいずれかのセルが空であるか、数値以外のデータが含まれている場合、そのセルは SUMPRODUCT によって無視されます。
Additional details:
SUMPRODUCT 関数に固有の詳細
- SUMPRODUCT は、次の値を計算して返します。
- [math]\displaystyle{ \sum_{i}^{N} 配列 1_{i} \times 配列 2_{i} \times ... \times 配列 254_{i} \times 配列 255_{i} }[/math]
- ここで、N は各配列引数のエントリ数です。
- SUMPRODUCT を使用して、指定した条件が真のセルを合計することもできます。次の例を参照してください。
Calc の配列関数に関する一般事項
次のテキスト内での繰り返しを避けるために、Windows / Linux キーの組み合わせのみが指定されます。次の表は、これらのキーの組み合わせと macOS の同等のキーの組み合わせとのマッピングを示しています。
Windows/Linux のキーの組み合わせ | macOS 対応 | 機能 |
---|---|---|
Ctrl + ⇧ Shift + ↵ Enter | ⌘ Cmd + ⇧ Shift + ↵ Enter | 配列数式を作成します。 |
Ctrl + / | ⌘ Cmd + / | 配列数式範囲内のすべてのセルを選択します。"/" はテンキーの除算キーです。 |
Ctrl + C | ⌘ Cmd + C | コピーします。 |
Ctrl + V | ⌘ Cmd + V | 貼り付けます。 |
- 配列は、データを含むセルの四角形の範囲です。たとえば、3 行 × 3 列の正方形の範囲は 3 x 3 配列です。可能な最小の配列は、2 つの隣接するセルを持つ 1 x 2 または 2 x 1 配列です。(実際の最小配列は 1 x 1)
- セル範囲内の個々の値が評価される数式は、配列数式 と呼ばれます。配列数式と他の数式の違いは、配列数式では 1 つの値ではなく複数の値が同時に処理されることです。
- 関数ウィザード を使用して配列数式を作成する場合は、結果が配列で返されるように 配列 チェックボックスをオンにする必要があります。オンにしない場合は、計算される配列の左上のセルの値のみが返されます。
- 配列数式をセルに直接入力する 場合は、↵ Enter キーではなく Ctrl + ⇧ Shift + ↵ Enter キーの組み合わせを使用する必要があります。その場合にのみ、数式は配列数式になります。
- 配列数式は、波括弧 または 中括弧 ("{" および "}") で囲まれで表示されます。これらの中括弧を手動で入力して配列数式を作成することはできません。
- 一部の配列関数は、式が通常通りに入力された場合でも、配列数式として評価されるパラメータ を取ります。これらは、MDETERM、MINVERSE、MMULT、SUMPRODUCT、SUMX2MY2、SUMX2PY2、および SUMXMY2 です。
- Calcでは、数式での定数の インライン配列 をサポートしています。インライン配列は、波括弧または中括弧 ("{"および"}") で囲まれています。個々の要素には、数値(負数を含む)、論理定数 (TRUE、 FALSE)、またはリテラル文字列を指定できます。定数以外の式は使用できません。配列には、1 つ以上の行と 1 つ以上の列を入力できます。すべての行は同じ数の要素で構成されている必要があります。同様に、すべての列は同じ数の要素で構成されている必要があります。
- 配列数式の編集。配列数式を含むセル範囲を選択します。範囲全体を選択するには、範囲内にカーソルを置き、 Ctrl + / を押します。次に、 F2 を押すか、数式入力ボックスにカーソルを置き、必要に応じて数式を編集し、そして最後に Ctrl + ⇧ Shift + ↵ Enter のキーの組み合わせを使用します。
- 配列数式の削除。配列数式を含むセル範囲を選択します。範囲全体を選択するには、範囲内にカーソルを置いて Ctrl + / を押します。配列数式を含む配列の内容を削除するには、Delete を押します。または、← Backspace を押して [内容の削除] ダイアログボックスを表示し、数式 または すべてのを削除 を選択して、 をクリックします。
- 配列数式のコピー。配列数式を含むセル範囲を選択します。範囲全体を選択するには、範囲内にカーソルを置いて Ctrl + / を押します。次に、F2 を押すか、数式入力ボックスにカーソルを置きます。 Ctrl + C を押して数式をコピーします。配列数式を挿入するセル範囲を選択し、F2 を押すか、数式入力ボックスにカーソルを置きます。選択したスペースで Ctrl + V を押して数式を貼り付け、 Ctrl + ⇧ Shift + ↵ Enter のキーの組み合わせを使用して確定します。選択された範囲に配列数式が含まれます。
- 配列範囲の調整。配列数式を含むセル範囲を選択します。範囲全体を選択するには、範囲内にカーソルを置き、Ctrl + / を押します。選択範囲の右下に小さなアイコンが表示され、マウスを使用して範囲を拡大または縮小できます。配列範囲を調整しても、配列数式は自動的に調整されません。結果が表示される範囲を変更するだけです。
Examples:
Formula | Description | Returns |
---|---|---|
=SUMPRODUCT({1,2,3,4,5,6}; {3,4,5,6,7,8}) | 関数は各配列内の 6 つの数値の積を合計します。返される値は、(1*3) + (2*4) + (3*5) + (4*6) + (5*7) + (6*8) として計算されます。 | 133 |
=SUMPRODUCT(A1:B2; F1:G2) ここで、セル A1、A2、B1、B2、F1、F2、G1、および G2 には、それぞれ 4.7、-8.5、2.7、8.9、4.6、-4.7、2.1、および 0.1 の値が含まれます。 |
関数は各配列内の 4 つの数値の積を合計します。返される値は、A1*F1 + B1*G1 + A2*F2 + B2*G2 として計算されます。 | 68.13 |
=SUMPRODUCT(配列データ) ここで、配列データは、値 {1, 2, 3, 4, 5, 6; 7, 8, 9, 10, 11, 12} を含む 2 x 6 のセル領域をカバーする名前付き範囲です。 |
配列引数が 1 つしかないため、関数は配列内の 12 個の数値を単純に合計します。 | 78 |
次のデータは、条件付きカウントに SUMPRODUCT を使用する簡単な例を提供するために使用できます。
A | B | C | D | |
---|---|---|---|---|
1 | 地域 | カテゴリ | 従業員 | 売上高 |
2 | North | Tennis | Kurt | $410 |
3 | East | Golf | Hans | $1,508 |
4 | South | Sailing | Ute | $2,340 |
5 | East | Tennis | Brigitte | $4,872 |
6 | East | Tennis | Fritz | $2,623 |
7 | South | Tennis | Fritz | $3,821 |
8 | South | Golf | Fritz | $3,739 |
9 | West | Golf | Ute | $4,195 |
10 | East | Golf | Hans | $2,023 |
11 | West | Tennis | Hans | $2,804 |
12 | West | Sailing | Ute | $579 |
13 | North | Tennis | Kurt | $1,858 |
14 | East | Tennis | Hans | $2,827 |
15 | North | Golf | Ute | $4,482 |
16 | South | Golf | Hans | $1,539 |
Formula | Description | Returns |
---|---|---|
=SUMPRODUCT(A2:A16="North"; D2:D16) | North 地域 (セル A2:A16) を表す行の 売上高 (セル D2:D16) を合計します。 | $6,750 |
=SUMPRODUCT(B2:B16="Golf"; C2:C16="Hans"; D2:D16) | 特定の従業員 Hans (セル C2:C16) とゴルフ・カテゴリ (セル B2:B16) を表す行の 売上高 (セル D2:D16) が合計されます。 | $5,070 |
=SUMPRODUCT((A2:A16="North") + (A2:A16="East"); D2:D16) | North または East 地域 (セル A2:A16) を表す行の売上高 (セル D2:D16) を合計します。 | $20,603 |
Related LibreOffice functions:
なし。
ODF standard:
Related (or similar) Excel functions:
SUMPRODUCT