Dokumentation/Calc Funktionen/TYP

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/TYPE and the translation is 100% complete.
    Other languages:


    Funktionsname:

    TYP

    Kategorie:

    Information

    Zusammenfassung:

    Gibt einen numerischen Wert zurück, der den Typ des mitgegebenen Arguments angibt.

    Syntax:

    TYP(Wert)

    Rückgabewerte:

    Gibt eine Zahl in Übereinstimmung mit folgender Tabelle zurück:

    Typ des Argumentes Rückgabewert
    Zahl 1
    Text 2
    logischer Wert / Wahrheitswert 4
    Formel 8
    Fehler 16
    Aufzählung 64

    Argumente:

    Wert ist ein Ausdruck oder einer Referenz auf eine Zelle, die den Ausdruck enthält, dessen Typ bestimmt wird.

    • Falls das Argument eine Referenz auf eine Zelle ist, die sowohl einen Fehler als eine Formel enthält, wird 16 zurückgegeben.
    • Falls das Argument eine Referenz auf eine leere Zelle ist, wird 1 zurückgegeben.

    Zusätzliche Informationen:

    • Calc gibt 8 zurück, um eine Formelzelle anzugegeben. Dieser Wert ist in der der Funktionsbeschreibung der ODF 1.2 nicht angegeben und wird in Microsoft EXCEL nicht verwendet. Dieser Wert gibt den Typ des Ergebnisses der Formel an.
    • Gemäß der Webseite von Microsoft unter Funktion TYP ist ein Rückgabewert von 128 in EXCEL möglich (für "compound data"). Dieser Wert ist in der Funktionsbeschreibung der ODF 1.2 nicht angegeben.
    • logische Werte / Wahrheitswerte sind in Calc als Zahlen verstanden, wobei sie in EXCEL ihre eigene Kategorie haben.
    • Als Ergebnis dieser unterschiedlichen Verhaltensweisen, sollte wohlüberlegt sein, ob eine Kompatibilität zu EXCEL wichtig ist.

    Beispiele:

    Formel Beschreibung Ergebnis
    =TYP(12,34) Wert ist eine Zahl. 1
    =TYP(B1)

    wobei Zelle B1 die Zahl 12,34 enthält.

    Die referenzierte Zelle enthält eine Zahl. 1
    =TYP("Gut gemacht ist besser als gut gesagt.") Wert ist ein Text. 2
    =TYP(B2)

    wobei die Zelle B2 den Text "Gut gemacht ist besser als gut gesagt" ohne Anführungszeichen enthält.

    Die referenzierte Zelle enthält Text. 2
    =TYP(B3)

    wobei die Zelle B3 den logischen Wert WAHR enthält.

    Die referenzierte Zelle enthält einen logischen Wert. 4
    =TYP(WAHR()) Der Wert entspricht einer Zahl. 1
    =TYP(FALSCH)

    wenn das Gebietsschema Deutsch gewählt ist.

    Der Wert entspricht einer Zahl. 1
    =TYP(B4)

    wobei die Zelle B4 die Formel =2 * PI() * POTENZ(3; 2) enthält.

    Die referenzierte Zelle enthält eine Formel. 8
    =TYP(B5)

    wobei die Zelle B5 die Formel =WURZEL(-4) enthält.

    Die referenzierte Zelle enthält einen Fehler. Ein "Invalid argument" error wurde gefunden (Fehler:502).

    16
    =TYP(B6)

    wobei die Zelle B6 entweder die Formel =NV() (#NV error) oder die Formel =1/0 (#DIV/0! error) enthält

    Die referenzierte Zelle enthält einen Fehler. 16
    =TYP({3; 5; 7}) Das Argument ist eine Aufzählung. 64
    { =TYP(D1:D2) }

    eingegeben in die Zellen B7:B8 als eine Aufzählung.

    Sowohl Zelle B7 als auch Zelle B8 zeigen jegliches Ergebnis aus Zellen D1 und D2 an. 64

    Ähnliche LibreOffice Funktionen:

    FEHLER.TYP

    FEHLERTYP

    ODF Standard:

    Kapitel 6.13.33, Teil 2.

    Betroffene (oder ähnliche) EXCEL-Funktionen:

    TYPE