Documentazione/Funzioni di Calc/AMMORT.DEGR
TDF LibreOffice Document Liberation Project Blog comunitari Weblate Nextcloud Redmine Ask LibreOffice Donazione
Nome funzione:
AMMORT.DEGR
Categoria:
Analisi finanziaria
Riepilogo:
Calcola il deprezzamento (o ammortamento) di un bene durante un periodo specifico utilizzando un modello di ammortamento degressivo. Questo metodo viene ammortizzato con un'aliquota più elevata all'inizio e l'aliquota diminuisce durante la vita utile del bene. Se il bene viene acquisito nel corso di un periodo contabile, l'ammortamento per tale periodo viene calcolato su base proporzionale.
AMMORT.DEGR è destinato agli utenti del sistema contabile francese.
Sintassi:
AMMORT.DEGR(Costo; Data di acquisto; Primo periodo; Cespite; Periodo; Tasso[; Base])
Restituisce:
Restituisce un numero reale non negativo che rappresenta l'ammortamento del cespite durante il periodo specificato, espresso nelle stesse unità valutarie del costo del cespite e dei valori di recupero.
Argomenti:
Costo è un numero reale positivo, o un riferimento a una cella contenente quel numero, che rappresenta il costo o il valore del bene prima dell'ammortamento.
Data di acquisto è una data, o un riferimento a una cella contenente tale data, che è la data di inizio dell'ammortamento. Per un bene materiale, questa è solitamente la data di acquisizione.
Primo periodo è una data, o un riferimento a una cella contenente tale data, che è la data di fine del primo periodo contabile durante il quale viene calcolato l'ammortamento.
Cespite è un numero reale positivo, oppure un riferimento ad una cella contenente quel numero, che rappresenta il valore residuo del bene al termine della sua vita ammortizzata. Cespite deve essere espresso nella stessa unità di valuta di Costo.
Periodo è un numero intero non negativo o un riferimento a una cella contenente tale numero intero, che specifica il periodo contabile per il quale viene restituito il valore di ammortamento. Il valore 0 indica il periodo che termina nella data indicata da Primo periodo. I periodi contabili successivi sono numerati 1, 2, 3 e così via.
Tasso è un numero reale positivo (espresso come percentuale, come 2,5%, o una frazione decimale, come 0,025), o un riferimento a una cella contenente quel numero, che è il tasso annuale al quale il valore del bene viene ammortizzato.
Base è un numero intero da 0 a 4 o un riferimento a una cella contenente quell'intero, che viene scelto da un elenco di opzioni e indica come calcolare l'anno. Per ulteriori informazioni, visitate la pagina [1] di Wikipedia.
| Base | Calcolo |
|---|---|
| 0 o omesso | Metodo USA (NASD), 12 mesi di 30 giorni ciascuno |
| 1 | Numero esatto di giorni nei mesi, numero esatto di giorni nell'anno. |
| 2 | Il numero esatto di giorni nel mese, l'anno ha 360 giorni. |
| 3 | Il numero esatto di giorni nel mese, l'anno ha 365 giorni. |
| 4 | Metodo europeo, 12 mesi da 30 giorni ciascuno. |
- Se Data di acquisto o Primo periodo non è una data valida, allora AMMORT.DEGR restituisce un errore #VALORE!.
- Se uno dei valori Costo, Recupero, Periodo o Tasso non è numerico, allora AMMORT.DEGR segnala un errore #VALORE!.
- Se Base non è numerico, AMMORT.DEGR segnala un errore di argomento non valido (Err:502).
- Se Data di acquisto è successiva a Primo periodo, AMMORT.DEGR segnala un errore di argomento non valido (Err:502).
- Se Costo o Tasso è inferiore o uguale a 0, AMMORT.DEGR segnala un errore di argomento non valido (Err:502).
- Se Recupero è inferiore a 0 o maggiore di Costo, allora AMMORT.DEGR segnala un errore di argomento non valido (Err:502).
- Se Periodo o Base è un valore non intero, AMMORT.DEGR lo tronca in un valore intero.
- Se Periodo è inferiore a 0, AMMORT.DEGR segnala un errore di argomento non valido (Err:502).
- Se (dopo qualsiasi troncamento) Base non è uguale a 0, 1, 2, 3 o 4, AMMORT.DEGR segnala un errore di argomento non valido (Err:502).
Dettagli aggiuntivi:
- AMMORT.DEGR utilizza un fattore di deprezzamento (f) che dipende dalla durata ([math]\displaystyle{ t~=~\frac{1}{Rate} }[/math]) del bene. Lo scopo di questo fattore è quello di aumentare il tasso di ammortamento per i beni con una vita più lunga ed è definito come segue:
| Durata del bene (t) | Fattore di ammortamento (f) |
|---|---|
| t < 3 | 1 |
| 3 <= t < 5 | 1,5 |
| 5 <= t <=6 | 2 |
| t > 6 | 2,5 |
- Se Periodo = 0, l'ammortamento viene calcolato proporzionalmente. Per questo periodo la formula per AMMORT.DEGR è:
- [math]\displaystyle{ \operatorname{AMMORT.DEGR_{0}}~=~f*Costo~*~Rata~*~\operatorname{FRAZIONEANNO}(Data~Acquisto; Primo~Periodo; Base) }[/math]
- Se Data Acquisto è uguale a Primo Periodo, allora [math]\displaystyle{ \operatorname{AMMORT.DEGR_{0}}~=~0 }[/math]
- Per i periodi successivi, AMMORT.DEGR calcola l'ammortamento in base al costo o al valore del bene prima dell'ammortamento meno l'ammortamento totale nei periodi precedenti.
- Se Periodo = 1, l'ammortamento viene calcolato come segue.
- [math]\displaystyle{ \operatorname{AMMORT.DEGR_{1}}~=~f*(Costo-AMMORT.DEGR_{0})~*~Rata }[/math]
- Se Periodo = 2, l'ammortamento viene calcolato come segue.
- [math]\displaystyle{ \operatorname{AMMORT.DEGR_{2}}~=~f*(Costo-AMMORT.DEGR_{0}-AMMORT.DEGR_{1})~*~Rata }[/math]
- Tale elaborazione prosegue per periodi successivi fino al termine dell'ammortamento. L'ammortamento totale su tutti i periodi non sarà maggiore del valore del bene prima di qualsiasi ammortamento, indicato nell'argomento Costo.
- Esistono alcune differenze tra il comportamento di AMMORT.DEGR in Calc e Microsoft Excel.
- Excel non supporta l'opzione 2 per l'argomento Base (numero effettivo di giorni nel mese, 360 giorni nell'anno).
- Calc ed Excel si comportano diversamente quando la data di acquisto coincide con la fine di un periodo contabile. Calc considera il periodo iniziale 0 come di lunghezza zero e pertanto restituisce un ammortamento pari a zero. Excel considera il periodo iniziale 0 come il primo periodo completo.
- Aumentando l'argomento Periodo, l'ultimo periodo che restituisce un valore di ammortamento diverso da zero potrebbe restituire valori diversi per Calc ed Excel.
- Potrebbero esserci piccole differenze di arrotondamento tra i valori restituiti da Excel e Calc.
- Queste differenze potrebbero limitare l'interoperabilità quando si dispone di un foglio di calcolo Calc contenente chiamate AMMORT.DEGR che viene successivamente aperto in Excel.
- Per ulteriori informazioni di base su deprezzamento e ammortamento, visitare Depreciation e Amortization (business) di Wikipedia. pagine.
Esempi:
Esempio semplice con più chiamate a AMMORT.DEGR
La tabella seguente illustra il comportamento della funzione AMMORT.DEGR.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Costo | 1200 | Periodo | Ammortamento | |
| 2 | Data di acquisto | 2022-07-01 | 0 | 225 | |
| 3 | Primo periodo | 2022-12-31 | 1 | 366 | |
| 4 | Cespite | 200 | 2 | 228 | |
| 5 | Periodo | - | 3 | 143 | |
| 6 | Tasso | 15% | 4 | 119 | |
| 7 | Base | 0 | 5 | 0 | |
| 8 | 6 | 0 | |||
| 9 | 7 | 0 | |||
| 10 | 8 | 0 | |||
| 11 | |||||
| 12 | Totale | 1081 |
I dati nelle celle B1:B4 e B6:B7 contengono i valori per la maggior parte degli argomenti passati nelle chiamate alla funzione AMMORT.DEGR. La funzione viene chiamata nove volte, una per ciascun valore dell'argomento Periodo fornito nelle celle da D2 a D10. La cella E2 contiene la formula =AMMORT.DEGR($B$1; $B$2; $B$3; $B$4; $D2; $B$6; $B$7) </codice>; la cella E3 contiene la formula =AMMORT.DEGR($B$1; $B$2; $B$3; $B$4; $D3, $B$6, $B$7) </codice>; e così via. I valori restituiti dalle chiamate AMMORT.DEGR vengono visualizzati nelle celle E2:E10 e la cella E12 contiene la somma di tutti i valori nelle celle E2:E10. In questi risultati è possibile osservare le seguenti caratteristiche:
- Per questi dati di esempio, l'ammortamento viene calcolato durante un periodo parziale (periodo 0) e quattro periodi contabili completi (periodi da 1 a 4).
- Periodo 0. Poiché il bene è stato acquisito a metà del periodo contabile, l'ammortamento per il periodo 0 viene calcolato su base proporzionale come [math]\displaystyle{ 1200 \times 0,5 \times 2,5 \times 0,15~=~225 }[/math].
- Periodo 1. Per questo periodo contabile completo, l'ammortamento viene calcolato come [math]\displaystyle{ (1200-225) \times 2.5 \times 0.15~=~365.625 }[/math] e AMMORT.DEGR arrotonda questo valore a 366.
- I valori di ammortamento per i periodi 2 e 3 vengono calcolati in modo simile al periodo 1.
- Durante i periodi da 0 a 3, l'ammortamento totale è 962. Poiché Costo - Cespite - 962 è maggiore di 0, AMMORT.DEGR determina che dovrebbe esserci una spesa di ammortamento finale nel periodo 4. Tuttavia, invece di utilizzare lo stesso algoritmo dei passaggi da 1 a 3, il numero restituito per il periodo 4 è la metà della differenza tra il valore originale dell'argomento Costo (1200 in questo caso) meno l'ammortamento totale nei periodi precedenti (962 in questo caso), ovvero [math]\displaystyle{ 0,5 \times 238 }[/math] o [math]\displaystyle{ 119 }[/math].
- Per i periodi 5 o successivi, AMMORT.DEGR restituisce 0.
Ulteriori esempi
Formula
Descrizione
Restituisce
=AMMORT.DEGR(1500; "2001-04-01"; "2001-06-15"; 454; 0; 0,19; 2)
Qui la funzione calcola l'ammortamento proporzionale per il periodo 0, che è un breve periodo di circa 2,5 mesi.
119
=AMMORT.DEGR(1500; "2001-04-01"; "2001-06-15"; 454; 0; 0,19)
Anche in questo caso la funzione calcola l'ammortamento proporzionale per il periodo 0, ovvero un breve periodo di circa 2,5 mesi. Tuttavia, in questo caso, il valore dell'argomento Basi non è specificato e quindi viene applicato il valore predefinito 0, fornendo un risultato leggermente diverso dall'esempio precedente.
117
=AMMORT.DEGR(1500; "2001-04-01"; "2001-06-15"; 454; 1; 0,19; 2)
Qui la funzione calcola l'importo dell'ammortamento per un intero periodo contabile (periodo 1).
525
=AMMORT.DEGR(2000; DATA(2020; 2; 1); DATA(2020; 12; 31); 10; 4; 10%; 0)
Qui la funzione calcola l'importo dell'ammortamento per un intero periodo contabile (periodo 4). Tenete presente che spesso è una buona pratica utilizzare la funzione DATA invece di digitare valori di data formattati.
163
Funzioni di LibreOffice correlate:
Standard ODF:
Nessuno
Funzioni equivalenti (o simili) di Excel:
AMORDEGRC