Documentation/Calc Functions/BETA.INV

    From The Document Foundation Wiki

    Function name:

    BETA.INV

    Category:

    Statistical Analysis

    Summary:

    Calculates the inverse of the cumulative distribution function for a beta distribution.

    The beta distribution is a family of continuous probability distributions that can be used to model random variables that lie within finite bounds. The distribution has two characteristic positive real numbers, usually denoted as alpha (α) and beta (β), that control its shape. In many cases the beta distribution is defined on the range [0, 1] but in the more general case can be defined on a range [a, b], where a and b are the lower and upper bounds of the distribution (a < b).

    Using the nomenclature of the previous paragraph, BETA.INV uses an iterative algorithm to calculate a value x that lies in the range [a, b] such that [math]\displaystyle{ \text{BETADIST}(x;\:α;\:β;\:a;\:b;\:1)~=~p }[/math], where the given probability p lies in the range [0, 1].

    Syntax:

    BETA.INV(Number; Alpha; Beta [; Start [; End]])

    Returns:

    Returns a real number, which is the value of the random variable that would give the specified probability in the cumulative distribution function for the specified beta distribution. The returned value will lie within the defined range of the distribution.

    Arguments:

    Number is a real number, or a reference to a cell containing that number, which is a probability in the cumulative distribution function of the beta distribution function. Number lies in the range [0, 1].

    Alpha is a positive real number, or a reference to a cell containing that number, which is the value of one of the two parameters that control the shape of the beta distribution.

    Beta is a positive real number, or a reference to a cell containing that number, which is the value of the second of the two parameters that control the shape of the beta distribution.

    Start is a real number, or a reference to a cell containing that number, which is the lower bound of the distribution. If omitted, the default value of 0.0 is used.

    End is a real number, or a reference to a cell containing that number, which is the upper bound of the distribution. If omitted, the default value of 1.0 is used.

    • If any of Number, Alpha, Beta, Start, or End is non-numeric, then BETA.INV reports a #VALUE! error.
    • If either Alpha or Beta is less than or equal to 0.0, then BETA.INV reports an invalid argument error (Err:502).
    • If Number is less than 0.0 or greater than 1.0, then BETA.INV reports an invalid argument error (Err:502).
    • If Start is greater than or equal to End, then BETA.INV reports an invalid argument error (Err:502).

    Additional details:

    • Calc's BETAINV and BETA.INV functions perform the same calculations. The requirements for BETAINV are specified in ODF 1.2; BETA.INV is provided for interoperability with Microsoft Excel.
    • The name space for BETA.INV is COM.MICROSOFT.BETA.INV.
    • For more information on the beta distribution, visit Wikipedia's Beta distribution page.

    Examples:

    Formula Description Returns
    =BETA.INV(A1; A2; A3; A4; A5) where cells A1:A5 contain the numbers 0.5, 1, 2, 0, and 1 respectively. Here the function calculates the inverse of the beta cumulative distribution function defined on the range [0, 1] for the parameters x=0.5; α=1; β=2. Note that the formula =BETADIST(0.292893218813453; A2; A3; A4; A5; 1) returns (approximately) 0.5. 0.292893218813453
    =BETA.INV(0.0; 1; 2) Here the function calculates the inverse of the beta cumulative distribution function defined on the range [0, 1] for the parameters x=0.0; α=1; β=2. The Start and End arguments are omitted and so the default values of 0 and 1 are applied. As expected, the value of x=0.0 returns the lower bound of the range of the distribution. Similarly, the formula =BETA.INV(1.0; 1; 2) returns 1, the upper bound of the distribution. 0
    =BETA.INV(0.0975038972564338; 6.2; 4.3; -2.4; 6.5) Here the function calculates the inverse of the beta cumulative distribution function defined on the range [-2.4, 6.5] for the parameters x=0.0975038972564338; α=6.2; β=4.3. Note that the formula =BETADIST(1.1; 6.2; 4.3; -2.4; 6.5) returns the value 0.0975038972564338. 1.1

    Related LibreOffice functions:

    BETA.DIST

    BETADIST

    BETAINV

    ODF standard:

    None

    Related (or similar) Excel functions:

    BETA.INV