Dokumentation/Calc Funktionen/SVERWEIS
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende
Funktionsname:
SVERWEIS
Kategorie:
Tabelle
Zusammenfassung:
Führt eine senkrechte Suche auf eine spezifizierte Datentabelle aus. Vergleicht ein gegebenes Suchkriterium mit den Einträgen in der ersten Spalte der Datentabelle und, wenn ein Treffer gefunden wird, wird der Inhalt der Zelle in der selben Zeile wie der Treffer aber in einer anderen Spalte zurückgegeben.
Der Suchprozess verwendet entweder Platzhalter oder reguläre Ausdrücke. Standardmässig ist die Suche nicht case-sensitiv. Eine case-sensitive Suche kann unter Verwendung eines regulären Ausdruckes durchgeführt werden.
Falls die Daten waagerecht organisiert sind und Vergleichsdaten in der ersten Zeile haben, wird WVERWEIS statt SVERWEIS verwendet.
Syntax:
SVERWEIS(Suchkriterium; Feld; Index[; sortierter Suchbereich])
Rückgabewerte:
Gibt den Inhalt einer Zelle zurück, die in der selben Zeile wie die Trefffer-Zelle liegt, aber in einer anderen Spalte. Die zurückgegebenen Daten können numerisch oder nicht numerisch sein.
Argumente:
Suchkriterium ist ein Text (in Anführungszeichen), eine Zahl oder eine Referenz auf eine Zelle mit einer dieser Typen. Suchkriterium wird mit den Inhalten der Zellen in der ersten Spalte des Arrays verglichen, um die interessante Zeile zu ermitteln.
Feld spezifiziert den Zellbereich, den die Datentabelle belegt. Dieser Bereich kann durch Eingabe des Zellbezuges der Zelle oben links, gefolgt von einem Doppelpunkt (:) und dem Zellbezug der Zelle unten rechts (z. Bsp. A1:E10) definiert werden. Feld kann auch durch Angabe des benannten Bereiches oder des Datenbankbereiches spezifiziert werden. Es ist auch möglich, das Feld als Aufzählung anzugeben.
Index ist eine positive Ganzzahl oder eine Referenz auf eine Zelle, die diese Zahl enthält Diese Zahl zeigt die Spalte, die die zurückzugebenden Daten enthält. Die erste Spalte hat den Index 1. Index kann nicht größer als die Anzahl der Spalten im Feld sein.
Der sortierte Suchbereich ist ein logischer Wert (WAHR oder FALSCH) oder eine Referenz auf eine Zelle mit dem Wert. Dieser Wert zeigt, ob die Daten in der ersten Spalte des Feldes korrekt sortiert sein sollten (wie im Abschnitt #Zusätzliche Informationen: beschrieben).
- * Falls der sortierte Suchbereich auf 0 oder FALSCH steht, dann sind die Daten in der erstgen Spalte des Feldes unsortiert und SVERWEIS sucht nach einem exakten Treffer.
- Falls der sortierte Suchbereich entweder fehlt oder auf WAHR gesetzt wird oder irgendeinem anderen numerischen Wert als 0 steht, dann sind die Daten in der ersten Spalte des Feldes sortiert und SVERWEIS kann sowohl nach exakten oder nach ungefähren (best-fit) Treffern suchen.
- If Sorted range lookup is either omitted, or set to WAHR or to any numeric value other than 0, then the data in the first column of Array is assumed to be ordered and SVERWEIS can produce "best-fit" (either exact or inexact) matches.
Die folgenden Fälle können auftreten:
- * Falls der Index nicht-numerisch ist, dann meldet SVERWEIS einen #WERT! Fehler.
- Falls der Index keine Ganzzahl ist, dann verkürzt sie SVERWEIS auf eine Ganzzahl.
- Falls der Index nach einer Verkürzung kleiner als 1 oder größer als die Anzahl an Spalten im Index ist, dann meldet SVERWEIS einen invalid argument error (Fehler:502).
- Falls der sortierte Suchbereich WAHR ist, aber die Zellen in der ersten Spalte nicht wie erwartet sortiert sind, ist das Ergebnis von SVERWEIS nicht vorhersehbar. In solchen Fällen kann es sein, dass kein Fehler gemeldet wird und das Ergebnis nicht offensichtlich bedeutungslos ist.
- Falls der sortierte Suchbereich FALSCH ist und kein exakter Treffer für das Suchkriterium gefunden wird, meldet SVERWEIS einen #NV (Wert nicht verfügbar) Fehler.
- Falls der sortierte Suchbereich WAHR ist und das Suchkriterium vor der ersten Zelle in der ersten Spalte der Datentabelle fündig würde, dann meldet SVERWEIS einen #NV (Wert nicht verfügbar) Fehler.
- If Index is a non-integer value, then SVERWEIS truncates it to an integer.
- If, after any truncation, Index is less than 1 or greater than the number of columns contained in Array, SVERWEIS reports an invalid argument error (Fehler:502).
- If Sorted range lookup is WAHR, but the cells in the first column of the data table are not ordered as expected, then the result returned by SVERWEIS is unpredictable. In such cases, it is possible that no error will be reported and it may not be obvious that the returned result is meaningless.
- If Sorted range lookup is FALSCH, and no exact match to Search criterion can be found in the data table, then SVERWEIS reports the #NV (value not available) error.
- If Sorted range lookup is WAHR, and the Search criterion argument would precede the first cell in the first column of the data table, then SVERWEIS reports the #NV (value not available) error.
Zusätzliche Informationen:
Spezifische Eigenheiten der Funktion SVERWEIS
- * Falls der sortierte Suchbereich FALSCH ist und die erste Spalte der Tabelle mehrere Zellen mit dem gleichen Inhalt hat, wird SVERWEIS nur den Eintrag ganz oben als Treffer liefern.
- * Falls der sortierte Suchbereich WAHR ist, muss die erste Spalte zuerst die Zahlen in aufsteigender Sortierung beinhalten und dann die Texte in alphabetischer Reihenfolge. Falls die erste Spalte nicht wie erwartet sortiert ist, ist das ergebnis unberechenbar. SVERWEIS ermittelt, wo in der ersten Spalte das Suchkriterium in der sortierten Reihe auftaucht.
- Falls es einen exakten Treffer des Suchkriteriums in der ersten Spalte gibt, wird diese Zeile genutzt, um den Rückgabewert zu ermitteln.
- Falls es keinen genauen Treffer zwischen Suchkriterium und den Einträgen der ersten Spalte gibt, wird die Zeile direkt oberhalb vom Suchkriterium genutzt.
- If there is an exact match between Search criterion and one of the entries in the first column, that row is used to determine the return value.
- If there is no exact match between Search criterion and any of the entries in the first column, the row immediately before where Search criterion would appear in the first column is used.
- * Falls ein regulärer Ausdruck im Bereich Platzhalter in Formeln im Dialog ▸ ▸ ▸ (oder ▸ ▸ ▸ unter macOS) ermöglicht wurde, dann wird SVERWEIS exakte Trefffer für den regulären Ausdruck als Suchkriterium finden. Das macht nur Sinn wenn der sortierte Suchbereich FALSCH ist.
- * Falls Platzhalter im Bereich Platzhalter in Formeln im Dialog ▸ ▸ ▸ (oder ▸ ▸ ▸ unter macOS) ermöglicht wurden, dann findet SVERWEIS exakte Treffer für das Suchktiterium als regulärer Ausdruck. Das macht nur Sinn wenn der sortierte Suchbereich FALSCH ist.
- * Falls die Option Suchkriterien = und <> müssen auf ganze Zellen zutreffen in den Allgemeinen Berechnungen des Dialoges ▸ ▸ ▸ (oder ▸ ▸ ▸ unter macOS) angeklickt ist, dann muss das Suchkriterium mit dem ganzen Text in einer Zelle übereinstimmen. Ansonsten kann es auch nur mit einem Teil des Textes übereinstimmen.
- * Die Option Groß- und Kleinschreibung im Bereich Allgemeine Berechnungen des Dialoges ▸ ▸ ▸ (oder ▸ ▸ ▸ unter macOS) hat keine Auswirkung auf die Ausführung von SVERWEIS. Standardmäßig ist SVERWEIS nicht case-sensitiv, es sei denn eine case-sensitive Suche wird durch einen spezifischen regulären Ausdruck angestossen.
Allgemeine Informationen über die regulären Ausdrücke in Calc
 |
Anmerkung:
|
- Ein regulärer Ausdruck ist eine Zeichenkette die ein Textmuster beschreibt. Genauere allgemeine Hintergrundinformationen finden sich in der Wiki Regulärer Ausdruck
- Reguläre Ausdrücke sind weit verbreitet. Dabei gibt es viele Prozessoren für reguläre Ausdrücke. Calc nutzt den open source Regular Expressions package from the International Components for Unicode (ICU). Siehe bitte unter deren Dokumentation zu den regulären Ausdrücken für weitergehende Informationen inklusive der volständigen Beschreibung zur Syntax der ICU Regular Expressions.
- Zusätzlich stellt die LibreOffice Hilfe eine umfangreiche Liste der regulären Ausdrücke zur Verfügung.
- Calcs Generator für reguläre Ausdrücke unterstützt zahlreiche Erfassungs Möglichkeiten, welche es Untergruppen in einem Bereich erlauben innerhalb eines Treffers identifiziert zu werden und in einem Text ersetzt werden können. Runde Klammern werden genutzt um Komponenten eines regulären Ausdruckes zu gruppieren und eine nummerierte Treffer-Liste zu erzeugen. Um eine solche Treffer-Liste in einen Text einzufügen, verwenden Sie bitte das Kürzel "$n", wobei n die Zahl der Treffer-Liste ist.
Allgemeine Informationen über die Platzhalter in Calc
Platzhalter sind spezielle Zeichen für Suchtexte in Argumenten für einige Funktionen in Calc; sie können auch im Suchdialog verwendet werden. Der Gebrauch von Platzhaltern ermöglicht fortgeschrittenere Suchparamter bei einer einfachen Textsuche.
Calc unterstützt entweder Platzhalter oder reguläre Ausdrücke abhängig von den Einstellungen der aktuellen Applikation. Standardmäßig werden Platzhalter statt regulärer Ausdrücke unterstützt.
Um sicherzustellen, dass Platzhalter unterstützt werden, rufen Sie ▸ ▸ ▸ auf. Überprüfen Sie hier, ob die Einstellung Platzhalter in Formeln ermöglichen ausgewählt ist. Beachten Sie auch, dass reguläre Ausdrücke durch Auswählen von Reguläre Ausdrücke in Formeln ermöglichen unterstüzt werden können. Genauso können Sie weder Platzhalter noch reguläre Ausdrücke unterstützen lassen.
Die folgende Tabelle zeigt die Platzhalter, die Calc unterstützt.
| Platzhalter | Beschreibung |
|---|---|
| ? (Fragezeichen) | Vertritt ein einzelnes Zeichen. Zum Beispiel kann der Suchtext "b?g" "bag" oder "beg" heißen, aber nicht "boog" oder "mug". Beachte, dass es auch nicht "bg" heißen kann, da "?" genau ein Zeichen sein muss. Der Platzhalter "?" vertritt kein fehlendes Zeichen. |
| * (Asterisk) | Vertritt eine Reihe von Zeichen inklusive dem Leer-Text. Zum Beispiel vertritt der Text "*cast" "cast", "forecast" und "outcast", aber nicht "forecaster" unter Verwendung der Standardeinstellungen von Calc. Falls die Einstellung Suchkriterien = und <> müssen auf ganze Zellen zutreffen in ▸ ▸ ▸ ausgeblendet ist, dann wird "forecaster" auch durch *cast vertreten. |
| ~ (Tilde) | Unterdrückt die Sonderbehandlung des Fragezeichens Asterisken oder der Tilde, welche direkt nach der Tilde kommen. Zum Beispiel, stellt der Suchstring "why~?" nur "why?" und nicht "whys" oder "why~s" dar. |
Platzhalter sind nicht case sensitiv, also "A?" heißt sowohl "A1" also auch "a1".
Diese Platzhalter werden sowohl in Calc als auch in Microsoft EXCEL unterstützt. Wenn also Kompatibilität zwischen den beiden Anwendungen erforderlich ist, arbeiten Sie mit Platzhaltern anstatt mit regulären Ausdrücken. Wenn dagegen Kompatibilität nicht notwendig ist, arbeiten Sie stattdessen mit regulären Ausdrücken für mächtigere Möglichkeiten.
Beispiele:
Die folgende Tabelle ist ein echtes Beispiel einer unsortierten Tabelle mit Daten aus dem Periodensystem der chemischen Elemente.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Element | Symbol | Kernladungszahl | Relative Atommasse |
| 2 | Wasserstoff | H | 1 | 1,008 |
| 3 | Helium | He | 2 | 4,003 |
| 4 | Lithium | Li | 3 | 6,94 |
| 5 | Beryllium | Be | 4 | 9,012 |
| 6 | Bor | B | 5 | 10,81 |
| 7 | Kohlenstoff | C | 6 | 12,011 |
| 8 | Stickstoff | N | 7 | 14,007 |
| 9 | Sauerstoff | O | 8 | 15,999 |
| 10 | Flour | F | 9 | 18,998 |
| 11 | Neon | Ne | 10 | 20,18 |
Die folgenden Beispiele nutzen die obige Tabelle. In den meisten Fällen steht der sortierte Suchbereich auf 0 (FALSCH), so dass SVERWEIS nach einer exakten Übereinstimmung in der unsortierten Tabelle sucht.
| Formel | Beschreibung | Ergebnis |
|---|---|---|
| =SVERWEIS("Helium"; $A$2:$D$11; 2; 0) |
Die Funktion findet den Text "Helium" in der ersten Spalte der Datentabelle (Zelle A3) und gibt die Daten aus der Zelle im Schnittpunkt dieser Zeile und der zweiten Spalte der Tabelle (Zelle B3) zurück. Das Symbol für Helium wird zurückgegeben. |
He |
| =SVERWEIS("Kohlenstoff"; $A$2:$D$11; 3; 0) |
Die Funktion findet den Text "Kohlenstoff" in der ersten Spalte der Datentabelle (Zelle A7) und gibt die Daten aus der Zelle im Schnittpunkt dieser Zeile und der dritten Spalte der Tabelle (Zelle C7) zurück. Die Kernladungszahl für Kohlenstoff wird zurückgegeben. |
6 |
| =SVERWEIS("Sauerstoff"; $A$2:$D$11; 4,6; 0) |
Die Funktion findet den Text "Sauerstoff" in der ersten Spalte der Datentabelle (Zelle A9) und gibt die Daten aus der Zelle im Schnittpunkt dieser Zeile und der vierten Spalte der Tabelle (Zelle D9) zurück - der Index von 4,6 wird verkürzt auf 4. Die relative Atommasse von Sauerstoff wird zurückgegeben. |
15,999 |
| =SVERWEIS("Neon"; $A$2:$D$11; 2; WAHR()) |
Dieses Beispiel zeigt die Verwirrung, die auftritt, wenn der sortierte Suchbereich (standardmässig) auf WAHR gesetzt ist und die Tabelle nicht in der erwarteten Reihenfolge sortiert ist. Die Formel gibt den (unberechenbaren) Text "C" statt dem erwarteten "Ne" zurück. |
C |
|
=SVERWEIS("^bo.*"; $A$2:$D$11; 4; 0)
|
Die Funktion findet den Text "^bo*" in der ersten Zeile der Datentabelle (Zelle A6) und gibt die Daten aus der Zelle im Schnittpunkt dieser Zeile und der vierten Spalte der Tabelle (Zelle D6) zurück. Die relative Atommasse für Bor wird zurückgegeben. |
10,81 |
|
=SVERWEIS("sti*"; $A$2:$D$11; 4; 0)
|
Die Funktion findet den Text "sti*" in der ersten Spalte der Datentabelle (Zelle A8) und gibt die Daten aus der Zelle im Schnittpunkt dieser Zeile und der vierten Zeile der Tabelle (Zelle D8) zurück. Die relative Atommasse für Stickstoff wird zurückgegeben. |
14,007 |
Die folgende Tabelle zeigt die Verkaufsdaten für eine kleine Firma. Vier Zeilen (benannt mit 1 bis 4) zeigen die gesamten Verkäufe in jedem Quartal des Jahres und die Namen der Top Verkäufer des Quartals. Vier Zeilen (benannt mit E_reg, N_reg, S_reg und W_reg) zeigen die gesamten Verkäufe in jedem Gebiet in diesem Jahr und die Namen der Top Verkäufer in diesem Gebiet in diesem Jahr. Die Daten in der ersten Spalte sind in der beschriebenen Reihenfolge sortiert und spezifizieren in den folgenden Beispielen keinen Wert für den soritierten Suchbereich, wenn SVERWEIS den Standardwert WAHR verwendet.
| A | B | C | |
|---|---|---|---|
| 1 | Kategorie | Endsumme | Top Verkäufer |
| 2 | 1 | $27.094 | Samuel |
| 3 | 2 | $96.516 | Aaron |
| 4 | 3 | $82.485 | Pippa |
| 5 | 4 | $48.487 | Ollie |
| 6 | E_reg | $99.908 | Lillian |
| 7 | N_reg | $83.535 | George |
| 8 | S_reg | $46.553 | Zara |
| 9 | W_reg | $24.586 | Kristina |
| Formel | Beschreibung | Ergebnis |
|---|---|---|
| =SVERWEIS(0; $A$2:$C$9; 2) |
Die Funktion sucht die Zahl 0 in der ersten Spalte in der Datentabelle, aber da 0 kleiner als die erste Zahl (1) in der Spalte ist, meldet die Formel einen #NV Fehler. |
#NV |
| =SVERWEIS(2,5; $A$2:$C$9; 2) |
Die Funktion sucht die Zahl 2,5 in der ersten Spalte der Datentabelle. Da 2,5 größer als 2 und kleiner als 3 ist, nimmt SVERWEIS den Wert 2 (aus der Zeile 3). Die Formel gibt die Daten aus der Zelle im Schnittpunkt dieser Zeile und der zweiten Spalte der Tabelle (Zelle B3) zurück. Die gesamten Verkäufe für das zweite Quartal werden zurückgegeben. |
96516 |
| =SVERWEIS(3; $A$2:$C$9; 2) |
Die Funktion sucht die Zahl 3 in der ersten Spalte der Datentabelle (Zelle A4) und gibt die Daten im Schnittpunkt dieser Zeile und der zweiten Spalte der Tabelle (Zelle B4).
Die gesamten Verkäufe aus dem dritten Quartal werden zurückgegeben.
Die Formel |
82485 |
| =SVERWEIS(123; $A$2:$C$9; 2) |
Die Funktion sucht die Zahl 123 in der ersten Spalte der Datentabelle. Da 123 größer als die (anderen) Zahlen ist, verwendet SVERWEIS Zeile 5. Die gesamten Verkäufe im Schnittpunkt dieser Zeile und der zweiten Spalte der Tabelle (Zelle B5) werden zurückgegeben. Die gesamten Verkäufe aus dem vierten Quartal werden zurückgegeben. |
48487 |
| =SVERWEIS("C_reg"; $A$2:$C$9; 3) |
Die Funktion sucht den Text "C_reg" in der ersten Spalte in der Datentabelle, aber da "C_reg" alphabetisch vor dem ersten Eintrag ("E_reg") in der Spalte kommt, meldet die Formel einen #NV Fehler. |
#NV |
| =SVERWEIS("F_reg"; $A$2:$C$9; 3) |
Die Funktion sucht den Text "F_reg" in der ersten Spalte der Datentabelle. Da "F_reg" alphabetisch nach "E_reg" aber vor "N_reg" kommt, verwendet SVERWEIS den vorherigen Wert aus Zeile 6. Die Daten im Schnittpunkt dieser Zeile und der dritten Spalte der Tabelle (Zelle C6) werden zurückgegeben. Der Top-Verkäufer aus dem Gebiet "E_reg" wird zurückgegeben. |
Lillian |
| =SVERWEIS("S_reg"; $A$2:$C$9; 3) |
Die Funktion findet den Text "S_reg" in der ersten Spalte der Datentabelle (Zelle A8) und gibt die Daten aus der Zelle im Schnittpunkt dieser Zeile und der dritten Spalte der Tabelle (Zelle C8) zurück. Der Top-Verkäufer aus dem Gebiet "S_reg" wird zurückgegeben. |
Zara |
| =SVERWEIS("Zagreb"; $A$2:$C$9; 3) |
Die Funktion sucht den Text "Zagreb" in der ersten Spalte der Datentabelle. Da "Zagreb" alphabetisch nach den aktuellen Texten kommt, verwendet SVERWEIS den untersten Wert der Liste (Zeile 9). Die gesamten Verkäufe im Schnittpunkt dieser Spalte und der dritten Spalte der Tabelle (Zelle C9) werden zurückgegeben. Der Top-Verkäufer aus dem Gebiet "W_reg" wird zurückgegeben. |
Kristina |
Das letzte Beispiel zeigt, dass das Feld auch eine Aufzählung sein kann. In diesem Fall ist das Komma als Spaltentrenner und der Strichpunkt als Zeilentrenner verwendet. Diese Feldtrenner können über den Abschnitt Trennzeichen im Dialog ▸ ▸ ▸ (oder ▸ ▸ ▸ unter macOS) geändert werden.
| Formel | Beschreibung | Ergebnis |
|---|---|---|
| =SVERWEIS(5; {1, "Montag"; 2, "Dienstag"; 3, "Mittwoch"; 4, "Donnerstag"; 5, "Freitag"; 6, "Samstag"; 7, "Sonntag"}; 2) |
Die Funktion findet die Zahl 5 in der ersten Spalte des Feldes und gibt die Daten im Schnittpunkt dieser Zeile und der zweiten Spalte des Feldes zurück. |
Freitag |
Ähnliche LibreOffice Funktionen:
ODF Standard:
Betroffene (oder ähnliche) EXCEL-Funktionen:
VLOOKUP