Documentation/Calc Funktionen/FEHLER.TYP

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/ERROR.TYPE and the translation is 98% complete.
    Outdated translations are marked like this.

    TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende

    Other languages:


    Funktionsname:

    FEHLER.TYP

    Kategorie:

    Tabelle

    Zusammenfassung:

    Generiert einen Code für den Typ eines Fehlers.

    Syntax:

    FEHLER.TYP(Ausdruck)

    Rückgabewerte:

    Gibt für einen der sieben definierten Fehlermeldungen eine positive Ganzzahl im Bereich [1, 7] zurück. Gibt einen #NV Fehler zurück, falls das Argument keinen Fehler oder keinen dieser sieben Fehler aus der Fehlertabelle enthält.

    Die Liste der sieben Fehler in Calc sind in dieser Tabelle aufgelistet.

    Zuordnung der Fehler zu den Fehlertypen
    Fehler Ergebnis
    Fehler:511 (Variable fehlt)
    [tdf#154167][tdf#154915] #NULL!     		1
    #DIV/0! 2
    #WERT! 3
    #BEZUG! 4
    #NAME? 5
    #ZAHL! 6
    #NV 7
    kein Fehler oder
    Fehler wird von dieser Liste nicht abgedeckt     		#NV
    • Falls bis LibreOffice 7.5 (inklusive), der Ausdruck in Fehler:511 resultiert, ist das Ergebnis von FEHLER.TYP 1. Das Ergebnis ist nicht in Übereinstimmung mit dem ODF Standard. Das wurde mit LibreOffice 7.6 korrigiert. Siehe die untenstehenden Beispiele.
    • Bis LibreOffice 7.5 (inklusive) gibt es keine Formel, die den Fehler #NULL! liefert. Stattdessen erzeugte der Fall "keine Referenz der Schnittmenge" der Funktion #BEZUG! eine Fehlermeldung. Das wurde in LibreOffice 7.6 korrigiert. Siehe die untenstehenden Beispiele.

    Argumente:

    Ausdruck ist ein Ausdruck oder einer Referenz auf eine Zelle, die den Ausdruck enthält, dessen Fehlertyp bestimmt wird.

    Zusätzliche Informationen:

    • Der ganzzahlige Fehlertyp kann helfen, eine besprochene Fehlermeldung zu erzeugen, die für die angesprochene Zeilgruppe der Tabelle hilfreich ist.
    • FEHLER.TYP gibt im Gegensatz zu den meisten anderen Funktionen keine Fehler weiter.
    • Andere Tabellenkalkulationen können andere Fehlercodes als Calc für die selbe Formel liefern. Im Moment liefert auch Calc seine eigenen "Fehler:nnn" Fehlercodes, wobei andere Implementationen den Fehler #ZAHL! für die selben Formeln melden. Daher ist aus Kompatibilitätsgründen Vorsicht geboten.
    • Für Formeln, die "Fehler:nnn" Fehler Codes liefern, gibt Calc's FEHLER.TYP einen #NV, das selbe Ergebnis wie für Fehlerfreiheit. Andere Implementierungen differenzieren zwischen diesen zwei Fällen und erzeugen unterschiedliche Ergebnisse. Daher ist aus Kompatibilitätsgründen Vorsicht geboten.
    • Andere Implementationen akzeptieren Fehler Codes direkt eingegeben als Zeichenketten für den Ausdruck und geben den selben FEHLER.TYP zurück wie für einen aktuellen/echten Ausdruck. Das hilft, Formeln mit Hilfe des FEHLER.TYP zu testen. LibreOffice Calc unterstützt die Verwendung des Ausdruckes. In anderen Worten erwartet der Ausdruck keine Zeichenkette mit dem Fehler Code selbst, sondern das Ergebnis eines Ausdruckes oder eine Referenz auf einen Ausdruck.
    • Andere Tabellenkalkulationen erzeugen andere numerische Ergebnisse als [1...7] für den FEHLER.TYP. Daher ist aus Kompatibilitätsgründen Vorsicht geboten.
    • Falls die Funktion FEHLER.TYP als Bedingung in einem WENN-Aufruf verwendet wird, und die Funktion FEHLER.TYP einen #NV meldet, meldet auch die Funktion WENN einen #NV. Um das zu vermeiden, wird ISTFEHLER wie im unten stehenden Beispiel gezeigt verwendet.

    Beispiele:

    Die folgende Tabelle wird für Daten (aus Ergebnissen und Formeln) für die unten stehenden Beispiele genutzt.

    Beispielsdaten
    A B C D E
    1 Ergebnis Beschreibung Formel
    2 Fehler:511 fehlendes Argument =WURZEL()
    3 Fehler:502 =WURZEL(-2)
    4 3,14 π =PI()
    5 10
    6 2 1 4
    7 5 0
    8 3 A5:D6 überschneidet sich mit A6:B7 [1] =SUMME(A5:D6!A6:B7)
    9 #NULL! keine Überschneidung =SUMME(A5:A6!B6:B7)
    10 #BEZUG! ⇐ Kopie =B10 =#BEZUG!10
    1. ↑ Das Leerzeichen wird in einigen Tabellen-Werkzeugen als Schnittmengen-Operator verwendet.
    Formel Beschreibung Ergebnis
    =FEHLER.TYP(A2)

    =FEHLER.TYP(WURZEL())

    		Fehler:511 fehlendes Argument 1 (LO < 7.6) #NV
    =FEHLER.TYP(A9)

    =FEHLER.TYP(SUMME(A5:A6!B6:B7))

    		#NULL! keine Überschneidung 1
    =FEHLER.TYP(B6/D7)

    =FEHLER.TYP(1/0)

    		#DIV/0! Division durch Null 2
    =FEHLER.TYP( "Zeichenkette" + 0 ) #WERT! Kein (gültiger) Wert 3
    =FEHLER.TYP(A10) #BEZUG! keine gültige Referenz 4
    =FEHLER.TYP(unbekannter_Name) #NAME? ungültiger Name 5
    =FEHLER.TYP(1000^500) #ZAHL! überlaufender / ungültiger numerischer Wert 6
    =FEHLER.TYP(NV()) #NV Wert nicht verfügbar / nicht gefunden 7
    =FEHLER.TYP(A3)

    =FEHLER.TYP(WURZEL(-2))

    Eine negative Zahl ist für WURZEL ein ungültiger Wert. Fehler:502 wird keinem spezifischen Fehlertyp zugeordnet.

    		#NV
    =FEHLER.TYP(D6) In der angegebenen Zelle gibt es keinen Fehler. #NV

    =WENN(ISTFEHLER(A5/A6);   WENN(FEHLER.TYP(A5/A6)=2;   "*** Division durch Null ist nicht zulässig ***");   A5/A6)

    Falls die Division durchgeführt werden kann, wird das Ergebnis angezeigt. Falls der Wert des Teilers Null (oder leer) ist, wird stattdessen eine nutzer-freundliche Fehlermeldung angezeigt. Andere mögliche Fehler werdedn durch diese Formel/dieses Beispiel nicht abgefangen.

    		10/2=5

    =WENN(ISTFEHLER(A5/D7);   WENN(FEHLER.TYP(A5/D7)=2;   "*** Division durch Null ist nicht zulässig ***");   A5/D7)

    		*** Division durch Null ist nicht zulässig ***

    Ähnliche LibreOffice Funktionen:

    FEHLERTYP

    WENN

    WENNFEHLER

    WENNNV

    ISTFEHL

    ISTFEHLER

    ISTNV

    ISTZAHL

    ISTTEXT

    NV

    ODF Standard:

    Kapitel 6.13.11, Teil 2.

    Betroffene (oder ähnliche) EXCEL-Funktionen:

    ERROR.TYPE


    Retrieved from "https://wiki.documentfoundation.org/index.php?title=Documentation/Calc_Functions/ERROR.TYPE/de&oldid=775263"