Dokumentation/Calc Funktionen/AMORDEGRK

This page is a translated version of the page Documentation/Calc Functions/AMORDEGRC and the translation is 100% complete.

TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende

Other languages:

Calc Funktionen Start | Liste der Funktionen | Abkürzungen

Funktionsname:

AMORDEGRK

Kategorie:

Finanzmathematik

Zusammenfassung:

Berechnet den Wertverlust (oder Amortisation) eines Anlageguts während einer Anlageperiode bei deggressiver Abschreibung. Diese Methode schreibt anfänglich mit einer höheren Rate ab und senkt die Rate über die Nutzungsdauer des Anlagegutes. Falls das Anlagegut innerhalb der Buchungsperiode angeschafft wird, wird die Abschreibung für diese Periode anteilig vorgenommen.

AMORDEGRK ist für Nutzer des französischen Buchungssystems ausgelegt.

Syntax:

AMORDEGRK(Anschaffungskosten, Anschaffungsdatum; Erste Periode; Restwert; Nutzungsdauer; Abschreibungssatz[; Basis])

Rückgabewerte:

Gibt den Wertverlust des Anlagegutes während der angegebenen Laufzeit, ausgedrückt in der gleichen Währung wie die Anschaffungskosten und der Restwert, als nicht-negative Dezimalzahl zurück.

Argumente:

Anschaffungskosten ist eine positive Dezimalzahl oder eine Referenz auf eine Zelle mit der Zahl. Diese Zahl sind die Anschaffungskosten bzw. der Wert des Anlagegutes vor der Abschreibung.

Anschaffungsdatum ist ein Datum oder eine Referenz auf eine Zelle, die das Datum enthält. An diesem Datum startet die Abschreibung. Für Sachanlagen ist das üblicherweise das Kaufdatum.

Erste Periode ist ein Datum oder eine Referenz auf eine Zelle, die das Datum enthält. An diesem Datum endet die erste Bilanzierungsperiode für die die Abschreibung berechnet wird.

Restwert ist eine positive Dezimalzahl oder eine Referenz auf eine Zelle mit der Zahl. Diese Zahl ist der Restwert des Anlagegutes am Ende der Abschreibung. Der Restwert muss in der gleichen Währung wie die Anschaffungskosten sein.

Nutzungsdauer ist eine nicht-negative Ganzzahl oder eine Referenz auf eine Zelle, welche die Ganzzahl enthält. Diese Zahl bezeichnet die Anlagedauer zu dem der Abschreibungsbetrag errechnet wird. Der Wert 0 zeigt an, dass die Nutzungsdauer am Datum der Ersten Periode endet. Folgende Perioden werden mit 1, 2, 3, usw. nummeriert.

Abschreibungssatz ist eine positive Dezimalzahl (ausgedrückt als Prozentsatz wie z. Bsp. 2,5 % oder als Dezimalbruch wie z. Bsp. 0,025) oder eine Referenz auf die Zelle welche den Abschreibungssatz des Anlagegutes enthält.

Basis ist eine Ganzzahl im Bereich 0 bis 4, welche anzeigt, wie das Jahr berechnet wird. Oder eine Referenz auf eine Zelle, die diese Ganzzahl enthält, wird verwendet. Für mehr Hintergrund Informationen, siehe Wiki unter Zinsberechnungsmethode.

Basis	Berechnung
0 oder fehlt	US-Methode (NASD), 12 Monate je 30 Tage
1	Exakte Anzahl der Tage im Monat, exakte Anzahl der Tage im Jahr.
2	Exakte Anzahl der Tage im Monat, Das Jahr hat 360 Tage.
3	Exakte Anzahl der Tage im Monat, Jahr hat 365 Tage.
4	Euro-Methode, 12 Monate zu je 30 Tagen.

Falls Anschaffungsdatum oder Erste Periode kein gültiges Datum enthält, gibt AMORDEGRK einen #WERT!-Fehler zurück
Falls Anschaffungskosten, Restwert, Nutzungsdauer oder Abschreibungssatz nicht-numerisch sind, gibt AMORDEGRK einen #WERT!-Fehler zurück
Falls Basis nicht numerisch ist, gibt AMORDEGRK einen invalid argument error (Fehler:502) zurück.
Falls das Anschaffungsdatum nach der Ersten Periode liegt, gibt AMORDEGRK einen invalid argument error (Fehler:502) zurück.
Falls entweder der Anschaffungskosten oder der Abschreibungssatz kleiner oder gleich 0 ist, gibt AMORDEGRK einen invalid argument error (Fehler:502) zurück.
Falls entweder der Restwert kleiner als 0 oder größer als die Anschaffungskosten ist, gibt AMORDEGRK einen invalid argument error (Fehler:502) zurück.
Falls entweder die Nutzungsdauer oder Basis kein ganzzahliger Wert ist, verkürzt ihn AMORDEGRK auf einen ganzzahligen Wert.
Falls Nutzungsdauer kleiner 0 ist, gibt AMORDEGRK einen invalid argument error (Fehler:502) zurück.
Falls nach einer eventuellen Verkürzung Basis nicht 0, 1, 2, 3 oder 4 ist, gibt AMORDEGRK einen invalid argument error (Fehler:502) zurück.

Zusätzliche Informationen:

AMORDEGRK nutzt einen Abschreibungssatz (f) welcher von der Nutzungsdauer ([math]\displaystyle{ t~=~\frac{1}{Abschreibungssatz} }[/math]) des Anlagegutes abhängt. Der Zweck dieses Faktors ist es, den Satz der Abschreibung für Anlagegüter mit längerer Lebensdauer zu erhöhen. Der Abschreibungssatz ist folgendermassen definiert:

Abschreibungssätze aus AMORDEGRK
Nutzungsdauer des Anlagegutes (t)	Abschreibungssatz (f)
t < 3	1
3 <= t < 5	1,5
5 <= t <=6	2
t > 6	2,5

Falls Nutzungsdauer = 0 ist, wird die Abschreibung anteilig berechnet. Für diese Periode lautet die Formel für AMORDEGRK:

[math]\displaystyle{ \operatorname{AMORDEGRK_{0}}~=~f*Anschaffungskosten~*~Abschreibungssatz~*~\operatorname{BRTEILJAHRE}(Anschaffungsdatum; Erste~Periode; Basis) }[/math]

Falls das Anschaffungsdatum gleich der Ersten Periode ist, dann gilt: [math]\displaystyle{ \operatorname{AMORDEGRK_{0}}~=~0 }[/math]

Für folgende Perioden berechnet AMORDEGRK die Abschreibung basierend auf den Kosten oder dem Wert des Anlagegutes vor der Abschreibung minus der gesamten Abschreibung in den vorhergehenden Perioden.
Falls Nutzungsdauer = 1 berechnet sich der Wertverlust wie folgt:

[math]\displaystyle{ \operatorname{AMORDEGRK_{1}}~=~f*(Anschaffungskosten-AMORDEGRK_{0})~*~Abschreibungssatz }[/math]

Falls Nutzungsdauer = 1 berechnet sich der Wertverlust wie folgt:

[math]\displaystyle{ \operatorname{AMORDEGRK_{2}}~=~f*(Anschaffungskosten-AMORDEGRK_{0}-AMORDEGRK_{1})~*~Abschreibungssatz }[/math]

Dieser Vorgang geht über die folgenden Perioden weiter bis zum Ende des Abschreibungsvorganges. Die gesamte Abschreibungssumme über alle Perioden wird nicht größer als der Wert des Anlagegutes vor der Abschreibung sein, der im Argument Anschaffungskosten angegeben ist.
Es gibt einige Unterschiede im Verhalten von AMORDEGRK in Calc und in EXCEL.

EXCEL unterstützt nicht die Option 2 für die Basis (Exakte Anzahl der Tage im Monat, das Jahr hat 360 Tage.).
Calc und EXCEL verhalten sich unterschiedlich, wenn das Anschaffungsdatum sich mit dem Ende einer Buchungsperiode deckt. Calc betrachtet die erste Periode 0 als Länge 0 und gibt daher 0 Abschreibung zurück. EXCEL betrachtet die erste Periode 0 als die erste volle Periode.
Da das Argument Nutzungsdauer erhöht ist, wird die letzte Periode mit einer Abschreibung ungleich 0 in Calc und EXCEL unterschiedlich sein.
Es kann kleinere Rundungsdifferenzen zwischen Calc und EXCEL geben.

Diese Differenzen können die Kompatibilität beschränken, wenn eine Calc-Tabelle, die AMORDEGRK-Aufrufe enthält, später in EXCEL geöffnet werden.

Für weitergehende Hintergrundinformationen über Abschreibungen und Amortisationen siehe Wiki unter Abschreibung und Amortisation

Beispiele:

Einfaches Beispiel mit mehrfachen Aufrufen von AMORDEGRK

Die folgende Tabelle zeigt das Verhalten der Funktion AMORDEGRK.

	A	B	D	E
1	Kosten	1200	Periode	Abschreibung
2	Anschaffungsdatum	2022-07-01	0	225
3	Erste Periode	2022-12-31	1	366
4	Restwert	200	2	228
5	Periode	-	3	143
6	Abschreibungssatz	15 %	4	119
7	Basis	0	5	0
8			6	0
9			7	0
10			8	0
11
12			Endsumme	1081

Die Daten in den Zellen B1:B4 und B6:B7 enthalten Werte für die meisten Argumente von AMORDEGRK. Die Funktion wird neun mal aufgerufen, einmal für jeden Wert der Periode aus den Zellen D2:D10. Zelle E2 enthält die Formel=AMORDEGRK($B$1; $B$2; $B$3; $B$4; $D2; $B$6; $B$7). Zelle E3 enthält die Formel =AMORDEGRK($B$1; $B$2; $B$3; $B$4; $D3, $B$6, $B$7) und so weiter. Die Rückgabewerte von AMORDEGRK sind in den Zellen E2:E10. Die folgenden Besonderheiten können in den Ergebnissen abgelesen werden.

Für diese Beispieldaten wird die Abschreibung für eine Teil-Periode (Periode 0) und vier volle Buchungsperioden (Perioden 1 bis 4) berechnet.
Periode 0. Da das Anlagegut mitten in der Buchungsperiode angeschafft wird, wird die Abschreibung für Periode 0 anteilig aus [math]\displaystyle{ 1200 \times 0.5 \times 2.5 \times 0.15~=~225 }[/math] berechnet.
Periode 1. Für diese volle Buchungsperiode wird die Abschreibung aus [math]\displaystyle{ (1200-225) \times 2.5 \times 0.15~=~365.625 }[/math] berechnet und AMORDEGRK rundet diesen Wert auf 366.
Die Abschreibungswerte für die Perioden 2 und 3 sind auf gleiche Weise wie in Periode 1 berechnet.
Die komplette Abschreibung aus den Perioden 0 bis 3 beträgt 962. Anschaffungskosten - Restwert - 962 ist größer als 0, da AMORDEGRK voraussetzt, dass es eine Abschlussrate in Periode 4 gibt. Anstelle des gleichen Algorithmuses wie in Schritt 1 bis 3 ist der Wert für Periode 4 die halbe Differenz zwischen den Original Anschaffungskosten (1.200 in diesem Fall) minus der kompletten Abschreibung in den vorhergehenden Perioden (962 in diesem Fall), also [math]\displaystyle{ 0.5 \times 238 }[/math] oder [math]\displaystyle{ 119 }[/math].
Für Periode 5 oder später gibt AMORDEGRK 0 zurück.

Zusätzliche Beispiele

Formel	Beschreibung	Ergebnis
=AMORDEGRK(1500; "2001-04-01"; "2001-06-15"; 454; 0; 0,19; 2)	Hier rechnet die Funktion die anteilige Abschreibung für Periode 0, welche eine kurze Periode von ca. 2,5 Monaten ist.	119
=AMORDEGRK(1500; "2001-04-01"; "2001-06-15"; 454; 0; 0,19)	Hier rechnet die Funktion wieder die anteilige Abschreibung für Periode 0, welche eine kurze Periode von ca. 2,5 Monaten ist. Allerdings wird die Basis in diesem Fall nicht angegeben und daher wird der Standardwert 0 angewendet. Daher gibt es ein zum vorigen Beispiel leicht unterschiedliches Ergebnis.	117
=AMORDEGRK(1500; "2001-04-01"; "2001-06-15"; 454; 1; 0,19; 2)	Hier rechnet die Funktion die Abschreibungssumme für eine volle Buchhaltungsperiode (Periode 1).	525
=AMORDEGRK(2000; DATUM(2020; 2; 1); DATUM(2020; 12; 31); 10; 4; 10%; 0)	Hier rechnet die Funktion die Abschreibungssumme für eine volle Buchhaltungsperiode (Periode 4). Beachten Sie, dass es oft gute Praxis ist, die Funktion DATUM anstatt formatierte Datums-Werte zu verwenden.	163

ODF Standard:

Nichts

Betroffene (oder ähnliche) EXCEL-Funktionen:

AMORDEGRC